499e95e90f38d9d785609a3c0ed2d1e41a5c8f15
[~shefty/rdma-dev.git] / arch / s390 / kernel / entry64.S
1 /*
2  *    S390 low-level entry points.
3  *
4  *    Copyright IBM Corp. 1999, 2012
5  *    Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
6  *               Hartmut Penner (hp@de.ibm.com),
7  *               Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
8  *               Heiko Carstens <heiko.carstens@de.ibm.com>
9  */
10
11 #include <linux/init.h>
12 #include <linux/linkage.h>
13 #include <asm/processor.h>
14 #include <asm/cache.h>
15 #include <asm/errno.h>
16 #include <asm/ptrace.h>
17 #include <asm/thread_info.h>
18 #include <asm/asm-offsets.h>
19 #include <asm/unistd.h>
20 #include <asm/page.h>
21 #include <asm/sigp.h>
22
23 __PT_R0      =  __PT_GPRS
24 __PT_R1      =  __PT_GPRS + 8
25 __PT_R2      =  __PT_GPRS + 16
26 __PT_R3      =  __PT_GPRS + 24
27 __PT_R4      =  __PT_GPRS + 32
28 __PT_R5      =  __PT_GPRS + 40
29 __PT_R6      =  __PT_GPRS + 48
30 __PT_R7      =  __PT_GPRS + 56
31 __PT_R8      =  __PT_GPRS + 64
32 __PT_R9      =  __PT_GPRS + 72
33 __PT_R10     =  __PT_GPRS + 80
34 __PT_R11     =  __PT_GPRS + 88
35 __PT_R12     =  __PT_GPRS + 96
36 __PT_R13     =  __PT_GPRS + 104
37 __PT_R14     =  __PT_GPRS + 112
38 __PT_R15     =  __PT_GPRS + 120
39
40 STACK_SHIFT = PAGE_SHIFT + THREAD_ORDER
41 STACK_SIZE  = 1 << STACK_SHIFT
42
43 _TIF_WORK_SVC = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
44                  _TIF_MCCK_PENDING | _TIF_PER_TRAP )
45 _TIF_WORK_INT = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
46                  _TIF_MCCK_PENDING)
47 _TIF_TRACE    = (_TIF_SYSCALL_TRACE | _TIF_SYSCALL_AUDIT | _TIF_SECCOMP | \
48                  _TIF_SYSCALL_TRACEPOINT)
49 _TIF_EXIT_SIE = (_TIF_SIGPENDING | _TIF_NEED_RESCHED | _TIF_MCCK_PENDING)
50
51 #define BASED(name) name-system_call(%r13)
52
53         .macro  TRACE_IRQS_ON
54 #ifdef CONFIG_TRACE_IRQFLAGS
55         basr    %r2,%r0
56         brasl   %r14,trace_hardirqs_on_caller
57 #endif
58         .endm
59
60         .macro  TRACE_IRQS_OFF
61 #ifdef CONFIG_TRACE_IRQFLAGS
62         basr    %r2,%r0
63         brasl   %r14,trace_hardirqs_off_caller
64 #endif
65         .endm
66
67         .macro  LOCKDEP_SYS_EXIT
68 #ifdef CONFIG_LOCKDEP
69         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
70         jz      .+10
71         brasl   %r14,lockdep_sys_exit
72 #endif
73         .endm
74
75         .macro SPP newpp
76 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
77         tm      __LC_MACHINE_FLAGS+6,0x20       # MACHINE_FLAG_SPP
78         jz      .+8
79         .insn   s,0xb2800000,\newpp
80 #endif
81         .endm
82
83         .macro  HANDLE_SIE_INTERCEPT scratch
84 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
85         tmhh    %r8,0x0001              # interrupting from user ?
86         jnz     .+42
87         lgr     \scratch,%r9
88         slg     \scratch,BASED(.Lsie_loop)
89         clg     \scratch,BASED(.Lsie_length)
90         jhe     .+22
91         lg      %r9,BASED(.Lsie_loop)
92         SPP     BASED(.Lhost_id)        # set host id
93 #endif
94         .endm
95
96         .macro  CHECK_STACK stacksize,savearea
97 #ifdef CONFIG_CHECK_STACK
98         tml     %r15,\stacksize - CONFIG_STACK_GUARD
99         lghi    %r14,\savearea
100         jz      stack_overflow
101 #endif
102         .endm
103
104         .macro  SWITCH_ASYNC savearea,stack,shift
105         tmhh    %r8,0x0001              # interrupting from user ?
106         jnz     1f
107         lgr     %r14,%r9
108         slg     %r14,BASED(.Lcritical_start)
109         clg     %r14,BASED(.Lcritical_length)
110         jhe     0f
111         lghi    %r11,\savearea          # inside critical section, do cleanup
112         brasl   %r14,cleanup_critical
113         tmhh    %r8,0x0001              # retest problem state after cleanup
114         jnz     1f
115 0:      lg      %r14,\stack             # are we already on the target stack?
116         slgr    %r14,%r15
117         srag    %r14,%r14,\shift
118         jnz     1f
119         CHECK_STACK 1<<\shift,\savearea
120         j       2f
121 1:      lg      %r15,\stack             # load target stack
122 2:      aghi    %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
123         la      %r11,STACK_FRAME_OVERHEAD(%r15)
124         .endm
125
126         .macro UPDATE_VTIME scratch,enter_timer
127         lg      \scratch,__LC_EXIT_TIMER
128         slg     \scratch,\enter_timer
129         alg     \scratch,__LC_USER_TIMER
130         stg     \scratch,__LC_USER_TIMER
131         lg      \scratch,__LC_LAST_UPDATE_TIMER
132         slg     \scratch,__LC_EXIT_TIMER
133         alg     \scratch,__LC_SYSTEM_TIMER
134         stg     \scratch,__LC_SYSTEM_TIMER
135         mvc     __LC_LAST_UPDATE_TIMER(8),\enter_timer
136         .endm
137
138         .macro  LAST_BREAK scratch
139         srag    \scratch,%r10,23
140         jz      .+10
141         stg     %r10,__TI_last_break(%r12)
142         .endm
143
144         .macro REENABLE_IRQS
145         stg     %r8,__LC_RETURN_PSW
146         ni      __LC_RETURN_PSW,0xbf
147         ssm     __LC_RETURN_PSW
148         .endm
149
150         .macro STCK savearea
151 #ifdef CONFIG_HAVE_MARCH_Z9_109_FEATURES
152         .insn   s,0xb27c0000,\savearea          # store clock fast
153 #else
154         .insn   s,0xb2050000,\savearea          # store clock
155 #endif
156         .endm
157
158         .section .kprobes.text, "ax"
159
160 /*
161  * Scheduler resume function, called by switch_to
162  *  gpr2 = (task_struct *) prev
163  *  gpr3 = (task_struct *) next
164  * Returns:
165  *  gpr2 = prev
166  */
167 ENTRY(__switch_to)
168         stmg    %r6,%r15,__SF_GPRS(%r15)        # store gprs of prev task
169         stg     %r15,__THREAD_ksp(%r2)          # store kernel stack of prev
170         lg      %r4,__THREAD_info(%r2)          # get thread_info of prev
171         lg      %r5,__THREAD_info(%r3)          # get thread_info of next
172         lgr     %r15,%r5
173         aghi    %r15,STACK_SIZE                 # end of kernel stack of next
174         stg     %r3,__LC_CURRENT                # store task struct of next
175         stg     %r5,__LC_THREAD_INFO            # store thread info of next
176         stg     %r15,__LC_KERNEL_STACK          # store end of kernel stack
177         lctl    %c4,%c4,__TASK_pid(%r3)         # load pid to control reg. 4
178         mvc     __LC_CURRENT_PID+4(4,%r0),__TASK_pid(%r3) # store pid of next
179         lg      %r15,__THREAD_ksp(%r3)          # load kernel stack of next
180         tm      __TI_flags+7(%r4),_TIF_MCCK_PENDING # machine check pending?
181         jz      0f
182         ni      __TI_flags+7(%r4),255-_TIF_MCCK_PENDING # clear flag in prev
183         oi      __TI_flags+7(%r5),_TIF_MCCK_PENDING     # set it in next
184 0:      lmg     %r6,%r15,__SF_GPRS(%r15)        # load gprs of next task
185         br      %r14
186
187 __critical_start:
188 /*
189  * SVC interrupt handler routine. System calls are synchronous events and
190  * are executed with interrupts enabled.
191  */
192
193 ENTRY(system_call)
194         stpt    __LC_SYNC_ENTER_TIMER
195 sysc_stmg:
196         stmg    %r8,%r15,__LC_SAVE_AREA_SYNC
197         lg      %r10,__LC_LAST_BREAK
198         lg      %r12,__LC_THREAD_INFO
199         larl    %r13,system_call
200 sysc_per:
201         lg      %r15,__LC_KERNEL_STACK
202         aghi    %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
203         la      %r11,STACK_FRAME_OVERHEAD(%r15) # pointer to pt_regs
204 sysc_vtime:
205         UPDATE_VTIME %r13,__LC_SYNC_ENTER_TIMER
206         LAST_BREAK %r13
207         stmg    %r0,%r7,__PT_R0(%r11)
208         mvc     __PT_R8(64,%r11),__LC_SAVE_AREA_SYNC
209         mvc     __PT_PSW(16,%r11),__LC_SVC_OLD_PSW
210         mvc     __PT_INT_CODE(4,%r11),__LC_SVC_ILC
211 sysc_do_svc:
212         oi      __TI_flags+7(%r12),_TIF_SYSCALL
213         llgh    %r8,__PT_INT_CODE+2(%r11)
214         slag    %r8,%r8,2                       # shift and test for svc 0
215         jnz     sysc_nr_ok
216         # svc 0: system call number in %r1
217         llgfr   %r1,%r1                         # clear high word in r1
218         cghi    %r1,NR_syscalls
219         jnl     sysc_nr_ok
220         sth     %r1,__PT_INT_CODE+2(%r11)
221         slag    %r8,%r1,2
222 sysc_nr_ok:
223         larl    %r10,sys_call_table             # 64 bit system call table
224 #ifdef CONFIG_COMPAT
225         tm      __TI_flags+5(%r12),(_TIF_31BIT>>16)
226         jno     sysc_noemu
227         larl    %r10,sys_call_table_emu         # 31 bit system call table
228 sysc_noemu:
229 #endif
230         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
231         stg     %r2,__PT_ORIG_GPR2(%r11)
232         stg     %r7,STACK_FRAME_OVERHEAD(%r15)
233         lgf     %r9,0(%r8,%r10)                 # get system call add.
234         tm      __TI_flags+6(%r12),_TIF_TRACE >> 8
235         jnz     sysc_tracesys
236         basr    %r14,%r9                        # call sys_xxxx
237         stg     %r2,__PT_R2(%r11)               # store return value
238
239 sysc_return:
240         LOCKDEP_SYS_EXIT
241 sysc_tif:
242         tm      __PT_PSW+1(%r11),0x01           # returning to user ?
243         jno     sysc_restore
244         tm      __TI_flags+7(%r12),_TIF_WORK_SVC
245         jnz     sysc_work                       # check for work
246         ni      __TI_flags+7(%r12),255-_TIF_SYSCALL
247 sysc_restore:
248         lg      %r14,__LC_VDSO_PER_CPU
249         lmg     %r0,%r10,__PT_R0(%r11)
250         mvc     __LC_RETURN_PSW(16),__PT_PSW(%r11)
251         stpt    __LC_EXIT_TIMER
252         mvc     __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
253         lmg     %r11,%r15,__PT_R11(%r11)
254         lpswe   __LC_RETURN_PSW
255 sysc_done:
256
257 #
258 # One of the work bits is on. Find out which one.
259 #
260 sysc_work:
261         tm      __TI_flags+7(%r12),_TIF_MCCK_PENDING
262         jo      sysc_mcck_pending
263         tm      __TI_flags+7(%r12),_TIF_NEED_RESCHED
264         jo      sysc_reschedule
265         tm      __TI_flags+7(%r12),_TIF_SIGPENDING
266         jo      sysc_sigpending
267         tm      __TI_flags+7(%r12),_TIF_NOTIFY_RESUME
268         jo      sysc_notify_resume
269         tm      __TI_flags+7(%r12),_TIF_PER_TRAP
270         jo      sysc_singlestep
271         j       sysc_return             # beware of critical section cleanup
272
273 #
274 # _TIF_NEED_RESCHED is set, call schedule
275 #
276 sysc_reschedule:
277         larl    %r14,sysc_return
278         jg      schedule
279
280 #
281 # _TIF_MCCK_PENDING is set, call handler
282 #
283 sysc_mcck_pending:
284         larl    %r14,sysc_return
285         jg      s390_handle_mcck        # TIF bit will be cleared by handler
286
287 #
288 # _TIF_SIGPENDING is set, call do_signal
289 #
290 sysc_sigpending:
291         ni      __TI_flags+7(%r12),255-_TIF_PER_TRAP # clear TIF_PER_TRAP
292         lgr     %r2,%r11                # pass pointer to pt_regs
293         brasl   %r14,do_signal
294         tm      __TI_flags+7(%r12),_TIF_SYSCALL
295         jno     sysc_return
296         lmg     %r2,%r7,__PT_R2(%r11)   # load svc arguments
297         lghi    %r8,0                   # svc 0 returns -ENOSYS
298         llgh    %r1,__PT_INT_CODE+2(%r11)       # load new svc number
299         cghi    %r1,NR_syscalls
300         jnl     sysc_nr_ok              # invalid svc number -> do svc 0
301         slag    %r8,%r1,2
302         j       sysc_nr_ok              # restart svc
303
304 #
305 # _TIF_NOTIFY_RESUME is set, call do_notify_resume
306 #
307 sysc_notify_resume:
308         lgr     %r2,%r11                # pass pointer to pt_regs
309         larl    %r14,sysc_return
310         jg      do_notify_resume
311
312 #
313 # _TIF_PER_TRAP is set, call do_per_trap
314 #
315 sysc_singlestep:
316         ni      __TI_flags+7(%r12),255-(_TIF_SYSCALL | _TIF_PER_TRAP)
317         lgr     %r2,%r11                # pass pointer to pt_regs
318         larl    %r14,sysc_return
319         jg      do_per_trap
320
321 #
322 # call tracehook_report_syscall_entry/tracehook_report_syscall_exit before
323 # and after the system call
324 #
325 sysc_tracesys:
326         lgr     %r2,%r11                # pass pointer to pt_regs
327         la      %r3,0
328         llgh    %r0,__PT_INT_CODE+2(%r11)
329         stg     %r0,__PT_R2(%r11)
330         brasl   %r14,do_syscall_trace_enter
331         lghi    %r0,NR_syscalls
332         clgr    %r0,%r2
333         jnh     sysc_tracenogo
334         sllg    %r8,%r2,2
335         lgf     %r9,0(%r8,%r10)
336 sysc_tracego:
337         lmg     %r3,%r7,__PT_R3(%r11)
338         stg     %r7,STACK_FRAME_OVERHEAD(%r15)
339         lg      %r2,__PT_ORIG_GPR2(%r11)
340         basr    %r14,%r9                # call sys_xxx
341         stg     %r2,__PT_R2(%r11)       # store return value
342 sysc_tracenogo:
343         tm      __TI_flags+6(%r12),_TIF_TRACE >> 8
344         jz      sysc_return
345         lgr     %r2,%r11                # pass pointer to pt_regs
346         larl    %r14,sysc_return
347         jg      do_syscall_trace_exit
348
349 #
350 # a new process exits the kernel with ret_from_fork
351 #
352 ENTRY(ret_from_fork)
353         la      %r11,STACK_FRAME_OVERHEAD(%r15)
354         lg      %r12,__LC_THREAD_INFO
355         brasl   %r14,schedule_tail
356         TRACE_IRQS_ON
357         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
358         tm      __PT_PSW+1(%r11),0x01   # forking a kernel thread ?
359         jne     sysc_tracenogo
360         # it's a kernel thread
361         lmg     %r9,%r10,__PT_R9(%r11)  # load gprs
362 ENTRY(kernel_thread_starter)
363         la      %r2,0(%r10)
364         basr    %r14,%r9
365         j       sysc_tracenogo
366
367 /*
368  * Program check handler routine
369  */
370
371 ENTRY(pgm_check_handler)
372         stpt    __LC_SYNC_ENTER_TIMER
373         stmg    %r8,%r15,__LC_SAVE_AREA_SYNC
374         lg      %r10,__LC_LAST_BREAK
375         lg      %r12,__LC_THREAD_INFO
376         larl    %r13,system_call
377         lmg     %r8,%r9,__LC_PGM_OLD_PSW
378         HANDLE_SIE_INTERCEPT %r14
379         tmhh    %r8,0x0001              # test problem state bit
380         jnz     1f                      # -> fault in user space
381         tmhh    %r8,0x4000              # PER bit set in old PSW ?
382         jnz     0f                      # -> enabled, can't be a double fault
383         tm      __LC_PGM_ILC+3,0x80     # check for per exception
384         jnz     pgm_svcper              # -> single stepped svc
385 0:      CHECK_STACK STACK_SIZE,__LC_SAVE_AREA_SYNC
386         j       2f
387 1:      UPDATE_VTIME %r14,__LC_SYNC_ENTER_TIMER
388         LAST_BREAK %r14
389         lg      %r15,__LC_KERNEL_STACK
390         lg      %r14,__TI_task(%r12)
391         lghi    %r13,__LC_PGM_TDB
392         tm      __LC_PGM_ILC+2,0x02     # check for transaction abort
393         jz      2f
394         mvc     __THREAD_trap_tdb(256,%r14),0(%r13)
395 2:      aghi    %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
396         la      %r11,STACK_FRAME_OVERHEAD(%r15)
397         stmg    %r0,%r7,__PT_R0(%r11)
398         mvc     __PT_R8(64,%r11),__LC_SAVE_AREA_SYNC
399         stmg    %r8,%r9,__PT_PSW(%r11)
400         mvc     __PT_INT_CODE(4,%r11),__LC_PGM_ILC
401         mvc     __PT_INT_PARM_LONG(8,%r11),__LC_TRANS_EXC_CODE
402         stg     %r10,__PT_ARGS(%r11)
403         tm      __LC_PGM_ILC+3,0x80     # check for per exception
404         jz      0f
405         tmhh    %r8,0x0001              # kernel per event ?
406         jz      pgm_kprobe
407         oi      __TI_flags+7(%r12),_TIF_PER_TRAP
408         mvc     __THREAD_per_address(8,%r14),__LC_PER_ADDRESS
409         mvc     __THREAD_per_cause(2,%r14),__LC_PER_CAUSE
410         mvc     __THREAD_per_paid(1,%r14),__LC_PER_PAID
411 0:      REENABLE_IRQS
412         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
413         larl    %r1,pgm_check_table
414         llgh    %r10,__PT_INT_CODE+2(%r11)
415         nill    %r10,0x007f
416         sll     %r10,3
417         je      sysc_return
418         lg      %r1,0(%r10,%r1)         # load address of handler routine
419         lgr     %r2,%r11                # pass pointer to pt_regs
420         basr    %r14,%r1                # branch to interrupt-handler
421         j       sysc_return
422
423 #
424 # PER event in supervisor state, must be kprobes
425 #
426 pgm_kprobe:
427         REENABLE_IRQS
428         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
429         lgr     %r2,%r11                # pass pointer to pt_regs
430         brasl   %r14,do_per_trap
431         j       sysc_return
432
433 #
434 # single stepped system call
435 #
436 pgm_svcper:
437         oi      __TI_flags+7(%r12),_TIF_PER_TRAP
438         mvc     __LC_RETURN_PSW(8),__LC_SVC_NEW_PSW
439         larl    %r14,sysc_per
440         stg     %r14,__LC_RETURN_PSW+8
441         lpswe   __LC_RETURN_PSW         # branch to sysc_per and enable irqs
442
443 /*
444  * IO interrupt handler routine
445  */
446 ENTRY(io_int_handler)
447         STCK    __LC_INT_CLOCK
448         stpt    __LC_ASYNC_ENTER_TIMER
449         stmg    %r8,%r15,__LC_SAVE_AREA_ASYNC
450         lg      %r10,__LC_LAST_BREAK
451         lg      %r12,__LC_THREAD_INFO
452         larl    %r13,system_call
453         lmg     %r8,%r9,__LC_IO_OLD_PSW
454         HANDLE_SIE_INTERCEPT %r14
455         SWITCH_ASYNC __LC_SAVE_AREA_ASYNC,__LC_ASYNC_STACK,STACK_SHIFT
456         tmhh    %r8,0x0001              # interrupting from user?
457         jz      io_skip
458         UPDATE_VTIME %r14,__LC_ASYNC_ENTER_TIMER
459         LAST_BREAK %r14
460 io_skip:
461         stmg    %r0,%r7,__PT_R0(%r11)
462         mvc     __PT_R8(64,%r11),__LC_SAVE_AREA_ASYNC
463         stmg    %r8,%r9,__PT_PSW(%r11)
464         TRACE_IRQS_OFF
465         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
466         lgr     %r2,%r11                # pass pointer to pt_regs
467         brasl   %r14,do_IRQ
468 io_return:
469         LOCKDEP_SYS_EXIT
470         TRACE_IRQS_ON
471 io_tif:
472         tm      __TI_flags+7(%r12),_TIF_WORK_INT
473         jnz     io_work                 # there is work to do (signals etc.)
474 io_restore:
475         lg      %r14,__LC_VDSO_PER_CPU
476         lmg     %r0,%r10,__PT_R0(%r11)
477         mvc     __LC_RETURN_PSW(16),__PT_PSW(%r11)
478         stpt    __LC_EXIT_TIMER
479         mvc     __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
480         lmg     %r11,%r15,__PT_R11(%r11)
481         lpswe   __LC_RETURN_PSW
482 io_done:
483
484 #
485 # There is work todo, find out in which context we have been interrupted:
486 # 1) if we return to user space we can do all _TIF_WORK_INT work
487 # 2) if we return to kernel code and kvm is enabled check if we need to
488 #    modify the psw to leave SIE
489 # 3) if we return to kernel code and preemptive scheduling is enabled check
490 #    the preemption counter and if it is zero call preempt_schedule_irq
491 # Before any work can be done, a switch to the kernel stack is required.
492 #
493 io_work:
494         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
495         jo      io_work_user            # yes -> do resched & signal
496 #ifdef CONFIG_PREEMPT
497         # check for preemptive scheduling
498         icm     %r0,15,__TI_precount(%r12)
499         jnz     io_restore              # preemption is disabled
500         tm      __TI_flags+7(%r12),_TIF_NEED_RESCHED
501         jno     io_restore
502         # switch to kernel stack
503         lg      %r1,__PT_R15(%r11)
504         aghi    %r1,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
505         mvc     STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
506         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
507         la      %r11,STACK_FRAME_OVERHEAD(%r1)
508         lgr     %r15,%r1
509         # TRACE_IRQS_ON already done at io_return, call
510         # TRACE_IRQS_OFF to keep things symmetrical
511         TRACE_IRQS_OFF
512         brasl   %r14,preempt_schedule_irq
513         j       io_return
514 #else
515         j       io_restore
516 #endif
517
518 #
519 # Need to do work before returning to userspace, switch to kernel stack
520 #
521 io_work_user:
522         lg      %r1,__LC_KERNEL_STACK
523         aghi    %r1,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
524         mvc     STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
525         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
526         la      %r11,STACK_FRAME_OVERHEAD(%r1)
527         lgr     %r15,%r1
528
529 #
530 # One of the work bits is on. Find out which one.
531 # Checked are: _TIF_SIGPENDING, _TIF_NOTIFY_RESUME, _TIF_NEED_RESCHED
532 #              and _TIF_MCCK_PENDING
533 #
534 io_work_tif:
535         tm      __TI_flags+7(%r12),_TIF_MCCK_PENDING
536         jo      io_mcck_pending
537         tm      __TI_flags+7(%r12),_TIF_NEED_RESCHED
538         jo      io_reschedule
539         tm      __TI_flags+7(%r12),_TIF_SIGPENDING
540         jo      io_sigpending
541         tm      __TI_flags+7(%r12),_TIF_NOTIFY_RESUME
542         jo      io_notify_resume
543         j       io_return               # beware of critical section cleanup
544
545 #
546 # _TIF_MCCK_PENDING is set, call handler
547 #
548 io_mcck_pending:
549         # TRACE_IRQS_ON already done at io_return
550         brasl   %r14,s390_handle_mcck   # TIF bit will be cleared by handler
551         TRACE_IRQS_OFF
552         j       io_return
553
554 #
555 # _TIF_NEED_RESCHED is set, call schedule
556 #
557 io_reschedule:
558         # TRACE_IRQS_ON already done at io_return
559         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
560         brasl   %r14,schedule           # call scheduler
561         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
562         TRACE_IRQS_OFF
563         j       io_return
564
565 #
566 # _TIF_SIGPENDING or is set, call do_signal
567 #
568 io_sigpending:
569         # TRACE_IRQS_ON already done at io_return
570         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
571         lgr     %r2,%r11                # pass pointer to pt_regs
572         brasl   %r14,do_signal
573         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
574         TRACE_IRQS_OFF
575         j       io_return
576
577 #
578 # _TIF_NOTIFY_RESUME or is set, call do_notify_resume
579 #
580 io_notify_resume:
581         # TRACE_IRQS_ON already done at io_return
582         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
583         lgr     %r2,%r11                # pass pointer to pt_regs
584         brasl   %r14,do_notify_resume
585         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
586         TRACE_IRQS_OFF
587         j       io_return
588
589 /*
590  * External interrupt handler routine
591  */
592 ENTRY(ext_int_handler)
593         STCK    __LC_INT_CLOCK
594         stpt    __LC_ASYNC_ENTER_TIMER
595         stmg    %r8,%r15,__LC_SAVE_AREA_ASYNC
596         lg      %r10,__LC_LAST_BREAK
597         lg      %r12,__LC_THREAD_INFO
598         larl    %r13,system_call
599         lmg     %r8,%r9,__LC_EXT_OLD_PSW
600         HANDLE_SIE_INTERCEPT %r14
601         SWITCH_ASYNC __LC_SAVE_AREA_ASYNC,__LC_ASYNC_STACK,STACK_SHIFT
602         tmhh    %r8,0x0001              # interrupting from user ?
603         jz      ext_skip
604         UPDATE_VTIME %r14,__LC_ASYNC_ENTER_TIMER
605         LAST_BREAK %r14
606 ext_skip:
607         stmg    %r0,%r7,__PT_R0(%r11)
608         mvc     __PT_R8(64,%r11),__LC_SAVE_AREA_ASYNC
609         stmg    %r8,%r9,__PT_PSW(%r11)
610         TRACE_IRQS_OFF
611         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
612         lghi    %r1,4096
613         lgr     %r2,%r11                # pass pointer to pt_regs
614         llgf    %r3,__LC_EXT_CPU_ADDR   # get cpu address + interruption code
615         llgf    %r4,__LC_EXT_PARAMS     # get external parameter
616         lg      %r5,__LC_EXT_PARAMS2-4096(%r1)  # get 64 bit external parameter
617         brasl   %r14,do_extint
618         j       io_return
619
620 /*
621  * Load idle PSW. The second "half" of this function is in cleanup_idle.
622  */
623 ENTRY(psw_idle)
624         stg     %r3,__SF_EMPTY(%r15)
625         larl    %r1,psw_idle_lpsw+4
626         stg     %r1,__SF_EMPTY+8(%r15)
627         STCK    __CLOCK_IDLE_ENTER(%r2)
628         stpt    __TIMER_IDLE_ENTER(%r2)
629 psw_idle_lpsw:
630         lpswe   __SF_EMPTY(%r15)
631         br      %r14
632 psw_idle_end:
633
634 __critical_end:
635
636 /*
637  * Machine check handler routines
638  */
639 ENTRY(mcck_int_handler)
640         STCK    __LC_MCCK_CLOCK
641         la      %r1,4095                # revalidate r1
642         spt     __LC_CPU_TIMER_SAVE_AREA-4095(%r1)      # revalidate cpu timer
643         lmg     %r0,%r15,__LC_GPREGS_SAVE_AREA-4095(%r1)# revalidate gprs
644         lg      %r10,__LC_LAST_BREAK
645         lg      %r12,__LC_THREAD_INFO
646         larl    %r13,system_call
647         lmg     %r8,%r9,__LC_MCK_OLD_PSW
648         HANDLE_SIE_INTERCEPT %r14
649         tm      __LC_MCCK_CODE,0x80     # system damage?
650         jo      mcck_panic              # yes -> rest of mcck code invalid
651         lghi    %r14,__LC_CPU_TIMER_SAVE_AREA
652         mvc     __LC_MCCK_ENTER_TIMER(8),0(%r14)
653         tm      __LC_MCCK_CODE+5,0x02   # stored cpu timer value valid?
654         jo      3f
655         la      %r14,__LC_SYNC_ENTER_TIMER
656         clc     0(8,%r14),__LC_ASYNC_ENTER_TIMER
657         jl      0f
658         la      %r14,__LC_ASYNC_ENTER_TIMER
659 0:      clc     0(8,%r14),__LC_EXIT_TIMER
660         jl      1f
661         la      %r14,__LC_EXIT_TIMER
662 1:      clc     0(8,%r14),__LC_LAST_UPDATE_TIMER
663         jl      2f
664         la      %r14,__LC_LAST_UPDATE_TIMER
665 2:      spt     0(%r14)
666         mvc     __LC_MCCK_ENTER_TIMER(8),0(%r14)
667 3:      tm      __LC_MCCK_CODE+2,0x09   # mwp + ia of old psw valid?
668         jno     mcck_panic              # no -> skip cleanup critical
669         SWITCH_ASYNC __LC_GPREGS_SAVE_AREA+64,__LC_PANIC_STACK,PAGE_SHIFT
670         tm      %r8,0x0001              # interrupting from user ?
671         jz      mcck_skip
672         UPDATE_VTIME %r14,__LC_MCCK_ENTER_TIMER
673         LAST_BREAK %r14
674 mcck_skip:
675         lghi    %r14,__LC_GPREGS_SAVE_AREA
676         mvc     __PT_R0(128,%r11),0(%r14)
677         stmg    %r8,%r9,__PT_PSW(%r11)
678         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
679         lgr     %r2,%r11                # pass pointer to pt_regs
680         brasl   %r14,s390_do_machine_check
681         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
682         jno     mcck_return
683         lg      %r1,__LC_KERNEL_STACK   # switch to kernel stack
684         aghi    %r1,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
685         mvc     STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
686         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
687         la      %r11,STACK_FRAME_OVERHEAD(%r1)
688         lgr     %r15,%r1
689         ssm     __LC_PGM_NEW_PSW        # turn dat on, keep irqs off
690         tm      __TI_flags+7(%r12),_TIF_MCCK_PENDING
691         jno     mcck_return
692         TRACE_IRQS_OFF
693         brasl   %r14,s390_handle_mcck
694         TRACE_IRQS_ON
695 mcck_return:
696         lg      %r14,__LC_VDSO_PER_CPU
697         lmg     %r0,%r10,__PT_R0(%r11)
698         mvc     __LC_RETURN_MCCK_PSW(16),__PT_PSW(%r11) # move return PSW
699         tm      __LC_RETURN_MCCK_PSW+1,0x01 # returning to user ?
700         jno     0f
701         stpt    __LC_EXIT_TIMER
702         mvc     __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
703 0:      lmg     %r11,%r15,__PT_R11(%r11)
704         lpswe   __LC_RETURN_MCCK_PSW
705
706 mcck_panic:
707         lg      %r14,__LC_PANIC_STACK
708         slgr    %r14,%r15
709         srag    %r14,%r14,PAGE_SHIFT
710         jz      0f
711         lg      %r15,__LC_PANIC_STACK
712 0:      aghi    %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
713         j       mcck_skip
714
715 #
716 # PSW restart interrupt handler
717 #
718 ENTRY(restart_int_handler)
719         stg     %r15,__LC_SAVE_AREA_RESTART
720         lg      %r15,__LC_RESTART_STACK
721         aghi    %r15,-__PT_SIZE                 # create pt_regs on stack
722         xc      0(__PT_SIZE,%r15),0(%r15)
723         stmg    %r0,%r14,__PT_R0(%r15)
724         mvc     __PT_R15(8,%r15),__LC_SAVE_AREA_RESTART
725         mvc     __PT_PSW(16,%r15),__LC_RST_OLD_PSW # store restart old psw
726         aghi    %r15,-STACK_FRAME_OVERHEAD      # create stack frame on stack
727         xc      0(STACK_FRAME_OVERHEAD,%r15),0(%r15)
728         lg      %r1,__LC_RESTART_FN             # load fn, parm & source cpu
729         lg      %r2,__LC_RESTART_DATA
730         lg      %r3,__LC_RESTART_SOURCE
731         ltgr    %r3,%r3                         # test source cpu address
732         jm      1f                              # negative -> skip source stop
733 0:      sigp    %r4,%r3,SIGP_SENSE              # sigp sense to source cpu
734         brc     10,0b                           # wait for status stored
735 1:      basr    %r14,%r1                        # call function
736         stap    __SF_EMPTY(%r15)                # store cpu address
737         llgh    %r3,__SF_EMPTY(%r15)
738 2:      sigp    %r4,%r3,SIGP_STOP               # sigp stop to current cpu
739         brc     2,2b
740 3:      j       3b
741
742         .section .kprobes.text, "ax"
743
744 #ifdef CONFIG_CHECK_STACK
745 /*
746  * The synchronous or the asynchronous stack overflowed. We are dead.
747  * No need to properly save the registers, we are going to panic anyway.
748  * Setup a pt_regs so that show_trace can provide a good call trace.
749  */
750 stack_overflow:
751         lg      %r11,__LC_PANIC_STACK   # change to panic stack
752         aghi    %r11,-__PT_SIZE         # create pt_regs
753         stmg    %r0,%r7,__PT_R0(%r11)
754         stmg    %r8,%r9,__PT_PSW(%r11)
755         mvc     __PT_R8(64,%r11),0(%r14)
756         stg     %r10,__PT_ORIG_GPR2(%r11) # store last break to orig_gpr2
757         lgr     %r15,%r11
758         aghi    %r15,-STACK_FRAME_OVERHEAD
759         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
760         lgr     %r2,%r11                # pass pointer to pt_regs
761         jg      kernel_stack_overflow
762 #endif
763
764         .align  8
765 cleanup_table:
766         .quad   system_call
767         .quad   sysc_do_svc
768         .quad   sysc_tif
769         .quad   sysc_restore
770         .quad   sysc_done
771         .quad   io_tif
772         .quad   io_restore
773         .quad   io_done
774         .quad   psw_idle
775         .quad   psw_idle_end
776
777 cleanup_critical:
778         clg     %r9,BASED(cleanup_table)        # system_call
779         jl      0f
780         clg     %r9,BASED(cleanup_table+8)      # sysc_do_svc
781         jl      cleanup_system_call
782         clg     %r9,BASED(cleanup_table+16)     # sysc_tif
783         jl      0f
784         clg     %r9,BASED(cleanup_table+24)     # sysc_restore
785         jl      cleanup_sysc_tif
786         clg     %r9,BASED(cleanup_table+32)     # sysc_done
787         jl      cleanup_sysc_restore
788         clg     %r9,BASED(cleanup_table+40)     # io_tif
789         jl      0f
790         clg     %r9,BASED(cleanup_table+48)     # io_restore
791         jl      cleanup_io_tif
792         clg     %r9,BASED(cleanup_table+56)     # io_done
793         jl      cleanup_io_restore
794         clg     %r9,BASED(cleanup_table+64)     # psw_idle
795         jl      0f
796         clg     %r9,BASED(cleanup_table+72)     # psw_idle_end
797         jl      cleanup_idle
798 0:      br      %r14
799
800
801 cleanup_system_call:
802         # check if stpt has been executed
803         clg     %r9,BASED(cleanup_system_call_insn)
804         jh      0f
805         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_ASYNC_ENTER_TIMER
806         cghi    %r11,__LC_SAVE_AREA_ASYNC
807         je      0f
808         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_MCCK_ENTER_TIMER
809 0:      # check if stmg has been executed
810         clg     %r9,BASED(cleanup_system_call_insn+8)
811         jh      0f
812         mvc     __LC_SAVE_AREA_SYNC(64),0(%r11)
813 0:      # check if base register setup + TIF bit load has been done
814         clg     %r9,BASED(cleanup_system_call_insn+16)
815         jhe     0f
816         # set up saved registers r10 and r12
817         stg     %r10,16(%r11)           # r10 last break
818         stg     %r12,32(%r11)           # r12 thread-info pointer
819 0:      # check if the user time update has been done
820         clg     %r9,BASED(cleanup_system_call_insn+24)
821         jh      0f
822         lg      %r15,__LC_EXIT_TIMER
823         slg     %r15,__LC_SYNC_ENTER_TIMER
824         alg     %r15,__LC_USER_TIMER
825         stg     %r15,__LC_USER_TIMER
826 0:      # check if the system time update has been done
827         clg     %r9,BASED(cleanup_system_call_insn+32)
828         jh      0f
829         lg      %r15,__LC_LAST_UPDATE_TIMER
830         slg     %r15,__LC_EXIT_TIMER
831         alg     %r15,__LC_SYSTEM_TIMER
832         stg     %r15,__LC_SYSTEM_TIMER
833 0:      # update accounting time stamp
834         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
835         # do LAST_BREAK
836         lg      %r9,16(%r11)
837         srag    %r9,%r9,23
838         jz      0f
839         mvc     __TI_last_break(8,%r12),16(%r11)
840 0:      # set up saved register r11
841         lg      %r15,__LC_KERNEL_STACK
842         aghi    %r15,-__PT_SIZE
843         stg     %r15,24(%r11)           # r11 pt_regs pointer
844         # fill pt_regs
845         mvc     __PT_R8(64,%r15),__LC_SAVE_AREA_SYNC
846         stmg    %r0,%r7,__PT_R0(%r15)
847         mvc     __PT_PSW(16,%r15),__LC_SVC_OLD_PSW
848         mvc     __PT_INT_CODE(4,%r15),__LC_SVC_ILC
849         # setup saved register r15
850         aghi    %r15,-STACK_FRAME_OVERHEAD
851         stg     %r15,56(%r11)           # r15 stack pointer
852         # set new psw address and exit
853         larl    %r9,sysc_do_svc
854         br      %r14
855 cleanup_system_call_insn:
856         .quad   system_call
857         .quad   sysc_stmg
858         .quad   sysc_per
859         .quad   sysc_vtime+18
860         .quad   sysc_vtime+42
861
862 cleanup_sysc_tif:
863         larl    %r9,sysc_tif
864         br      %r14
865
866 cleanup_sysc_restore:
867         clg     %r9,BASED(cleanup_sysc_restore_insn)
868         je      0f
869         lg      %r9,24(%r11)            # get saved pointer to pt_regs
870         mvc     __LC_RETURN_PSW(16),__PT_PSW(%r9)
871         mvc     0(64,%r11),__PT_R8(%r9)
872         lmg     %r0,%r7,__PT_R0(%r9)
873 0:      lmg     %r8,%r9,__LC_RETURN_PSW
874         br      %r14
875 cleanup_sysc_restore_insn:
876         .quad   sysc_done - 4
877
878 cleanup_io_tif:
879         larl    %r9,io_tif
880         br      %r14
881
882 cleanup_io_restore:
883         clg     %r9,BASED(cleanup_io_restore_insn)
884         je      0f
885         lg      %r9,24(%r11)            # get saved r11 pointer to pt_regs
886         mvc     __LC_RETURN_PSW(16),__PT_PSW(%r9)
887         mvc     0(64,%r11),__PT_R8(%r9)
888         lmg     %r0,%r7,__PT_R0(%r9)
889 0:      lmg     %r8,%r9,__LC_RETURN_PSW
890         br      %r14
891 cleanup_io_restore_insn:
892         .quad   io_done - 4
893
894 cleanup_idle:
895         # copy interrupt clock & cpu timer
896         mvc     __CLOCK_IDLE_EXIT(8,%r2),__LC_INT_CLOCK
897         mvc     __TIMER_IDLE_EXIT(8,%r2),__LC_ASYNC_ENTER_TIMER
898         cghi    %r11,__LC_SAVE_AREA_ASYNC
899         je      0f
900         mvc     __CLOCK_IDLE_EXIT(8,%r2),__LC_MCCK_CLOCK
901         mvc     __TIMER_IDLE_EXIT(8,%r2),__LC_MCCK_ENTER_TIMER
902 0:      # check if stck & stpt have been executed
903         clg     %r9,BASED(cleanup_idle_insn)
904         jhe     1f
905         mvc     __CLOCK_IDLE_ENTER(8,%r2),__CLOCK_IDLE_EXIT(%r2)
906         mvc     __TIMER_IDLE_ENTER(8,%r2),__TIMER_IDLE_EXIT(%r2)
907 1:      # account system time going idle
908         lg      %r9,__LC_STEAL_TIMER
909         alg     %r9,__CLOCK_IDLE_ENTER(%r2)
910         slg     %r9,__LC_LAST_UPDATE_CLOCK
911         stg     %r9,__LC_STEAL_TIMER
912         mvc     __LC_LAST_UPDATE_CLOCK(8),__CLOCK_IDLE_EXIT(%r2)
913         lg      %r9,__LC_SYSTEM_TIMER
914         alg     %r9,__LC_LAST_UPDATE_TIMER
915         slg     %r9,__TIMER_IDLE_ENTER(%r2)
916         stg     %r9,__LC_SYSTEM_TIMER
917         mvc     __LC_LAST_UPDATE_TIMER(8),__TIMER_IDLE_EXIT(%r2)
918         # prepare return psw
919         nihh    %r8,0xfffd              # clear wait state bit
920         lg      %r9,48(%r11)            # return from psw_idle
921         br      %r14
922 cleanup_idle_insn:
923         .quad   psw_idle_lpsw
924
925 /*
926  * Integer constants
927  */
928         .align  8
929 .Lcritical_start:
930         .quad   __critical_start
931 .Lcritical_length:
932         .quad   __critical_end - __critical_start
933
934
935 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
936 /*
937  * sie64a calling convention:
938  * %r2 pointer to sie control block
939  * %r3 guest register save area
940  */
941 ENTRY(sie64a)
942         stmg    %r6,%r14,__SF_GPRS(%r15)        # save kernel registers
943         stg     %r2,__SF_EMPTY(%r15)            # save control block pointer
944         stg     %r3,__SF_EMPTY+8(%r15)          # save guest register save area
945         xc      __SF_EMPTY+16(8,%r15),__SF_EMPTY+16(%r15) # host id == 0
946         lmg     %r0,%r13,0(%r3)                 # load guest gprs 0-13
947 sie_loop:
948         lg      %r14,__LC_THREAD_INFO           # pointer thread_info struct
949         tm      __TI_flags+7(%r14),_TIF_EXIT_SIE
950         jnz     sie_exit
951         lg      %r14,__LC_GMAP                  # get gmap pointer
952         ltgr    %r14,%r14
953         jz      sie_gmap
954         lctlg   %c1,%c1,__GMAP_ASCE(%r14)       # load primary asce
955 sie_gmap:
956         lg      %r14,__SF_EMPTY(%r15)           # get control block pointer
957         SPP     __SF_EMPTY(%r15)                # set guest id
958         sie     0(%r14)
959 sie_done:
960         SPP     __SF_EMPTY+16(%r15)             # set host id
961         lg      %r14,__LC_THREAD_INFO           # pointer thread_info struct
962 sie_exit:
963         lctlg   %c1,%c1,__LC_USER_ASCE          # load primary asce
964         lg      %r14,__SF_EMPTY+8(%r15)         # load guest register save area
965         stmg    %r0,%r13,0(%r14)                # save guest gprs 0-13
966         lmg     %r6,%r14,__SF_GPRS(%r15)        # restore kernel registers
967         lghi    %r2,0
968         br      %r14
969 sie_fault:
970         lctlg   %c1,%c1,__LC_USER_ASCE          # load primary asce
971         lg      %r14,__LC_THREAD_INFO           # pointer thread_info struct
972         lg      %r14,__SF_EMPTY+8(%r15)         # load guest register save area
973         stmg    %r0,%r13,0(%r14)                # save guest gprs 0-13
974         lmg     %r6,%r14,__SF_GPRS(%r15)        # restore kernel registers
975         lghi    %r2,-EFAULT
976         br      %r14
977
978         .align  8
979 .Lsie_loop:
980         .quad   sie_loop
981 .Lsie_length:
982         .quad   sie_done - sie_loop
983 .Lhost_id:
984         .quad   0
985
986         EX_TABLE(sie_loop,sie_fault)
987 #endif
988
989                 .section .rodata, "a"
990 #define SYSCALL(esa,esame,emu)  .long esame
991         .globl  sys_call_table
992 sys_call_table:
993 #include "syscalls.S"
994 #undef SYSCALL
995
996 #ifdef CONFIG_COMPAT
997
998 #define SYSCALL(esa,esame,emu)  .long emu
999 sys_call_table_emu:
1000 #include "syscalls.S"
1001 #undef SYSCALL
1002 #endif