f954b37740c0605e6d4a4ad34a9b7d4005b7d5a1
[~shefty/rdma-dev.git] / arch / s390 / kernel / entry.S
1 /*
2  *    S390 low-level entry points.
3  *
4  *    Copyright IBM Corp. 1999, 2012
5  *    Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
6  *               Hartmut Penner (hp@de.ibm.com),
7  *               Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
8  *               Heiko Carstens <heiko.carstens@de.ibm.com>
9  */
10
11 #include <linux/init.h>
12 #include <linux/linkage.h>
13 #include <asm/cache.h>
14 #include <asm/errno.h>
15 #include <asm/ptrace.h>
16 #include <asm/thread_info.h>
17 #include <asm/asm-offsets.h>
18 #include <asm/unistd.h>
19 #include <asm/page.h>
20 #include <asm/sigp.h>
21
22 __PT_R0      =  __PT_GPRS
23 __PT_R1      =  __PT_GPRS + 4
24 __PT_R2      =  __PT_GPRS + 8
25 __PT_R3      =  __PT_GPRS + 12
26 __PT_R4      =  __PT_GPRS + 16
27 __PT_R5      =  __PT_GPRS + 20
28 __PT_R6      =  __PT_GPRS + 24
29 __PT_R7      =  __PT_GPRS + 28
30 __PT_R8      =  __PT_GPRS + 32
31 __PT_R9      =  __PT_GPRS + 36
32 __PT_R10     =  __PT_GPRS + 40
33 __PT_R11     =  __PT_GPRS + 44
34 __PT_R12     =  __PT_GPRS + 48
35 __PT_R13     =  __PT_GPRS + 524
36 __PT_R14     =  __PT_GPRS + 56
37 __PT_R15     =  __PT_GPRS + 60
38
39 _TIF_WORK_SVC = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
40                  _TIF_MCCK_PENDING | _TIF_PER_TRAP )
41 _TIF_WORK_INT = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
42                  _TIF_MCCK_PENDING)
43 _TIF_TRACE    = (_TIF_SYSCALL_TRACE | _TIF_SYSCALL_AUDIT | _TIF_SECCOMP | \
44                  _TIF_SYSCALL_TRACEPOINT)
45
46 STACK_SHIFT = PAGE_SHIFT + THREAD_ORDER
47 STACK_SIZE  = 1 << STACK_SHIFT
48
49 #define BASED(name) name-system_call(%r13)
50
51         .macro  TRACE_IRQS_ON
52 #ifdef CONFIG_TRACE_IRQFLAGS
53         basr    %r2,%r0
54         l       %r1,BASED(.Lhardirqs_on)
55         basr    %r14,%r1                # call trace_hardirqs_on_caller
56 #endif
57         .endm
58
59         .macro  TRACE_IRQS_OFF
60 #ifdef CONFIG_TRACE_IRQFLAGS
61         basr    %r2,%r0
62         l       %r1,BASED(.Lhardirqs_off)
63         basr    %r14,%r1                # call trace_hardirqs_off_caller
64 #endif
65         .endm
66
67         .macro  LOCKDEP_SYS_EXIT
68 #ifdef CONFIG_LOCKDEP
69         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
70         jz      .+10
71         l       %r1,BASED(.Llockdep_sys_exit)
72         basr    %r14,%r1                # call lockdep_sys_exit
73 #endif
74         .endm
75
76         .macro  CHECK_STACK stacksize,savearea
77 #ifdef CONFIG_CHECK_STACK
78         tml     %r15,\stacksize - CONFIG_STACK_GUARD
79         la      %r14,\savearea
80         jz      stack_overflow
81 #endif
82         .endm
83
84         .macro  SWITCH_ASYNC savearea,stack,shift
85         tmh     %r8,0x0001              # interrupting from user ?
86         jnz     1f
87         lr      %r14,%r9
88         sl      %r14,BASED(.Lcritical_start)
89         cl      %r14,BASED(.Lcritical_length)
90         jhe     0f
91         la      %r11,\savearea          # inside critical section, do cleanup
92         bras    %r14,cleanup_critical
93         tmh     %r8,0x0001              # retest problem state after cleanup
94         jnz     1f
95 0:      l       %r14,\stack             # are we already on the target stack?
96         slr     %r14,%r15
97         sra     %r14,\shift
98         jnz     1f
99         CHECK_STACK 1<<\shift,\savearea
100         j       2f
101 1:      l       %r15,\stack             # load target stack
102 2:      ahi     %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
103         la      %r11,STACK_FRAME_OVERHEAD(%r15)
104         .endm
105
106         .macro  ADD64 high,low,timer
107         al      \high,\timer
108         al      \low,4+\timer
109         brc     12,.+8
110         ahi     \high,1
111         .endm
112
113         .macro  SUB64 high,low,timer
114         sl      \high,\timer
115         sl      \low,4+\timer
116         brc     3,.+8
117         ahi     \high,-1
118         .endm
119
120         .macro  UPDATE_VTIME high,low,enter_timer
121         lm      \high,\low,__LC_EXIT_TIMER
122         SUB64   \high,\low,\enter_timer
123         ADD64   \high,\low,__LC_USER_TIMER
124         stm     \high,\low,__LC_USER_TIMER
125         lm      \high,\low,__LC_LAST_UPDATE_TIMER
126         SUB64   \high,\low,__LC_EXIT_TIMER
127         ADD64   \high,\low,__LC_SYSTEM_TIMER
128         stm     \high,\low,__LC_SYSTEM_TIMER
129         mvc     __LC_LAST_UPDATE_TIMER(8),\enter_timer
130         .endm
131
132         .macro REENABLE_IRQS
133         st      %r8,__LC_RETURN_PSW
134         ni      __LC_RETURN_PSW,0xbf
135         ssm     __LC_RETURN_PSW
136         .endm
137
138         .section .kprobes.text, "ax"
139
140 /*
141  * Scheduler resume function, called by switch_to
142  *  gpr2 = (task_struct *) prev
143  *  gpr3 = (task_struct *) next
144  * Returns:
145  *  gpr2 = prev
146  */
147 ENTRY(__switch_to)
148         stm     %r6,%r15,__SF_GPRS(%r15)        # store gprs of prev task
149         st      %r15,__THREAD_ksp(%r2)          # store kernel stack of prev
150         l       %r4,__THREAD_info(%r2)          # get thread_info of prev
151         l       %r5,__THREAD_info(%r3)          # get thread_info of next
152         lr      %r15,%r5
153         ahi     %r15,STACK_SIZE                 # end of kernel stack of next
154         st      %r3,__LC_CURRENT                # store task struct of next
155         st      %r5,__LC_THREAD_INFO            # store thread info of next
156         st      %r15,__LC_KERNEL_STACK          # store end of kernel stack
157         lctl    %c4,%c4,__TASK_pid(%r3)         # load pid to control reg. 4
158         mvc     __LC_CURRENT_PID(4,%r0),__TASK_pid(%r3) # store pid of next
159         l       %r15,__THREAD_ksp(%r3)          # load kernel stack of next
160         tm      __TI_flags+3(%r4),_TIF_MCCK_PENDING # machine check pending?
161         jz      0f
162         ni      __TI_flags+3(%r4),255-_TIF_MCCK_PENDING # clear flag in prev
163         oi      __TI_flags+3(%r5),_TIF_MCCK_PENDING     # set it in next
164 0:      lm      %r6,%r15,__SF_GPRS(%r15)        # load gprs of next task
165         br      %r14
166
167 __critical_start:
168 /*
169  * SVC interrupt handler routine. System calls are synchronous events and
170  * are executed with interrupts enabled.
171  */
172
173 ENTRY(system_call)
174         stpt    __LC_SYNC_ENTER_TIMER
175 sysc_stm:
176         stm     %r8,%r15,__LC_SAVE_AREA_SYNC
177         l       %r12,__LC_THREAD_INFO
178         l       %r13,__LC_SVC_NEW_PSW+4
179 sysc_per:
180         l       %r15,__LC_KERNEL_STACK
181         ahi     %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
182         la      %r11,STACK_FRAME_OVERHEAD(%r15) # pointer to pt_regs
183 sysc_vtime:
184         UPDATE_VTIME %r8,%r9,__LC_SYNC_ENTER_TIMER
185         stm     %r0,%r7,__PT_R0(%r11)
186         mvc     __PT_R8(32,%r11),__LC_SAVE_AREA_SYNC
187         mvc     __PT_PSW(8,%r11),__LC_SVC_OLD_PSW
188         mvc     __PT_INT_CODE(4,%r11),__LC_SVC_ILC
189 sysc_do_svc:
190         oi      __TI_flags+3(%r12),_TIF_SYSCALL
191         lh      %r8,__PT_INT_CODE+2(%r11)
192         sla     %r8,2                           # shift and test for svc0
193         jnz     sysc_nr_ok
194         # svc 0: system call number in %r1
195         cl      %r1,BASED(.Lnr_syscalls)
196         jnl     sysc_nr_ok
197         sth     %r1,__PT_INT_CODE+2(%r11)
198         lr      %r8,%r1
199         sla     %r8,2
200 sysc_nr_ok:
201         l       %r10,BASED(.Lsys_call_table)    # 31 bit system call table
202         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15)
203         st      %r2,__PT_ORIG_GPR2(%r11)
204         st      %r7,STACK_FRAME_OVERHEAD(%r15)
205         l       %r9,0(%r8,%r10)                 # get system call addr.
206         tm      __TI_flags+2(%r12),_TIF_TRACE >> 8
207         jnz     sysc_tracesys
208         basr    %r14,%r9                        # call sys_xxxx
209         st      %r2,__PT_R2(%r11)               # store return value
210
211 sysc_return:
212         LOCKDEP_SYS_EXIT
213 sysc_tif:
214         tm      __PT_PSW+1(%r11),0x01           # returning to user ?
215         jno     sysc_restore
216         tm      __TI_flags+3(%r12),_TIF_WORK_SVC
217         jnz     sysc_work                       # check for work
218         ni      __TI_flags+3(%r12),255-_TIF_SYSCALL
219 sysc_restore:
220         mvc     __LC_RETURN_PSW(8),__PT_PSW(%r11)
221         stpt    __LC_EXIT_TIMER
222         lm      %r0,%r15,__PT_R0(%r11)
223         lpsw    __LC_RETURN_PSW
224 sysc_done:
225
226 #
227 # One of the work bits is on. Find out which one.
228 #
229 sysc_work:
230         tm      __TI_flags+3(%r12),_TIF_MCCK_PENDING
231         jo      sysc_mcck_pending
232         tm      __TI_flags+3(%r12),_TIF_NEED_RESCHED
233         jo      sysc_reschedule
234         tm      __TI_flags+3(%r12),_TIF_PER_TRAP
235         jo      sysc_singlestep
236         tm      __TI_flags+3(%r12),_TIF_SIGPENDING
237         jo      sysc_sigpending
238         tm      __TI_flags+3(%r12),_TIF_NOTIFY_RESUME
239         jo      sysc_notify_resume
240         j       sysc_return             # beware of critical section cleanup
241
242 #
243 # _TIF_NEED_RESCHED is set, call schedule
244 #
245 sysc_reschedule:
246         l       %r1,BASED(.Lschedule)
247         la      %r14,BASED(sysc_return)
248         br      %r1                     # call schedule
249
250 #
251 # _TIF_MCCK_PENDING is set, call handler
252 #
253 sysc_mcck_pending:
254         l       %r1,BASED(.Lhandle_mcck)
255         la      %r14,BASED(sysc_return)
256         br      %r1                     # TIF bit will be cleared by handler
257
258 #
259 # _TIF_SIGPENDING is set, call do_signal
260 #
261 sysc_sigpending:
262         lr      %r2,%r11                # pass pointer to pt_regs
263         l       %r1,BASED(.Ldo_signal)
264         basr    %r14,%r1                # call do_signal
265         tm      __TI_flags+3(%r12),_TIF_SYSCALL
266         jno     sysc_return
267         lm      %r2,%r7,__PT_R2(%r11)   # load svc arguments
268         xr      %r8,%r8                 # svc 0 returns -ENOSYS
269         clc     __PT_INT_CODE+2(2,%r11),BASED(.Lnr_syscalls+2)
270         jnl     sysc_nr_ok              # invalid svc number -> do svc 0
271         lh      %r8,__PT_INT_CODE+2(%r11)       # load new svc number
272         sla     %r8,2
273         j       sysc_nr_ok              # restart svc
274
275 #
276 # _TIF_NOTIFY_RESUME is set, call do_notify_resume
277 #
278 sysc_notify_resume:
279         lr      %r2,%r11                # pass pointer to pt_regs
280         l       %r1,BASED(.Ldo_notify_resume)
281         la      %r14,BASED(sysc_return)
282         br      %r1                     # call do_notify_resume
283
284 #
285 # _TIF_PER_TRAP is set, call do_per_trap
286 #
287 sysc_singlestep:
288         ni      __TI_flags+3(%r12),255-_TIF_PER_TRAP
289         lr      %r2,%r11                # pass pointer to pt_regs
290         l       %r1,BASED(.Ldo_per_trap)
291         la      %r14,BASED(sysc_return)
292         br      %r1                     # call do_per_trap
293
294 #
295 # call tracehook_report_syscall_entry/tracehook_report_syscall_exit before
296 # and after the system call
297 #
298 sysc_tracesys:
299         l       %r1,BASED(.Ltrace_enter)
300         lr      %r2,%r11                # pass pointer to pt_regs
301         la      %r3,0
302         xr      %r0,%r0
303         icm     %r0,3,__PT_INT_CODE+2(%r11)
304         st      %r0,__PT_R2(%r11)
305         basr    %r14,%r1                # call do_syscall_trace_enter
306         cl      %r2,BASED(.Lnr_syscalls)
307         jnl     sysc_tracenogo
308         lr      %r8,%r2
309         sll     %r8,2
310         l       %r9,0(%r8,%r10)
311 sysc_tracego:
312         lm      %r3,%r7,__PT_R3(%r11)
313         st      %r7,STACK_FRAME_OVERHEAD(%r15)
314         l       %r2,__PT_ORIG_GPR2(%r11)
315         basr    %r14,%r9                # call sys_xxx
316         st      %r2,__PT_R2(%r11)       # store return value
317 sysc_tracenogo:
318         tm      __TI_flags+2(%r12),_TIF_TRACE >> 8
319         jz      sysc_return
320         l       %r1,BASED(.Ltrace_exit)
321         lr      %r2,%r11                # pass pointer to pt_regs
322         la      %r14,BASED(sysc_return)
323         br      %r1                     # call do_syscall_trace_exit
324
325 #
326 # a new process exits the kernel with ret_from_fork
327 #
328 ENTRY(ret_from_fork)
329         la      %r11,STACK_FRAME_OVERHEAD(%r15)
330         l       %r12,__LC_THREAD_INFO
331         l       %r13,__LC_SVC_NEW_PSW+4
332         tm      __PT_PSW+1(%r11),0x01   # forking a kernel thread ?
333         je      1f
334         l       %r1,BASED(.Lschedule_tail)
335         basr    %r14,%r1                # call schedule_tail
336         TRACE_IRQS_ON
337         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
338         j       sysc_tracenogo
339
340 1:      # it's a kernel thread
341         st      %r15,__PT_R15(%r11)     # store stack pointer for new kthread
342         l       %r1,BASED(.Lschedule_tail)
343         basr    %r14,%r1                # call schedule_tail
344         TRACE_IRQS_ON
345         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
346         lm      %r9,%r11,__PT_R9(%r11)  # load gprs
347 ENTRY(kernel_thread_starter)
348         la      %r2,0(%r10)
349         basr    %r14,%r9
350         la      %r2,0
351         br      %r11                    # do_exit
352
353 #
354 # kernel_execve function needs to deal with pt_regs that is not
355 # at the usual place
356 #
357 ENTRY(ret_from_kernel_execve)
358         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
359         lr      %r15,%r2
360         lr      %r11,%r2
361         ahi     %r15,-STACK_FRAME_OVERHEAD
362         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15)
363         l       %r12,__LC_THREAD_INFO
364         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
365         j       sysc_return
366
367 /*
368  * Program check handler routine
369  */
370
371 ENTRY(pgm_check_handler)
372         stpt    __LC_SYNC_ENTER_TIMER
373         stm     %r8,%r15,__LC_SAVE_AREA_SYNC
374         l       %r12,__LC_THREAD_INFO
375         l       %r13,__LC_SVC_NEW_PSW+4
376         lm      %r8,%r9,__LC_PGM_OLD_PSW
377         tmh     %r8,0x0001              # test problem state bit
378         jnz     1f                      # -> fault in user space
379         tmh     %r8,0x4000              # PER bit set in old PSW ?
380         jnz     0f                      # -> enabled, can't be a double fault
381         tm      __LC_PGM_ILC+3,0x80     # check for per exception
382         jnz     pgm_svcper              # -> single stepped svc
383 0:      CHECK_STACK STACK_SIZE,__LC_SAVE_AREA_SYNC
384         j       2f
385 1:      UPDATE_VTIME %r14,%r15,__LC_SYNC_ENTER_TIMER
386         l       %r15,__LC_KERNEL_STACK
387 2:      ahi     %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
388         la      %r11,STACK_FRAME_OVERHEAD(%r15)
389         stm     %r0,%r7,__PT_R0(%r11)
390         mvc     __PT_R8(32,%r11),__LC_SAVE_AREA_SYNC
391         stm     %r8,%r9,__PT_PSW(%r11)
392         mvc     __PT_INT_CODE(4,%r11),__LC_PGM_ILC
393         mvc     __PT_INT_PARM_LONG(4,%r11),__LC_TRANS_EXC_CODE
394         tm      __LC_PGM_ILC+3,0x80     # check for per exception
395         jz      0f
396         l       %r1,__TI_task(%r12)
397         tmh     %r8,0x0001              # kernel per event ?
398         jz      pgm_kprobe
399         oi      __TI_flags+3(%r12),_TIF_PER_TRAP
400         mvc     __THREAD_per_address(4,%r1),__LC_PER_ADDRESS
401         mvc     __THREAD_per_cause(2,%r1),__LC_PER_CAUSE
402         mvc     __THREAD_per_paid(1,%r1),__LC_PER_PAID
403 0:      REENABLE_IRQS
404         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15)
405         l       %r1,BASED(.Ljump_table)
406         la      %r10,0x7f
407         n       %r10,__PT_INT_CODE(%r11)
408         je      sysc_return
409         sll     %r10,2
410         l       %r1,0(%r10,%r1)         # load address of handler routine
411         lr      %r2,%r11                # pass pointer to pt_regs
412         basr    %r14,%r1                # branch to interrupt-handler
413         j       sysc_return
414
415 #
416 # PER event in supervisor state, must be kprobes
417 #
418 pgm_kprobe:
419         REENABLE_IRQS
420         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15)
421         l       %r1,BASED(.Ldo_per_trap)
422         lr      %r2,%r11                # pass pointer to pt_regs
423         basr    %r14,%r1                # call do_per_trap
424         j       sysc_return
425
426 #
427 # single stepped system call
428 #
429 pgm_svcper:
430         oi      __TI_flags+3(%r12),_TIF_PER_TRAP
431         mvc     __LC_RETURN_PSW(4),__LC_SVC_NEW_PSW
432         mvc     __LC_RETURN_PSW+4(4),BASED(.Lsysc_per)
433         lpsw    __LC_RETURN_PSW         # branch to sysc_per and enable irqs
434
435 /*
436  * IO interrupt handler routine
437  */
438
439 ENTRY(io_int_handler)
440         stck    __LC_INT_CLOCK
441         stpt    __LC_ASYNC_ENTER_TIMER
442         stm     %r8,%r15,__LC_SAVE_AREA_ASYNC
443         l       %r12,__LC_THREAD_INFO
444         l       %r13,__LC_SVC_NEW_PSW+4
445         lm      %r8,%r9,__LC_IO_OLD_PSW
446         tmh     %r8,0x0001              # interrupting from user ?
447         jz      io_skip
448         UPDATE_VTIME %r14,%r15,__LC_ASYNC_ENTER_TIMER
449 io_skip:
450         SWITCH_ASYNC __LC_SAVE_AREA_ASYNC,__LC_ASYNC_STACK,STACK_SHIFT
451         stm     %r0,%r7,__PT_R0(%r11)
452         mvc     __PT_R8(32,%r11),__LC_SAVE_AREA_ASYNC
453         stm     %r8,%r9,__PT_PSW(%r11)
454         TRACE_IRQS_OFF
455         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15)
456         l       %r1,BASED(.Ldo_IRQ)
457         lr      %r2,%r11                # pass pointer to pt_regs
458         basr    %r14,%r1                # call do_IRQ
459 io_return:
460         LOCKDEP_SYS_EXIT
461         TRACE_IRQS_ON
462 io_tif:
463         tm      __TI_flags+3(%r12),_TIF_WORK_INT
464         jnz     io_work                 # there is work to do (signals etc.)
465 io_restore:
466         mvc     __LC_RETURN_PSW(8),__PT_PSW(%r11)
467         stpt    __LC_EXIT_TIMER
468         lm      %r0,%r15,__PT_R0(%r11)
469         lpsw    __LC_RETURN_PSW
470 io_done:
471
472 #
473 # There is work todo, find out in which context we have been interrupted:
474 # 1) if we return to user space we can do all _TIF_WORK_INT work
475 # 2) if we return to kernel code and preemptive scheduling is enabled check
476 #    the preemption counter and if it is zero call preempt_schedule_irq
477 # Before any work can be done, a switch to the kernel stack is required.
478 #
479 io_work:
480         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
481         jo      io_work_user            # yes -> do resched & signal
482 #ifdef CONFIG_PREEMPT
483         # check for preemptive scheduling
484         icm     %r0,15,__TI_precount(%r12)
485         jnz     io_restore              # preemption disabled
486         tm      __TI_flags+3(%r12),_TIF_NEED_RESCHED
487         jno     io_restore
488         # switch to kernel stack
489         l       %r1,__PT_R15(%r11)
490         ahi     %r1,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
491         mvc     STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
492         xc      __SF_BACKCHAIN(4,%r1),__SF_BACKCHAIN(%r1)
493         la      %r11,STACK_FRAME_OVERHEAD(%r1)
494         lr      %r15,%r1
495         # TRACE_IRQS_ON already done at io_return, call
496         # TRACE_IRQS_OFF to keep things symmetrical
497         TRACE_IRQS_OFF
498         l       %r1,BASED(.Lpreempt_irq)
499         basr    %r14,%r1                # call preempt_schedule_irq
500         j       io_return
501 #else
502         j       io_restore
503 #endif
504
505 #
506 # Need to do work before returning to userspace, switch to kernel stack
507 #
508 io_work_user:
509         l       %r1,__LC_KERNEL_STACK
510         ahi     %r1,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
511         mvc     STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
512         xc      __SF_BACKCHAIN(4,%r1),__SF_BACKCHAIN(%r1)
513         la      %r11,STACK_FRAME_OVERHEAD(%r1)
514         lr      %r15,%r1
515
516 #
517 # One of the work bits is on. Find out which one.
518 # Checked are: _TIF_SIGPENDING, _TIF_NOTIFY_RESUME, _TIF_NEED_RESCHED
519 #               and _TIF_MCCK_PENDING
520 #
521 io_work_tif:
522         tm      __TI_flags+3(%r12),_TIF_MCCK_PENDING
523         jo      io_mcck_pending
524         tm      __TI_flags+3(%r12),_TIF_NEED_RESCHED
525         jo      io_reschedule
526         tm      __TI_flags+3(%r12),_TIF_SIGPENDING
527         jo      io_sigpending
528         tm      __TI_flags+3(%r12),_TIF_NOTIFY_RESUME
529         jo      io_notify_resume
530         j       io_return               # beware of critical section cleanup
531
532 #
533 # _TIF_MCCK_PENDING is set, call handler
534 #
535 io_mcck_pending:
536         # TRACE_IRQS_ON already done at io_return
537         l       %r1,BASED(.Lhandle_mcck)
538         basr    %r14,%r1                # TIF bit will be cleared by handler
539         TRACE_IRQS_OFF
540         j       io_return
541
542 #
543 # _TIF_NEED_RESCHED is set, call schedule
544 #
545 io_reschedule:
546         # TRACE_IRQS_ON already done at io_return
547         l       %r1,BASED(.Lschedule)
548         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
549         basr    %r14,%r1                # call scheduler
550         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
551         TRACE_IRQS_OFF
552         j       io_return
553
554 #
555 # _TIF_SIGPENDING is set, call do_signal
556 #
557 io_sigpending:
558         # TRACE_IRQS_ON already done at io_return
559         l       %r1,BASED(.Ldo_signal)
560         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
561         lr      %r2,%r11                # pass pointer to pt_regs
562         basr    %r14,%r1                # call do_signal
563         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
564         TRACE_IRQS_OFF
565         j       io_return
566
567 #
568 # _TIF_SIGPENDING is set, call do_signal
569 #
570 io_notify_resume:
571         # TRACE_IRQS_ON already done at io_return
572         l       %r1,BASED(.Ldo_notify_resume)
573         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
574         lr      %r2,%r11                # pass pointer to pt_regs
575         basr    %r14,%r1                # call do_notify_resume
576         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
577         TRACE_IRQS_OFF
578         j       io_return
579
580 /*
581  * External interrupt handler routine
582  */
583
584 ENTRY(ext_int_handler)
585         stck    __LC_INT_CLOCK
586         stpt    __LC_ASYNC_ENTER_TIMER
587         stm     %r8,%r15,__LC_SAVE_AREA_ASYNC
588         l       %r12,__LC_THREAD_INFO
589         l       %r13,__LC_SVC_NEW_PSW+4
590         lm      %r8,%r9,__LC_EXT_OLD_PSW
591         tmh     %r8,0x0001              # interrupting from user ?
592         jz      ext_skip
593         UPDATE_VTIME %r14,%r15,__LC_ASYNC_ENTER_TIMER
594 ext_skip:
595         SWITCH_ASYNC __LC_SAVE_AREA_ASYNC,__LC_ASYNC_STACK,STACK_SHIFT
596         stm     %r0,%r7,__PT_R0(%r11)
597         mvc     __PT_R8(32,%r11),__LC_SAVE_AREA_ASYNC
598         stm     %r8,%r9,__PT_PSW(%r11)
599         TRACE_IRQS_OFF
600         lr      %r2,%r11                # pass pointer to pt_regs
601         l       %r3,__LC_EXT_CPU_ADDR   # get cpu address + interruption code
602         l       %r4,__LC_EXT_PARAMS     # get external parameters
603         l       %r1,BASED(.Ldo_extint)
604         basr    %r14,%r1                # call do_extint
605         j       io_return
606
607 /*
608  * Load idle PSW. The second "half" of this function is in cleanup_idle.
609  */
610 ENTRY(psw_idle)
611         st      %r3,__SF_EMPTY(%r15)
612         basr    %r1,0
613         la      %r1,psw_idle_lpsw+4-.(%r1)
614         st      %r1,__SF_EMPTY+4(%r15)
615         oi      __SF_EMPTY+4(%r15),0x80
616         stck    __CLOCK_IDLE_ENTER(%r2)
617         stpt    __TIMER_IDLE_ENTER(%r2)
618 psw_idle_lpsw:
619         lpsw    __SF_EMPTY(%r15)
620         br      %r14
621 psw_idle_end:
622
623 __critical_end:
624
625 /*
626  * Machine check handler routines
627  */
628
629 ENTRY(mcck_int_handler)
630         stck    __LC_MCCK_CLOCK
631         spt     __LC_CPU_TIMER_SAVE_AREA        # revalidate cpu timer
632         lm      %r0,%r15,__LC_GPREGS_SAVE_AREA  # revalidate gprs
633         l       %r12,__LC_THREAD_INFO
634         l       %r13,__LC_SVC_NEW_PSW+4
635         lm      %r8,%r9,__LC_MCK_OLD_PSW
636         tm      __LC_MCCK_CODE,0x80     # system damage?
637         jo      mcck_panic              # yes -> rest of mcck code invalid
638         la      %r14,__LC_CPU_TIMER_SAVE_AREA
639         mvc     __LC_MCCK_ENTER_TIMER(8),0(%r14)
640         tm      __LC_MCCK_CODE+5,0x02   # stored cpu timer value valid?
641         jo      3f
642         la      %r14,__LC_SYNC_ENTER_TIMER
643         clc     0(8,%r14),__LC_ASYNC_ENTER_TIMER
644         jl      0f
645         la      %r14,__LC_ASYNC_ENTER_TIMER
646 0:      clc     0(8,%r14),__LC_EXIT_TIMER
647         jl      1f
648         la      %r14,__LC_EXIT_TIMER
649 1:      clc     0(8,%r14),__LC_LAST_UPDATE_TIMER
650         jl      2f
651         la      %r14,__LC_LAST_UPDATE_TIMER
652 2:      spt     0(%r14)
653         mvc     __LC_MCCK_ENTER_TIMER(8),0(%r14)
654 3:      tm      __LC_MCCK_CODE+2,0x09   # mwp + ia of old psw valid?
655         jno     mcck_panic              # no -> skip cleanup critical
656         tm      %r8,0x0001              # interrupting from user ?
657         jz      mcck_skip
658         UPDATE_VTIME %r14,%r15,__LC_MCCK_ENTER_TIMER
659 mcck_skip:
660         SWITCH_ASYNC __LC_GPREGS_SAVE_AREA+32,__LC_PANIC_STACK,PAGE_SHIFT
661         mvc     __PT_R0(64,%r11),__LC_GPREGS_SAVE_AREA
662         stm     %r8,%r9,__PT_PSW(%r11)
663         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15)
664         l       %r1,BASED(.Ldo_machine_check)
665         lr      %r2,%r11                # pass pointer to pt_regs
666         basr    %r14,%r1                # call s390_do_machine_check
667         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
668         jno     mcck_return
669         l       %r1,__LC_KERNEL_STACK   # switch to kernel stack
670         ahi     %r1,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
671         mvc     STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
672         xc      __SF_BACKCHAIN(4,%r1),__SF_BACKCHAIN(%r1)
673         la      %r11,STACK_FRAME_OVERHEAD(%r15)
674         lr      %r15,%r1
675         ssm     __LC_PGM_NEW_PSW        # turn dat on, keep irqs off
676         tm      __TI_flags+3(%r12),_TIF_MCCK_PENDING
677         jno     mcck_return
678         TRACE_IRQS_OFF
679         l       %r1,BASED(.Lhandle_mcck)
680         basr    %r14,%r1                # call s390_handle_mcck
681         TRACE_IRQS_ON
682 mcck_return:
683         mvc     __LC_RETURN_MCCK_PSW(8),__PT_PSW(%r11) # move return PSW
684         tm      __LC_RETURN_MCCK_PSW+1,0x01 # returning to user ?
685         jno     0f
686         lm      %r0,%r15,__PT_R0(%r11)
687         stpt    __LC_EXIT_TIMER
688         lpsw    __LC_RETURN_MCCK_PSW
689 0:      lm      %r0,%r15,__PT_R0(%r11)
690         lpsw    __LC_RETURN_MCCK_PSW
691
692 mcck_panic:
693         l       %r14,__LC_PANIC_STACK
694         slr     %r14,%r15
695         sra     %r14,PAGE_SHIFT
696         jz      0f
697         l       %r15,__LC_PANIC_STACK
698 0:      ahi     %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
699         j       mcck_skip
700
701 #
702 # PSW restart interrupt handler
703 #
704 ENTRY(restart_int_handler)
705         st      %r15,__LC_SAVE_AREA_RESTART
706         l       %r15,__LC_RESTART_STACK
707         ahi     %r15,-__PT_SIZE                 # create pt_regs on stack
708         xc      0(__PT_SIZE,%r15),0(%r15)
709         stm     %r0,%r14,__PT_R0(%r15)
710         mvc     __PT_R15(4,%r15),__LC_SAVE_AREA_RESTART
711         mvc     __PT_PSW(8,%r15),__LC_RST_OLD_PSW # store restart old psw
712         ahi     %r15,-STACK_FRAME_OVERHEAD      # create stack frame on stack
713         xc      0(STACK_FRAME_OVERHEAD,%r15),0(%r15)
714         l       %r1,__LC_RESTART_FN             # load fn, parm & source cpu
715         l       %r2,__LC_RESTART_DATA
716         l       %r3,__LC_RESTART_SOURCE
717         ltr     %r3,%r3                         # test source cpu address
718         jm      1f                              # negative -> skip source stop
719 0:      sigp    %r4,%r3,SIGP_SENSE              # sigp sense to source cpu
720         brc     10,0b                           # wait for status stored
721 1:      basr    %r14,%r1                        # call function
722         stap    __SF_EMPTY(%r15)                # store cpu address
723         lh      %r3,__SF_EMPTY(%r15)
724 2:      sigp    %r4,%r3,SIGP_STOP               # sigp stop to current cpu
725         brc     2,2b
726 3:      j       3b
727
728         .section .kprobes.text, "ax"
729
730 #ifdef CONFIG_CHECK_STACK
731 /*
732  * The synchronous or the asynchronous stack overflowed. We are dead.
733  * No need to properly save the registers, we are going to panic anyway.
734  * Setup a pt_regs so that show_trace can provide a good call trace.
735  */
736 stack_overflow:
737         l       %r15,__LC_PANIC_STACK   # change to panic stack
738         ahi     %r15,-__PT_SIZE         # create pt_regs
739         stm     %r0,%r7,__PT_R0(%r15)
740         stm     %r8,%r9,__PT_PSW(%r15)
741         mvc     __PT_R8(32,%r11),0(%r14)
742         lr      %r15,%r11
743         ahi     %r15,-STACK_FRAME_OVERHEAD
744         l       %r1,BASED(1f)
745         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15)
746         lr      %r2,%r11                # pass pointer to pt_regs
747         br      %r1                     # branch to kernel_stack_overflow
748 1:      .long   kernel_stack_overflow
749 #endif
750
751 cleanup_table:
752         .long   system_call + 0x80000000
753         .long   sysc_do_svc + 0x80000000
754         .long   sysc_tif + 0x80000000
755         .long   sysc_restore + 0x80000000
756         .long   sysc_done + 0x80000000
757         .long   io_tif + 0x80000000
758         .long   io_restore + 0x80000000
759         .long   io_done + 0x80000000
760         .long   psw_idle + 0x80000000
761         .long   psw_idle_end + 0x80000000
762
763 cleanup_critical:
764         cl      %r9,BASED(cleanup_table)        # system_call
765         jl      0f
766         cl      %r9,BASED(cleanup_table+4)      # sysc_do_svc
767         jl      cleanup_system_call
768         cl      %r9,BASED(cleanup_table+8)      # sysc_tif
769         jl      0f
770         cl      %r9,BASED(cleanup_table+12)     # sysc_restore
771         jl      cleanup_sysc_tif
772         cl      %r9,BASED(cleanup_table+16)     # sysc_done
773         jl      cleanup_sysc_restore
774         cl      %r9,BASED(cleanup_table+20)     # io_tif
775         jl      0f
776         cl      %r9,BASED(cleanup_table+24)     # io_restore
777         jl      cleanup_io_tif
778         cl      %r9,BASED(cleanup_table+28)     # io_done
779         jl      cleanup_io_restore
780         cl      %r9,BASED(cleanup_table+32)     # psw_idle
781         jl      0f
782         cl      %r9,BASED(cleanup_table+36)     # psw_idle_end
783         jl      cleanup_idle
784 0:      br      %r14
785
786 cleanup_system_call:
787         # check if stpt has been executed
788         cl      %r9,BASED(cleanup_system_call_insn)
789         jh      0f
790         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_ASYNC_ENTER_TIMER
791         chi     %r11,__LC_SAVE_AREA_ASYNC
792         je      0f
793         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_MCCK_ENTER_TIMER
794 0:      # check if stm has been executed
795         cl      %r9,BASED(cleanup_system_call_insn+4)
796         jh      0f
797         mvc     __LC_SAVE_AREA_SYNC(32),0(%r11)
798 0:      # set up saved registers r12, and r13
799         st      %r12,16(%r11)           # r12 thread-info pointer
800         st      %r13,20(%r11)           # r13 literal-pool pointer
801         # check if the user time calculation has been done
802         cl      %r9,BASED(cleanup_system_call_insn+8)
803         jh      0f
804         l       %r10,__LC_EXIT_TIMER
805         l       %r15,__LC_EXIT_TIMER+4
806         SUB64   %r10,%r15,__LC_SYNC_ENTER_TIMER
807         ADD64   %r10,%r15,__LC_USER_TIMER
808         st      %r10,__LC_USER_TIMER
809         st      %r15,__LC_USER_TIMER+4
810 0:      # check if the system time calculation has been done
811         cl      %r9,BASED(cleanup_system_call_insn+12)
812         jh      0f
813         l       %r10,__LC_LAST_UPDATE_TIMER
814         l       %r15,__LC_LAST_UPDATE_TIMER+4
815         SUB64   %r10,%r15,__LC_EXIT_TIMER
816         ADD64   %r10,%r15,__LC_SYSTEM_TIMER
817         st      %r10,__LC_SYSTEM_TIMER
818         st      %r15,__LC_SYSTEM_TIMER+4
819 0:      # update accounting time stamp
820         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
821         # set up saved register 11
822         l       %r15,__LC_KERNEL_STACK
823         ahi     %r15,-__PT_SIZE
824         st      %r15,12(%r11)           # r11 pt_regs pointer
825         # fill pt_regs
826         mvc     __PT_R8(32,%r15),__LC_SAVE_AREA_SYNC
827         stm     %r0,%r7,__PT_R0(%r15)
828         mvc     __PT_PSW(8,%r15),__LC_SVC_OLD_PSW
829         mvc     __PT_INT_CODE(4,%r15),__LC_SVC_ILC
830         # setup saved register 15
831         ahi     %r15,-STACK_FRAME_OVERHEAD
832         st      %r15,28(%r11)           # r15 stack pointer
833         # set new psw address and exit
834         l       %r9,BASED(cleanup_table+4)      # sysc_do_svc + 0x80000000
835         br      %r14
836 cleanup_system_call_insn:
837         .long   system_call + 0x80000000
838         .long   sysc_stm + 0x80000000
839         .long   sysc_vtime + 0x80000000 + 36
840         .long   sysc_vtime + 0x80000000 + 76
841
842 cleanup_sysc_tif:
843         l       %r9,BASED(cleanup_table+8)      # sysc_tif + 0x80000000
844         br      %r14
845
846 cleanup_sysc_restore:
847         cl      %r9,BASED(cleanup_sysc_restore_insn)
848         jhe     0f
849         l       %r9,12(%r11)            # get saved pointer to pt_regs
850         mvc     __LC_RETURN_PSW(8),__PT_PSW(%r9)
851         mvc     0(32,%r11),__PT_R8(%r9)
852         lm      %r0,%r7,__PT_R0(%r9)
853 0:      lm      %r8,%r9,__LC_RETURN_PSW
854         br      %r14
855 cleanup_sysc_restore_insn:
856         .long   sysc_done - 4 + 0x80000000
857
858 cleanup_io_tif:
859         l       %r9,BASED(cleanup_table+20)     # io_tif + 0x80000000
860         br      %r14
861
862 cleanup_io_restore:
863         cl      %r9,BASED(cleanup_io_restore_insn)
864         jhe     0f
865         l       %r9,12(%r11)            # get saved r11 pointer to pt_regs
866         mvc     __LC_RETURN_PSW(8),__PT_PSW(%r9)
867         mvc     0(32,%r11),__PT_R8(%r9)
868         lm      %r0,%r7,__PT_R0(%r9)
869 0:      lm      %r8,%r9,__LC_RETURN_PSW
870         br      %r14
871 cleanup_io_restore_insn:
872         .long   io_done - 4 + 0x80000000
873
874 cleanup_idle:
875         # copy interrupt clock & cpu timer
876         mvc     __CLOCK_IDLE_EXIT(8,%r2),__LC_INT_CLOCK
877         mvc     __TIMER_IDLE_EXIT(8,%r2),__LC_ASYNC_ENTER_TIMER
878         chi     %r11,__LC_SAVE_AREA_ASYNC
879         je      0f
880         mvc     __CLOCK_IDLE_EXIT(8,%r2),__LC_MCCK_CLOCK
881         mvc     __TIMER_IDLE_EXIT(8,%r2),__LC_MCCK_ENTER_TIMER
882 0:      # check if stck has been executed
883         cl      %r9,BASED(cleanup_idle_insn)
884         jhe     1f
885         mvc     __CLOCK_IDLE_ENTER(8,%r2),__CLOCK_IDLE_EXIT(%r2)
886         mvc     __TIMER_IDLE_ENTER(8,%r2),__TIMER_IDLE_EXIT(%r3)
887 1:      # account system time going idle
888         lm      %r9,%r10,__LC_STEAL_TIMER
889         ADD64   %r9,%r10,__CLOCK_IDLE_ENTER(%r2)
890         SUB64   %r9,%r10,__LC_LAST_UPDATE_CLOCK
891         stm     %r9,%r10,__LC_STEAL_TIMER
892         mvc     __LC_LAST_UPDATE_CLOCK(8),__CLOCK_IDLE_EXIT(%r2)
893         lm      %r9,%r10,__LC_SYSTEM_TIMER
894         ADD64   %r9,%r10,__LC_LAST_UPDATE_TIMER
895         SUB64   %r9,%r10,__TIMER_IDLE_ENTER(%r2)
896         stm     %r9,%r10,__LC_SYSTEM_TIMER
897         mvc     __LC_LAST_UPDATE_TIMER(8),__TIMER_IDLE_EXIT(%r2)
898         # prepare return psw
899         n       %r8,BASED(cleanup_idle_wait)    # clear wait state bit
900         l       %r9,24(%r11)                    # return from psw_idle
901         br      %r14
902 cleanup_idle_insn:
903         .long   psw_idle_lpsw + 0x80000000
904 cleanup_idle_wait:
905         .long   0xfffdffff
906
907 /*
908  * Integer constants
909  */
910         .align  4
911 .Lnr_syscalls:
912         .long   NR_syscalls
913 .Lvtimer_max:
914         .quad   0x7fffffffffffffff
915
916 /*
917  * Symbol constants
918  */
919 .Ldo_machine_check:     .long   s390_do_machine_check
920 .Lhandle_mcck:          .long   s390_handle_mcck
921 .Ldo_IRQ:               .long   do_IRQ
922 .Ldo_extint:            .long   do_extint
923 .Ldo_signal:            .long   do_signal
924 .Ldo_notify_resume:     .long   do_notify_resume
925 .Ldo_per_trap:          .long   do_per_trap
926 .Ljump_table:           .long   pgm_check_table
927 .Lschedule:             .long   schedule
928 #ifdef CONFIG_PREEMPT
929 .Lpreempt_irq:          .long   preempt_schedule_irq
930 #endif
931 .Ltrace_enter:          .long   do_syscall_trace_enter
932 .Ltrace_exit:           .long   do_syscall_trace_exit
933 .Lschedule_tail:        .long   schedule_tail
934 .Lsys_call_table:       .long   sys_call_table
935 .Lsysc_per:             .long   sysc_per + 0x80000000
936 #ifdef CONFIG_TRACE_IRQFLAGS
937 .Lhardirqs_on:          .long   trace_hardirqs_on_caller
938 .Lhardirqs_off:         .long   trace_hardirqs_off_caller
939 #endif
940 #ifdef CONFIG_LOCKDEP
941 .Llockdep_sys_exit:     .long   lockdep_sys_exit
942 #endif
943 .Lcritical_start:       .long   __critical_start + 0x80000000
944 .Lcritical_length:      .long   __critical_end - __critical_start
945
946                 .section .rodata, "a"
947 #define SYSCALL(esa,esame,emu)  .long esa
948         .globl  sys_call_table
949 sys_call_table:
950 #include "syscalls.S"
951 #undef SYSCALL