Merge tag 'mmc-updates-for-3.9-rc1' of git://git.kernel.org/pub/scm/linux/kernel...
[~shefty/rdma-dev.git] / arch / arm / boot / compressed / vmlinux.lds.in
1 /*
2  *  linux/arch/arm/boot/compressed/vmlinux.lds.in
3  *
4  *  Copyright (C) 2000 Russell King
5  *
6  * This program is free software; you can redistribute it and/or modify
7  * it under the terms of the GNU General Public License version 2 as
8  * published by the Free Software Foundation.
9  */
10 OUTPUT_ARCH(arm)
11 ENTRY(_start)
12 SECTIONS
13 {
14   /DISCARD/ : {
15     *(.ARM.exidx*)
16     *(.ARM.extab*)
17     /*
18      * Discard any r/w data - this produces a link error if we have any,
19      * which is required for PIC decompression.  Local data generates
20      * GOTOFF relocations, which prevents it being relocated independently
21      * of the text/got segments.
22      */
23     *(.data)
24   }
25
26   . = TEXT_START;
27   _text = .;
28
29   .text : {
30     _start = .;
31     *(.start)
32     *(.text)
33     *(.text.*)
34     *(.fixup)
35     *(.gnu.warning)
36     *(.glue_7t)
37     *(.glue_7)
38   }
39   .rodata : {
40     *(.rodata)
41     *(.rodata.*)
42   }
43   .piggydata : {
44     *(.piggydata)
45   }
46
47   . = ALIGN(4);
48   _etext = .;
49
50   .got.plt              : { *(.got.plt) }
51   _got_start = .;
52   .got                  : { *(.got) }
53   _got_end = .;
54
55   /* ensure the zImage file size is always a multiple of 64 bits */
56   /* (without a dummy byte, ld just ignores the empty section) */
57   .pad                  : { BYTE(0); . = ALIGN(8); }
58   _edata = .;
59
60   . = BSS_START;
61   __bss_start = .;
62   .bss                  : { *(.bss) }
63   _end = .;
64
65   . = ALIGN(8);         /* the stack must be 64-bit aligned */
66   .stack                : { *(.stack) }
67
68   .stab 0               : { *(.stab) }
69   .stabstr 0            : { *(.stabstr) }
70   .stab.excl 0          : { *(.stab.excl) }
71   .stab.exclstr 0       : { *(.stab.exclstr) }
72   .stab.index 0         : { *(.stab.index) }
73   .stab.indexstr 0      : { *(.stab.indexstr) }
74   .comment 0            : { *(.comment) }
75 }
76