14eec6a9577ebf3758e527224fb7e05e1749083f
[~shefty/rdma-dev.git] / arch / s390 / kernel / entry64.S
1 /*
2  *    S390 low-level entry points.
3  *
4  *    Copyright IBM Corp. 1999, 2012
5  *    Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
6  *               Hartmut Penner (hp@de.ibm.com),
7  *               Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
8  *               Heiko Carstens <heiko.carstens@de.ibm.com>
9  */
10
11 #include <linux/init.h>
12 #include <linux/linkage.h>
13 #include <asm/processor.h>
14 #include <asm/cache.h>
15 #include <asm/errno.h>
16 #include <asm/ptrace.h>
17 #include <asm/thread_info.h>
18 #include <asm/asm-offsets.h>
19 #include <asm/unistd.h>
20 #include <asm/page.h>
21 #include <asm/sigp.h>
22
23 __PT_R0      =  __PT_GPRS
24 __PT_R1      =  __PT_GPRS + 8
25 __PT_R2      =  __PT_GPRS + 16
26 __PT_R3      =  __PT_GPRS + 24
27 __PT_R4      =  __PT_GPRS + 32
28 __PT_R5      =  __PT_GPRS + 40
29 __PT_R6      =  __PT_GPRS + 48
30 __PT_R7      =  __PT_GPRS + 56
31 __PT_R8      =  __PT_GPRS + 64
32 __PT_R9      =  __PT_GPRS + 72
33 __PT_R10     =  __PT_GPRS + 80
34 __PT_R11     =  __PT_GPRS + 88
35 __PT_R12     =  __PT_GPRS + 96
36 __PT_R13     =  __PT_GPRS + 104
37 __PT_R14     =  __PT_GPRS + 112
38 __PT_R15     =  __PT_GPRS + 120
39
40 STACK_SHIFT = PAGE_SHIFT + THREAD_ORDER
41 STACK_SIZE  = 1 << STACK_SHIFT
42
43 _TIF_WORK_SVC = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
44                  _TIF_MCCK_PENDING | _TIF_PER_TRAP )
45 _TIF_WORK_INT = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
46                  _TIF_MCCK_PENDING)
47 _TIF_TRACE    = (_TIF_SYSCALL_TRACE | _TIF_SYSCALL_AUDIT | _TIF_SECCOMP | \
48                  _TIF_SYSCALL_TRACEPOINT)
49 _TIF_EXIT_SIE = (_TIF_SIGPENDING | _TIF_NEED_RESCHED | _TIF_MCCK_PENDING)
50
51 #define BASED(name) name-system_call(%r13)
52
53         .macro  TRACE_IRQS_ON
54 #ifdef CONFIG_TRACE_IRQFLAGS
55         basr    %r2,%r0
56         brasl   %r14,trace_hardirqs_on_caller
57 #endif
58         .endm
59
60         .macro  TRACE_IRQS_OFF
61 #ifdef CONFIG_TRACE_IRQFLAGS
62         basr    %r2,%r0
63         brasl   %r14,trace_hardirqs_off_caller
64 #endif
65         .endm
66
67         .macro  LOCKDEP_SYS_EXIT
68 #ifdef CONFIG_LOCKDEP
69         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
70         jz      .+10
71         brasl   %r14,lockdep_sys_exit
72 #endif
73         .endm
74
75         .macro SPP newpp
76 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
77         tm      __LC_MACHINE_FLAGS+6,0x20       # MACHINE_FLAG_SPP
78         jz      .+8
79         .insn   s,0xb2800000,\newpp
80 #endif
81         .endm
82
83         .macro  HANDLE_SIE_INTERCEPT scratch,pgmcheck
84 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
85         tmhh    %r8,0x0001              # interrupting from user ?
86         jnz     .+42
87         lgr     \scratch,%r9
88         slg     \scratch,BASED(.Lsie_loop)
89         clg     \scratch,BASED(.Lsie_length)
90         .if     \pgmcheck
91         # Some program interrupts are suppressing (e.g. protection).
92         # We must also check the instruction after SIE in that case.
93         # do_protection_exception will rewind to rewind_pad
94         jh      .+22
95         .else
96         jhe     .+22
97         .endif
98         lg      %r9,BASED(.Lsie_loop)
99         SPP     BASED(.Lhost_id)        # set host id
100 #endif
101         .endm
102
103         .macro  CHECK_STACK stacksize,savearea
104 #ifdef CONFIG_CHECK_STACK
105         tml     %r15,\stacksize - CONFIG_STACK_GUARD
106         lghi    %r14,\savearea
107         jz      stack_overflow
108 #endif
109         .endm
110
111         .macro  SWITCH_ASYNC savearea,stack,shift
112         tmhh    %r8,0x0001              # interrupting from user ?
113         jnz     1f
114         lgr     %r14,%r9
115         slg     %r14,BASED(.Lcritical_start)
116         clg     %r14,BASED(.Lcritical_length)
117         jhe     0f
118         lghi    %r11,\savearea          # inside critical section, do cleanup
119         brasl   %r14,cleanup_critical
120         tmhh    %r8,0x0001              # retest problem state after cleanup
121         jnz     1f
122 0:      lg      %r14,\stack             # are we already on the target stack?
123         slgr    %r14,%r15
124         srag    %r14,%r14,\shift
125         jnz     1f
126         CHECK_STACK 1<<\shift,\savearea
127         j       2f
128 1:      lg      %r15,\stack             # load target stack
129 2:      aghi    %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
130         la      %r11,STACK_FRAME_OVERHEAD(%r15)
131         .endm
132
133         .macro UPDATE_VTIME scratch,enter_timer
134         lg      \scratch,__LC_EXIT_TIMER
135         slg     \scratch,\enter_timer
136         alg     \scratch,__LC_USER_TIMER
137         stg     \scratch,__LC_USER_TIMER
138         lg      \scratch,__LC_LAST_UPDATE_TIMER
139         slg     \scratch,__LC_EXIT_TIMER
140         alg     \scratch,__LC_SYSTEM_TIMER
141         stg     \scratch,__LC_SYSTEM_TIMER
142         mvc     __LC_LAST_UPDATE_TIMER(8),\enter_timer
143         .endm
144
145         .macro  LAST_BREAK scratch
146         srag    \scratch,%r10,23
147         jz      .+10
148         stg     %r10,__TI_last_break(%r12)
149         .endm
150
151         .macro REENABLE_IRQS
152         stg     %r8,__LC_RETURN_PSW
153         ni      __LC_RETURN_PSW,0xbf
154         ssm     __LC_RETURN_PSW
155         .endm
156
157         .macro STCK savearea
158 #ifdef CONFIG_HAVE_MARCH_Z9_109_FEATURES
159         .insn   s,0xb27c0000,\savearea          # store clock fast
160 #else
161         .insn   s,0xb2050000,\savearea          # store clock
162 #endif
163         .endm
164
165         .section .kprobes.text, "ax"
166
167 /*
168  * Scheduler resume function, called by switch_to
169  *  gpr2 = (task_struct *) prev
170  *  gpr3 = (task_struct *) next
171  * Returns:
172  *  gpr2 = prev
173  */
174 ENTRY(__switch_to)
175         stmg    %r6,%r15,__SF_GPRS(%r15)        # store gprs of prev task
176         stg     %r15,__THREAD_ksp(%r2)          # store kernel stack of prev
177         lg      %r4,__THREAD_info(%r2)          # get thread_info of prev
178         lg      %r5,__THREAD_info(%r3)          # get thread_info of next
179         lgr     %r15,%r5
180         aghi    %r15,STACK_SIZE                 # end of kernel stack of next
181         stg     %r3,__LC_CURRENT                # store task struct of next
182         stg     %r5,__LC_THREAD_INFO            # store thread info of next
183         stg     %r15,__LC_KERNEL_STACK          # store end of kernel stack
184         lctl    %c4,%c4,__TASK_pid(%r3)         # load pid to control reg. 4
185         mvc     __LC_CURRENT_PID+4(4,%r0),__TASK_pid(%r3) # store pid of next
186         lg      %r15,__THREAD_ksp(%r3)          # load kernel stack of next
187         tm      __TI_flags+7(%r4),_TIF_MCCK_PENDING # machine check pending?
188         jz      0f
189         ni      __TI_flags+7(%r4),255-_TIF_MCCK_PENDING # clear flag in prev
190         oi      __TI_flags+7(%r5),_TIF_MCCK_PENDING     # set it in next
191 0:      lmg     %r6,%r15,__SF_GPRS(%r15)        # load gprs of next task
192         br      %r14
193
194 __critical_start:
195 /*
196  * SVC interrupt handler routine. System calls are synchronous events and
197  * are executed with interrupts enabled.
198  */
199
200 ENTRY(system_call)
201         stpt    __LC_SYNC_ENTER_TIMER
202 sysc_stmg:
203         stmg    %r8,%r15,__LC_SAVE_AREA_SYNC
204         lg      %r10,__LC_LAST_BREAK
205         lg      %r12,__LC_THREAD_INFO
206         larl    %r13,system_call
207 sysc_per:
208         lg      %r15,__LC_KERNEL_STACK
209         aghi    %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
210         la      %r11,STACK_FRAME_OVERHEAD(%r15) # pointer to pt_regs
211 sysc_vtime:
212         UPDATE_VTIME %r13,__LC_SYNC_ENTER_TIMER
213         LAST_BREAK %r13
214         stmg    %r0,%r7,__PT_R0(%r11)
215         mvc     __PT_R8(64,%r11),__LC_SAVE_AREA_SYNC
216         mvc     __PT_PSW(16,%r11),__LC_SVC_OLD_PSW
217         mvc     __PT_INT_CODE(4,%r11),__LC_SVC_ILC
218 sysc_do_svc:
219         oi      __TI_flags+7(%r12),_TIF_SYSCALL
220         llgh    %r8,__PT_INT_CODE+2(%r11)
221         slag    %r8,%r8,2                       # shift and test for svc 0
222         jnz     sysc_nr_ok
223         # svc 0: system call number in %r1
224         llgfr   %r1,%r1                         # clear high word in r1
225         cghi    %r1,NR_syscalls
226         jnl     sysc_nr_ok
227         sth     %r1,__PT_INT_CODE+2(%r11)
228         slag    %r8,%r1,2
229 sysc_nr_ok:
230         larl    %r10,sys_call_table             # 64 bit system call table
231 #ifdef CONFIG_COMPAT
232         tm      __TI_flags+5(%r12),(_TIF_31BIT>>16)
233         jno     sysc_noemu
234         larl    %r10,sys_call_table_emu         # 31 bit system call table
235 sysc_noemu:
236 #endif
237         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
238         stg     %r2,__PT_ORIG_GPR2(%r11)
239         stg     %r7,STACK_FRAME_OVERHEAD(%r15)
240         lgf     %r9,0(%r8,%r10)                 # get system call add.
241         tm      __TI_flags+6(%r12),_TIF_TRACE >> 8
242         jnz     sysc_tracesys
243         basr    %r14,%r9                        # call sys_xxxx
244         stg     %r2,__PT_R2(%r11)               # store return value
245
246 sysc_return:
247         LOCKDEP_SYS_EXIT
248 sysc_tif:
249         tm      __PT_PSW+1(%r11),0x01           # returning to user ?
250         jno     sysc_restore
251         tm      __TI_flags+7(%r12),_TIF_WORK_SVC
252         jnz     sysc_work                       # check for work
253         ni      __TI_flags+7(%r12),255-_TIF_SYSCALL
254 sysc_restore:
255         lg      %r14,__LC_VDSO_PER_CPU
256         lmg     %r0,%r10,__PT_R0(%r11)
257         mvc     __LC_RETURN_PSW(16),__PT_PSW(%r11)
258         stpt    __LC_EXIT_TIMER
259         mvc     __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
260         lmg     %r11,%r15,__PT_R11(%r11)
261         lpswe   __LC_RETURN_PSW
262 sysc_done:
263
264 #
265 # One of the work bits is on. Find out which one.
266 #
267 sysc_work:
268         tm      __TI_flags+7(%r12),_TIF_MCCK_PENDING
269         jo      sysc_mcck_pending
270         tm      __TI_flags+7(%r12),_TIF_NEED_RESCHED
271         jo      sysc_reschedule
272         tm      __TI_flags+7(%r12),_TIF_PER_TRAP
273         jo      sysc_singlestep
274         tm      __TI_flags+7(%r12),_TIF_SIGPENDING
275         jo      sysc_sigpending
276         tm      __TI_flags+7(%r12),_TIF_NOTIFY_RESUME
277         jo      sysc_notify_resume
278         j       sysc_return             # beware of critical section cleanup
279
280 #
281 # _TIF_NEED_RESCHED is set, call schedule
282 #
283 sysc_reschedule:
284         larl    %r14,sysc_return
285         jg      schedule
286
287 #
288 # _TIF_MCCK_PENDING is set, call handler
289 #
290 sysc_mcck_pending:
291         larl    %r14,sysc_return
292         jg      s390_handle_mcck        # TIF bit will be cleared by handler
293
294 #
295 # _TIF_SIGPENDING is set, call do_signal
296 #
297 sysc_sigpending:
298         lgr     %r2,%r11                # pass pointer to pt_regs
299         brasl   %r14,do_signal
300         tm      __TI_flags+7(%r12),_TIF_SYSCALL
301         jno     sysc_return
302         lmg     %r2,%r7,__PT_R2(%r11)   # load svc arguments
303         lghi    %r8,0                   # svc 0 returns -ENOSYS
304         llgh    %r1,__PT_INT_CODE+2(%r11)       # load new svc number
305         cghi    %r1,NR_syscalls
306         jnl     sysc_nr_ok              # invalid svc number -> do svc 0
307         slag    %r8,%r1,2
308         j       sysc_nr_ok              # restart svc
309
310 #
311 # _TIF_NOTIFY_RESUME is set, call do_notify_resume
312 #
313 sysc_notify_resume:
314         lgr     %r2,%r11                # pass pointer to pt_regs
315         larl    %r14,sysc_return
316         jg      do_notify_resume
317
318 #
319 # _TIF_PER_TRAP is set, call do_per_trap
320 #
321 sysc_singlestep:
322         ni      __TI_flags+7(%r12),255-_TIF_PER_TRAP
323         lgr     %r2,%r11                # pass pointer to pt_regs
324         larl    %r14,sysc_return
325         jg      do_per_trap
326
327 #
328 # call tracehook_report_syscall_entry/tracehook_report_syscall_exit before
329 # and after the system call
330 #
331 sysc_tracesys:
332         lgr     %r2,%r11                # pass pointer to pt_regs
333         la      %r3,0
334         llgh    %r0,__PT_INT_CODE+2(%r11)
335         stg     %r0,__PT_R2(%r11)
336         brasl   %r14,do_syscall_trace_enter
337         lghi    %r0,NR_syscalls
338         clgr    %r0,%r2
339         jnh     sysc_tracenogo
340         sllg    %r8,%r2,2
341         lgf     %r9,0(%r8,%r10)
342 sysc_tracego:
343         lmg     %r3,%r7,__PT_R3(%r11)
344         stg     %r7,STACK_FRAME_OVERHEAD(%r15)
345         lg      %r2,__PT_ORIG_GPR2(%r11)
346         basr    %r14,%r9                # call sys_xxx
347         stg     %r2,__PT_R2(%r11)       # store return value
348 sysc_tracenogo:
349         tm      __TI_flags+6(%r12),_TIF_TRACE >> 8
350         jz      sysc_return
351         lgr     %r2,%r11                # pass pointer to pt_regs
352         larl    %r14,sysc_return
353         jg      do_syscall_trace_exit
354
355 #
356 # a new process exits the kernel with ret_from_fork
357 #
358 ENTRY(ret_from_fork)
359         la      %r11,STACK_FRAME_OVERHEAD(%r15)
360         lg      %r12,__LC_THREAD_INFO
361         tm      __PT_PSW+1(%r11),0x01   # forking a kernel thread ?
362         je      1f
363         brasl   %r14,schedule_tail
364         TRACE_IRQS_ON
365         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
366         j       sysc_tracenogo
367 1:      # it's a kernel thread
368         stg     %r15,__PT_R15(%r11)     # store stack pointer for new kthread
369         brasl   %r14,schedule_tail
370         TRACE_IRQS_ON
371         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
372         lmg     %r9,%r11,__PT_R9(%r11)  # load gprs
373 ENTRY(kernel_thread_starter)
374         la      %r2,0(%r10)
375         basr    %r14,%r9
376         la      %r2,0
377         br      %r11                    # do_exit
378
379 ENTRY(ret_from_kernel_execve)
380         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
381         lgr     %r15,%r2
382         lgr     %r11,%r2
383         aghi    %r15,-STACK_FRAME_OVERHEAD
384         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
385         lg      %r12,__LC_THREAD_INFO
386         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
387         j       sysc_return
388
389 /*
390  * Program check handler routine
391  */
392
393 ENTRY(pgm_check_handler)
394         stpt    __LC_SYNC_ENTER_TIMER
395         stmg    %r8,%r15,__LC_SAVE_AREA_SYNC
396         lg      %r10,__LC_LAST_BREAK
397         lg      %r12,__LC_THREAD_INFO
398         larl    %r13,system_call
399         lmg     %r8,%r9,__LC_PGM_OLD_PSW
400         HANDLE_SIE_INTERCEPT %r14,1
401         tmhh    %r8,0x0001              # test problem state bit
402         jnz     1f                      # -> fault in user space
403         tmhh    %r8,0x4000              # PER bit set in old PSW ?
404         jnz     0f                      # -> enabled, can't be a double fault
405         tm      __LC_PGM_ILC+3,0x80     # check for per exception
406         jnz     pgm_svcper              # -> single stepped svc
407 0:      CHECK_STACK STACK_SIZE,__LC_SAVE_AREA_SYNC
408         j       2f
409 1:      UPDATE_VTIME %r14,__LC_SYNC_ENTER_TIMER
410         LAST_BREAK %r14
411         lg      %r15,__LC_KERNEL_STACK
412         lg      %r14,__TI_task(%r12)
413         lghi    %r13,__LC_PGM_TDB
414         tm      __LC_PGM_ILC+2,0x02     # check for transaction abort
415         jz      2f
416         mvc     __THREAD_trap_tdb(256,%r14),0(%r13)
417 2:      aghi    %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
418         la      %r11,STACK_FRAME_OVERHEAD(%r15)
419         stmg    %r0,%r7,__PT_R0(%r11)
420         mvc     __PT_R8(64,%r11),__LC_SAVE_AREA_SYNC
421         stmg    %r8,%r9,__PT_PSW(%r11)
422         mvc     __PT_INT_CODE(4,%r11),__LC_PGM_ILC
423         mvc     __PT_INT_PARM_LONG(8,%r11),__LC_TRANS_EXC_CODE
424         stg     %r10,__PT_ARGS(%r11)
425         tm      __LC_PGM_ILC+3,0x80     # check for per exception
426         jz      0f
427         tmhh    %r8,0x0001              # kernel per event ?
428         jz      pgm_kprobe
429         oi      __TI_flags+7(%r12),_TIF_PER_TRAP
430         mvc     __THREAD_per_address(8,%r14),__LC_PER_ADDRESS
431         mvc     __THREAD_per_cause(2,%r14),__LC_PER_CAUSE
432         mvc     __THREAD_per_paid(1,%r14),__LC_PER_PAID
433 0:      REENABLE_IRQS
434         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
435         larl    %r1,pgm_check_table
436         llgh    %r10,__PT_INT_CODE+2(%r11)
437         nill    %r10,0x007f
438         sll     %r10,2
439         je      sysc_return
440         lgf     %r1,0(%r10,%r1)         # load address of handler routine
441         lgr     %r2,%r11                # pass pointer to pt_regs
442         basr    %r14,%r1                # branch to interrupt-handler
443         j       sysc_return
444
445 #
446 # PER event in supervisor state, must be kprobes
447 #
448 pgm_kprobe:
449         REENABLE_IRQS
450         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
451         lgr     %r2,%r11                # pass pointer to pt_regs
452         brasl   %r14,do_per_trap
453         j       sysc_return
454
455 #
456 # single stepped system call
457 #
458 pgm_svcper:
459         oi      __TI_flags+7(%r12),_TIF_PER_TRAP
460         mvc     __LC_RETURN_PSW(8),__LC_SVC_NEW_PSW
461         larl    %r14,sysc_per
462         stg     %r14,__LC_RETURN_PSW+8
463         lpswe   __LC_RETURN_PSW         # branch to sysc_per and enable irqs
464
465 /*
466  * IO interrupt handler routine
467  */
468 ENTRY(io_int_handler)
469         STCK    __LC_INT_CLOCK
470         stpt    __LC_ASYNC_ENTER_TIMER
471         stmg    %r8,%r15,__LC_SAVE_AREA_ASYNC
472         lg      %r10,__LC_LAST_BREAK
473         lg      %r12,__LC_THREAD_INFO
474         larl    %r13,system_call
475         lmg     %r8,%r9,__LC_IO_OLD_PSW
476         HANDLE_SIE_INTERCEPT %r14,0
477         SWITCH_ASYNC __LC_SAVE_AREA_ASYNC,__LC_ASYNC_STACK,STACK_SHIFT
478         tmhh    %r8,0x0001              # interrupting from user?
479         jz      io_skip
480         UPDATE_VTIME %r14,__LC_ASYNC_ENTER_TIMER
481         LAST_BREAK %r14
482 io_skip:
483         stmg    %r0,%r7,__PT_R0(%r11)
484         mvc     __PT_R8(64,%r11),__LC_SAVE_AREA_ASYNC
485         stmg    %r8,%r9,__PT_PSW(%r11)
486         TRACE_IRQS_OFF
487         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
488         lgr     %r2,%r11                # pass pointer to pt_regs
489         brasl   %r14,do_IRQ
490 io_return:
491         LOCKDEP_SYS_EXIT
492         TRACE_IRQS_ON
493 io_tif:
494         tm      __TI_flags+7(%r12),_TIF_WORK_INT
495         jnz     io_work                 # there is work to do (signals etc.)
496 io_restore:
497         lg      %r14,__LC_VDSO_PER_CPU
498         lmg     %r0,%r10,__PT_R0(%r11)
499         mvc     __LC_RETURN_PSW(16),__PT_PSW(%r11)
500         stpt    __LC_EXIT_TIMER
501         mvc     __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
502         lmg     %r11,%r15,__PT_R11(%r11)
503         lpswe   __LC_RETURN_PSW
504 io_done:
505
506 #
507 # There is work todo, find out in which context we have been interrupted:
508 # 1) if we return to user space we can do all _TIF_WORK_INT work
509 # 2) if we return to kernel code and kvm is enabled check if we need to
510 #    modify the psw to leave SIE
511 # 3) if we return to kernel code and preemptive scheduling is enabled check
512 #    the preemption counter and if it is zero call preempt_schedule_irq
513 # Before any work can be done, a switch to the kernel stack is required.
514 #
515 io_work:
516         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
517         jo      io_work_user            # yes -> do resched & signal
518 #ifdef CONFIG_PREEMPT
519         # check for preemptive scheduling
520         icm     %r0,15,__TI_precount(%r12)
521         jnz     io_restore              # preemption is disabled
522         tm      __TI_flags+7(%r12),_TIF_NEED_RESCHED
523         jno     io_restore
524         # switch to kernel stack
525         lg      %r1,__PT_R15(%r11)
526         aghi    %r1,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
527         mvc     STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
528         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
529         la      %r11,STACK_FRAME_OVERHEAD(%r1)
530         lgr     %r15,%r1
531         # TRACE_IRQS_ON already done at io_return, call
532         # TRACE_IRQS_OFF to keep things symmetrical
533         TRACE_IRQS_OFF
534         brasl   %r14,preempt_schedule_irq
535         j       io_return
536 #else
537         j       io_restore
538 #endif
539
540 #
541 # Need to do work before returning to userspace, switch to kernel stack
542 #
543 io_work_user:
544         lg      %r1,__LC_KERNEL_STACK
545         aghi    %r1,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
546         mvc     STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
547         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
548         la      %r11,STACK_FRAME_OVERHEAD(%r1)
549         lgr     %r15,%r1
550
551 #
552 # One of the work bits is on. Find out which one.
553 # Checked are: _TIF_SIGPENDING, _TIF_NOTIFY_RESUME, _TIF_NEED_RESCHED
554 #              and _TIF_MCCK_PENDING
555 #
556 io_work_tif:
557         tm      __TI_flags+7(%r12),_TIF_MCCK_PENDING
558         jo      io_mcck_pending
559         tm      __TI_flags+7(%r12),_TIF_NEED_RESCHED
560         jo      io_reschedule
561         tm      __TI_flags+7(%r12),_TIF_SIGPENDING
562         jo      io_sigpending
563         tm      __TI_flags+7(%r12),_TIF_NOTIFY_RESUME
564         jo      io_notify_resume
565         j       io_return               # beware of critical section cleanup
566
567 #
568 # _TIF_MCCK_PENDING is set, call handler
569 #
570 io_mcck_pending:
571         # TRACE_IRQS_ON already done at io_return
572         brasl   %r14,s390_handle_mcck   # TIF bit will be cleared by handler
573         TRACE_IRQS_OFF
574         j       io_return
575
576 #
577 # _TIF_NEED_RESCHED is set, call schedule
578 #
579 io_reschedule:
580         # TRACE_IRQS_ON already done at io_return
581         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
582         brasl   %r14,schedule           # call scheduler
583         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
584         TRACE_IRQS_OFF
585         j       io_return
586
587 #
588 # _TIF_SIGPENDING or is set, call do_signal
589 #
590 io_sigpending:
591         # TRACE_IRQS_ON already done at io_return
592         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
593         lgr     %r2,%r11                # pass pointer to pt_regs
594         brasl   %r14,do_signal
595         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
596         TRACE_IRQS_OFF
597         j       io_return
598
599 #
600 # _TIF_NOTIFY_RESUME or is set, call do_notify_resume
601 #
602 io_notify_resume:
603         # TRACE_IRQS_ON already done at io_return
604         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
605         lgr     %r2,%r11                # pass pointer to pt_regs
606         brasl   %r14,do_notify_resume
607         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
608         TRACE_IRQS_OFF
609         j       io_return
610
611 /*
612  * External interrupt handler routine
613  */
614 ENTRY(ext_int_handler)
615         STCK    __LC_INT_CLOCK
616         stpt    __LC_ASYNC_ENTER_TIMER
617         stmg    %r8,%r15,__LC_SAVE_AREA_ASYNC
618         lg      %r10,__LC_LAST_BREAK
619         lg      %r12,__LC_THREAD_INFO
620         larl    %r13,system_call
621         lmg     %r8,%r9,__LC_EXT_OLD_PSW
622         HANDLE_SIE_INTERCEPT %r14,0
623         SWITCH_ASYNC __LC_SAVE_AREA_ASYNC,__LC_ASYNC_STACK,STACK_SHIFT
624         tmhh    %r8,0x0001              # interrupting from user ?
625         jz      ext_skip
626         UPDATE_VTIME %r14,__LC_ASYNC_ENTER_TIMER
627         LAST_BREAK %r14
628 ext_skip:
629         stmg    %r0,%r7,__PT_R0(%r11)
630         mvc     __PT_R8(64,%r11),__LC_SAVE_AREA_ASYNC
631         stmg    %r8,%r9,__PT_PSW(%r11)
632         TRACE_IRQS_OFF
633         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
634         lghi    %r1,4096
635         lgr     %r2,%r11                # pass pointer to pt_regs
636         llgf    %r3,__LC_EXT_CPU_ADDR   # get cpu address + interruption code
637         llgf    %r4,__LC_EXT_PARAMS     # get external parameter
638         lg      %r5,__LC_EXT_PARAMS2-4096(%r1)  # get 64 bit external parameter
639         brasl   %r14,do_extint
640         j       io_return
641
642 /*
643  * Load idle PSW. The second "half" of this function is in cleanup_idle.
644  */
645 ENTRY(psw_idle)
646         stg     %r3,__SF_EMPTY(%r15)
647         larl    %r1,psw_idle_lpsw+4
648         stg     %r1,__SF_EMPTY+8(%r15)
649         STCK    __CLOCK_IDLE_ENTER(%r2)
650         stpt    __TIMER_IDLE_ENTER(%r2)
651 psw_idle_lpsw:
652         lpswe   __SF_EMPTY(%r15)
653         br      %r14
654 psw_idle_end:
655
656 __critical_end:
657
658 /*
659  * Machine check handler routines
660  */
661 ENTRY(mcck_int_handler)
662         STCK    __LC_MCCK_CLOCK
663         la      %r1,4095                # revalidate r1
664         spt     __LC_CPU_TIMER_SAVE_AREA-4095(%r1)      # revalidate cpu timer
665         lmg     %r0,%r15,__LC_GPREGS_SAVE_AREA-4095(%r1)# revalidate gprs
666         lg      %r10,__LC_LAST_BREAK
667         lg      %r12,__LC_THREAD_INFO
668         larl    %r13,system_call
669         lmg     %r8,%r9,__LC_MCK_OLD_PSW
670         HANDLE_SIE_INTERCEPT %r14,0
671         tm      __LC_MCCK_CODE,0x80     # system damage?
672         jo      mcck_panic              # yes -> rest of mcck code invalid
673         lghi    %r14,__LC_CPU_TIMER_SAVE_AREA
674         mvc     __LC_MCCK_ENTER_TIMER(8),0(%r14)
675         tm      __LC_MCCK_CODE+5,0x02   # stored cpu timer value valid?
676         jo      3f
677         la      %r14,__LC_SYNC_ENTER_TIMER
678         clc     0(8,%r14),__LC_ASYNC_ENTER_TIMER
679         jl      0f
680         la      %r14,__LC_ASYNC_ENTER_TIMER
681 0:      clc     0(8,%r14),__LC_EXIT_TIMER
682         jl      1f
683         la      %r14,__LC_EXIT_TIMER
684 1:      clc     0(8,%r14),__LC_LAST_UPDATE_TIMER
685         jl      2f
686         la      %r14,__LC_LAST_UPDATE_TIMER
687 2:      spt     0(%r14)
688         mvc     __LC_MCCK_ENTER_TIMER(8),0(%r14)
689 3:      tm      __LC_MCCK_CODE+2,0x09   # mwp + ia of old psw valid?
690         jno     mcck_panic              # no -> skip cleanup critical
691         SWITCH_ASYNC __LC_GPREGS_SAVE_AREA+64,__LC_PANIC_STACK,PAGE_SHIFT
692         tm      %r8,0x0001              # interrupting from user ?
693         jz      mcck_skip
694         UPDATE_VTIME %r14,__LC_MCCK_ENTER_TIMER
695         LAST_BREAK %r14
696 mcck_skip:
697         lghi    %r14,__LC_GPREGS_SAVE_AREA
698         mvc     __PT_R0(128,%r11),0(%r14)
699         stmg    %r8,%r9,__PT_PSW(%r11)
700         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
701         lgr     %r2,%r11                # pass pointer to pt_regs
702         brasl   %r14,s390_do_machine_check
703         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
704         jno     mcck_return
705         lg      %r1,__LC_KERNEL_STACK   # switch to kernel stack
706         aghi    %r1,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
707         mvc     STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
708         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
709         la      %r11,STACK_FRAME_OVERHEAD(%r1)
710         lgr     %r15,%r1
711         ssm     __LC_PGM_NEW_PSW        # turn dat on, keep irqs off
712         tm      __TI_flags+7(%r12),_TIF_MCCK_PENDING
713         jno     mcck_return
714         TRACE_IRQS_OFF
715         brasl   %r14,s390_handle_mcck
716         TRACE_IRQS_ON
717 mcck_return:
718         lg      %r14,__LC_VDSO_PER_CPU
719         lmg     %r0,%r10,__PT_R0(%r11)
720         mvc     __LC_RETURN_MCCK_PSW(16),__PT_PSW(%r11) # move return PSW
721         tm      __LC_RETURN_MCCK_PSW+1,0x01 # returning to user ?
722         jno     0f
723         stpt    __LC_EXIT_TIMER
724         mvc     __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
725 0:      lmg     %r11,%r15,__PT_R11(%r11)
726         lpswe   __LC_RETURN_MCCK_PSW
727
728 mcck_panic:
729         lg      %r14,__LC_PANIC_STACK
730         slgr    %r14,%r15
731         srag    %r14,%r14,PAGE_SHIFT
732         jz      0f
733         lg      %r15,__LC_PANIC_STACK
734 0:      aghi    %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
735         j       mcck_skip
736
737 #
738 # PSW restart interrupt handler
739 #
740 ENTRY(restart_int_handler)
741         stg     %r15,__LC_SAVE_AREA_RESTART
742         lg      %r15,__LC_RESTART_STACK
743         aghi    %r15,-__PT_SIZE                 # create pt_regs on stack
744         xc      0(__PT_SIZE,%r15),0(%r15)
745         stmg    %r0,%r14,__PT_R0(%r15)
746         mvc     __PT_R15(8,%r15),__LC_SAVE_AREA_RESTART
747         mvc     __PT_PSW(16,%r15),__LC_RST_OLD_PSW # store restart old psw
748         aghi    %r15,-STACK_FRAME_OVERHEAD      # create stack frame on stack
749         xc      0(STACK_FRAME_OVERHEAD,%r15),0(%r15)
750         lg      %r1,__LC_RESTART_FN             # load fn, parm & source cpu
751         lg      %r2,__LC_RESTART_DATA
752         lg      %r3,__LC_RESTART_SOURCE
753         ltgr    %r3,%r3                         # test source cpu address
754         jm      1f                              # negative -> skip source stop
755 0:      sigp    %r4,%r3,SIGP_SENSE              # sigp sense to source cpu
756         brc     10,0b                           # wait for status stored
757 1:      basr    %r14,%r1                        # call function
758         stap    __SF_EMPTY(%r15)                # store cpu address
759         llgh    %r3,__SF_EMPTY(%r15)
760 2:      sigp    %r4,%r3,SIGP_STOP               # sigp stop to current cpu
761         brc     2,2b
762 3:      j       3b
763
764         .section .kprobes.text, "ax"
765
766 #ifdef CONFIG_CHECK_STACK
767 /*
768  * The synchronous or the asynchronous stack overflowed. We are dead.
769  * No need to properly save the registers, we are going to panic anyway.
770  * Setup a pt_regs so that show_trace can provide a good call trace.
771  */
772 stack_overflow:
773         lg      %r11,__LC_PANIC_STACK   # change to panic stack
774         aghi    %r11,-__PT_SIZE         # create pt_regs
775         stmg    %r0,%r7,__PT_R0(%r11)
776         stmg    %r8,%r9,__PT_PSW(%r11)
777         mvc     __PT_R8(64,%r11),0(%r14)
778         stg     %r10,__PT_ORIG_GPR2(%r11) # store last break to orig_gpr2
779         lgr     %r15,%r11
780         aghi    %r15,-STACK_FRAME_OVERHEAD
781         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
782         lgr     %r2,%r11                # pass pointer to pt_regs
783         jg      kernel_stack_overflow
784 #endif
785
786         .align  8
787 cleanup_table:
788         .quad   system_call
789         .quad   sysc_do_svc
790         .quad   sysc_tif
791         .quad   sysc_restore
792         .quad   sysc_done
793         .quad   io_tif
794         .quad   io_restore
795         .quad   io_done
796         .quad   psw_idle
797         .quad   psw_idle_end
798
799 cleanup_critical:
800         clg     %r9,BASED(cleanup_table)        # system_call
801         jl      0f
802         clg     %r9,BASED(cleanup_table+8)      # sysc_do_svc
803         jl      cleanup_system_call
804         clg     %r9,BASED(cleanup_table+16)     # sysc_tif
805         jl      0f
806         clg     %r9,BASED(cleanup_table+24)     # sysc_restore
807         jl      cleanup_sysc_tif
808         clg     %r9,BASED(cleanup_table+32)     # sysc_done
809         jl      cleanup_sysc_restore
810         clg     %r9,BASED(cleanup_table+40)     # io_tif
811         jl      0f
812         clg     %r9,BASED(cleanup_table+48)     # io_restore
813         jl      cleanup_io_tif
814         clg     %r9,BASED(cleanup_table+56)     # io_done
815         jl      cleanup_io_restore
816         clg     %r9,BASED(cleanup_table+64)     # psw_idle
817         jl      0f
818         clg     %r9,BASED(cleanup_table+72)     # psw_idle_end
819         jl      cleanup_idle
820 0:      br      %r14
821
822
823 cleanup_system_call:
824         # check if stpt has been executed
825         clg     %r9,BASED(cleanup_system_call_insn)
826         jh      0f
827         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_ASYNC_ENTER_TIMER
828         cghi    %r11,__LC_SAVE_AREA_ASYNC
829         je      0f
830         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_MCCK_ENTER_TIMER
831 0:      # check if stmg has been executed
832         clg     %r9,BASED(cleanup_system_call_insn+8)
833         jh      0f
834         mvc     __LC_SAVE_AREA_SYNC(64),0(%r11)
835 0:      # check if base register setup + TIF bit load has been done
836         clg     %r9,BASED(cleanup_system_call_insn+16)
837         jhe     0f
838         # set up saved registers r10 and r12
839         stg     %r10,16(%r11)           # r10 last break
840         stg     %r12,32(%r11)           # r12 thread-info pointer
841 0:      # check if the user time update has been done
842         clg     %r9,BASED(cleanup_system_call_insn+24)
843         jh      0f
844         lg      %r15,__LC_EXIT_TIMER
845         slg     %r15,__LC_SYNC_ENTER_TIMER
846         alg     %r15,__LC_USER_TIMER
847         stg     %r15,__LC_USER_TIMER
848 0:      # check if the system time update has been done
849         clg     %r9,BASED(cleanup_system_call_insn+32)
850         jh      0f
851         lg      %r15,__LC_LAST_UPDATE_TIMER
852         slg     %r15,__LC_EXIT_TIMER
853         alg     %r15,__LC_SYSTEM_TIMER
854         stg     %r15,__LC_SYSTEM_TIMER
855 0:      # update accounting time stamp
856         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
857         # do LAST_BREAK
858         lg      %r9,16(%r11)
859         srag    %r9,%r9,23
860         jz      0f
861         mvc     __TI_last_break(8,%r12),16(%r11)
862 0:      # set up saved register r11
863         lg      %r15,__LC_KERNEL_STACK
864         aghi    %r15,-__PT_SIZE
865         stg     %r15,24(%r11)           # r11 pt_regs pointer
866         # fill pt_regs
867         mvc     __PT_R8(64,%r15),__LC_SAVE_AREA_SYNC
868         stmg    %r0,%r7,__PT_R0(%r15)
869         mvc     __PT_PSW(16,%r15),__LC_SVC_OLD_PSW
870         mvc     __PT_INT_CODE(4,%r15),__LC_SVC_ILC
871         # setup saved register r15
872         aghi    %r15,-STACK_FRAME_OVERHEAD
873         stg     %r15,56(%r11)           # r15 stack pointer
874         # set new psw address and exit
875         larl    %r9,sysc_do_svc
876         br      %r14
877 cleanup_system_call_insn:
878         .quad   system_call
879         .quad   sysc_stmg
880         .quad   sysc_per
881         .quad   sysc_vtime+18
882         .quad   sysc_vtime+42
883
884 cleanup_sysc_tif:
885         larl    %r9,sysc_tif
886         br      %r14
887
888 cleanup_sysc_restore:
889         clg     %r9,BASED(cleanup_sysc_restore_insn)
890         je      0f
891         lg      %r9,24(%r11)            # get saved pointer to pt_regs
892         mvc     __LC_RETURN_PSW(16),__PT_PSW(%r9)
893         mvc     0(64,%r11),__PT_R8(%r9)
894         lmg     %r0,%r7,__PT_R0(%r9)
895 0:      lmg     %r8,%r9,__LC_RETURN_PSW
896         br      %r14
897 cleanup_sysc_restore_insn:
898         .quad   sysc_done - 4
899
900 cleanup_io_tif:
901         larl    %r9,io_tif
902         br      %r14
903
904 cleanup_io_restore:
905         clg     %r9,BASED(cleanup_io_restore_insn)
906         je      0f
907         lg      %r9,24(%r11)            # get saved r11 pointer to pt_regs
908         mvc     __LC_RETURN_PSW(16),__PT_PSW(%r9)
909         mvc     0(64,%r11),__PT_R8(%r9)
910         lmg     %r0,%r7,__PT_R0(%r9)
911 0:      lmg     %r8,%r9,__LC_RETURN_PSW
912         br      %r14
913 cleanup_io_restore_insn:
914         .quad   io_done - 4
915
916 cleanup_idle:
917         # copy interrupt clock & cpu timer
918         mvc     __CLOCK_IDLE_EXIT(8,%r2),__LC_INT_CLOCK
919         mvc     __TIMER_IDLE_EXIT(8,%r2),__LC_ASYNC_ENTER_TIMER
920         cghi    %r11,__LC_SAVE_AREA_ASYNC
921         je      0f
922         mvc     __CLOCK_IDLE_EXIT(8,%r2),__LC_MCCK_CLOCK
923         mvc     __TIMER_IDLE_EXIT(8,%r2),__LC_MCCK_ENTER_TIMER
924 0:      # check if stck & stpt have been executed
925         clg     %r9,BASED(cleanup_idle_insn)
926         jhe     1f
927         mvc     __CLOCK_IDLE_ENTER(8,%r2),__CLOCK_IDLE_EXIT(%r2)
928         mvc     __TIMER_IDLE_ENTER(8,%r2),__TIMER_IDLE_EXIT(%r2)
929 1:      # account system time going idle
930         lg      %r9,__LC_STEAL_TIMER
931         alg     %r9,__CLOCK_IDLE_ENTER(%r2)
932         slg     %r9,__LC_LAST_UPDATE_CLOCK
933         stg     %r9,__LC_STEAL_TIMER
934         mvc     __LC_LAST_UPDATE_CLOCK(8),__CLOCK_IDLE_EXIT(%r2)
935         lg      %r9,__LC_SYSTEM_TIMER
936         alg     %r9,__LC_LAST_UPDATE_TIMER
937         slg     %r9,__TIMER_IDLE_ENTER(%r2)
938         stg     %r9,__LC_SYSTEM_TIMER
939         mvc     __LC_LAST_UPDATE_TIMER(8),__TIMER_IDLE_EXIT(%r2)
940         # prepare return psw
941         nihh    %r8,0xfffd              # clear wait state bit
942         lg      %r9,48(%r11)            # return from psw_idle
943         br      %r14
944 cleanup_idle_insn:
945         .quad   psw_idle_lpsw
946
947 /*
948  * Integer constants
949  */
950         .align  8
951 .Lcritical_start:
952         .quad   __critical_start
953 .Lcritical_length:
954         .quad   __critical_end - __critical_start
955
956
957 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
958 /*
959  * sie64a calling convention:
960  * %r2 pointer to sie control block
961  * %r3 guest register save area
962  */
963 ENTRY(sie64a)
964         stmg    %r6,%r14,__SF_GPRS(%r15)        # save kernel registers
965         stg     %r2,__SF_EMPTY(%r15)            # save control block pointer
966         stg     %r3,__SF_EMPTY+8(%r15)          # save guest register save area
967         xc      __SF_EMPTY+16(8,%r15),__SF_EMPTY+16(%r15) # host id == 0
968         lmg     %r0,%r13,0(%r3)                 # load guest gprs 0-13
969 # some program checks are suppressing. C code (e.g. do_protection_exception)
970 # will rewind the PSW by the ILC, which is 4 bytes in case of SIE. Other
971 # instructions in the sie_loop should not cause program interrupts. So
972 # lets use a nop (47 00 00 00) as a landing pad.
973 # See also HANDLE_SIE_INTERCEPT
974 rewind_pad:
975         nop     0
976 sie_loop:
977         lg      %r14,__LC_THREAD_INFO           # pointer thread_info struct
978         tm      __TI_flags+7(%r14),_TIF_EXIT_SIE
979         jnz     sie_exit
980         lg      %r14,__LC_GMAP                  # get gmap pointer
981         ltgr    %r14,%r14
982         jz      sie_gmap
983         lctlg   %c1,%c1,__GMAP_ASCE(%r14)       # load primary asce
984 sie_gmap:
985         lg      %r14,__SF_EMPTY(%r15)           # get control block pointer
986         SPP     __SF_EMPTY(%r15)                # set guest id
987         sie     0(%r14)
988 sie_done:
989         SPP     __SF_EMPTY+16(%r15)             # set host id
990         lg      %r14,__LC_THREAD_INFO           # pointer thread_info struct
991 sie_exit:
992         lctlg   %c1,%c1,__LC_USER_ASCE          # load primary asce
993         lg      %r14,__SF_EMPTY+8(%r15)         # load guest register save area
994         stmg    %r0,%r13,0(%r14)                # save guest gprs 0-13
995         lmg     %r6,%r14,__SF_GPRS(%r15)        # restore kernel registers
996         lghi    %r2,0
997         br      %r14
998 sie_fault:
999         lctlg   %c1,%c1,__LC_USER_ASCE          # load primary asce
1000         lg      %r14,__LC_THREAD_INFO           # pointer thread_info struct
1001         lg      %r14,__SF_EMPTY+8(%r15)         # load guest register save area
1002         stmg    %r0,%r13,0(%r14)                # save guest gprs 0-13
1003         lmg     %r6,%r14,__SF_GPRS(%r15)        # restore kernel registers
1004         lghi    %r2,-EFAULT
1005         br      %r14
1006
1007         .align  8
1008 .Lsie_loop:
1009         .quad   sie_loop
1010 .Lsie_length:
1011         .quad   sie_done - sie_loop
1012 .Lhost_id:
1013         .quad   0
1014
1015         EX_TABLE(rewind_pad,sie_fault)
1016         EX_TABLE(sie_loop,sie_fault)
1017 #endif
1018
1019                 .section .rodata, "a"
1020 #define SYSCALL(esa,esame,emu)  .long esame
1021         .globl  sys_call_table
1022 sys_call_table:
1023 #include "syscalls.S"
1024 #undef SYSCALL
1025
1026 #ifdef CONFIG_COMPAT
1027
1028 #define SYSCALL(esa,esame,emu)  .long emu
1029 sys_call_table_emu:
1030 #include "syscalls.S"
1031 #undef SYSCALL
1032 #endif