]> git.openfabrics.org - ~shefty/rdma-dev.git/blob - arch/s390/kernel/entry64.S
e4038ea4dc57da1010309a4cb4fcaa28b19f7e3c
[~shefty/rdma-dev.git] / arch / s390 / kernel / entry64.S
1 /*
2  *  arch/s390/kernel/entry64.S
3  *    S390 low-level entry points.
4  *
5  *    Copyright (C) IBM Corp. 1999,2010
6  *    Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
7  *               Hartmut Penner (hp@de.ibm.com),
8  *               Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
9  *               Heiko Carstens <heiko.carstens@de.ibm.com>
10  */
11
12 #include <linux/linkage.h>
13 #include <linux/init.h>
14 #include <asm/cache.h>
15 #include <asm/errno.h>
16 #include <asm/ptrace.h>
17 #include <asm/thread_info.h>
18 #include <asm/asm-offsets.h>
19 #include <asm/unistd.h>
20 #include <asm/page.h>
21
22 /*
23  * Stack layout for the system_call stack entry.
24  * The first few entries are identical to the user_regs_struct.
25  */
26 SP_PTREGS    =  STACK_FRAME_OVERHEAD
27 SP_ARGS      =  STACK_FRAME_OVERHEAD + __PT_ARGS
28 SP_PSW       =  STACK_FRAME_OVERHEAD + __PT_PSW
29 SP_R0        =  STACK_FRAME_OVERHEAD + __PT_GPRS
30 SP_R1        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 8
31 SP_R2        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 16
32 SP_R3        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 24
33 SP_R4        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 32
34 SP_R5        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 40
35 SP_R6        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 48
36 SP_R7        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 56
37 SP_R8        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 64
38 SP_R9        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 72
39 SP_R10       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 80
40 SP_R11       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 88
41 SP_R12       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 96
42 SP_R13       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 104
43 SP_R14       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 112
44 SP_R15       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 120
45 SP_ORIG_R2   =  STACK_FRAME_OVERHEAD + __PT_ORIG_GPR2
46 SP_ILC       =  STACK_FRAME_OVERHEAD + __PT_ILC
47 SP_SVCNR      = STACK_FRAME_OVERHEAD + __PT_SVCNR
48 SP_SIZE      =  STACK_FRAME_OVERHEAD + __PT_SIZE
49
50 STACK_SHIFT = PAGE_SHIFT + THREAD_ORDER
51 STACK_SIZE  = 1 << STACK_SHIFT
52
53 _TIF_WORK_SVC = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
54                  _TIF_MCCK_PENDING | _TIF_RESTART_SVC | _TIF_SINGLE_STEP )
55 _TIF_WORK_INT = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
56                  _TIF_MCCK_PENDING)
57 _TIF_SYSCALL = (_TIF_SYSCALL_TRACE>>8 | _TIF_SYSCALL_AUDIT>>8 | \
58                 _TIF_SECCOMP>>8 | _TIF_SYSCALL_TRACEPOINT>>8)
59
60 #define BASED(name) name-system_call(%r13)
61
62         .macro  HANDLE_SIE_INTERCEPT
63 #if defined(CONFIG_KVM) || defined(CONFIG_KVM_MODULE)
64         lg      %r3,__LC_SIE_HOOK
65         ltgr    %r3,%r3
66         jz      0f
67         basr    %r14,%r3
68 0:
69 #endif
70         .endm
71
72 #ifdef CONFIG_TRACE_IRQFLAGS
73         .macro  TRACE_IRQS_ON
74         basr    %r2,%r0
75         brasl   %r14,trace_hardirqs_on_caller
76         .endm
77
78         .macro  TRACE_IRQS_OFF
79         basr    %r2,%r0
80         brasl   %r14,trace_hardirqs_off_caller
81         .endm
82 #else
83 #define TRACE_IRQS_ON
84 #define TRACE_IRQS_OFF
85 #endif
86
87 #ifdef CONFIG_LOCKDEP
88         .macro  LOCKDEP_SYS_EXIT
89         tm      SP_PSW+1(%r15),0x01     # returning to user ?
90         jz      0f
91         brasl   %r14,lockdep_sys_exit
92 0:
93         .endm
94 #else
95 #define LOCKDEP_SYS_EXIT
96 #endif
97
98         .macro  UPDATE_VTIME lc_from,lc_to,lc_sum
99         lg      %r10,\lc_from
100         slg     %r10,\lc_to
101         alg     %r10,\lc_sum
102         stg     %r10,\lc_sum
103         .endm
104
105 /*
106  * Register usage in interrupt handlers:
107  *    R9  - pointer to current task structure
108  *    R13 - pointer to literal pool
109  *    R14 - return register for function calls
110  *    R15 - kernel stack pointer
111  */
112
113         .macro  SAVE_ALL_SVC psworg,savearea
114         stmg    %r11,%r15,\savearea
115         lg      %r15,__LC_KERNEL_STACK  # problem state -> load ksp
116         aghi    %r15,-SP_SIZE           # make room for registers & psw
117         lg      %r11,__LC_LAST_BREAK
118         .endm
119
120         .macro  SAVE_ALL_PGM psworg,savearea
121         stmg    %r11,%r15,\savearea
122         tm      \psworg+1,0x01          # test problem state bit
123 #ifdef CONFIG_CHECK_STACK
124         jnz     1f
125         tml     %r15,STACK_SIZE - CONFIG_STACK_GUARD
126         jnz     2f
127         la      %r12,\psworg
128         j       stack_overflow
129 #else
130         jz      2f
131 #endif
132 1:      lg      %r15,__LC_KERNEL_STACK  # problem state -> load ksp
133 2:      aghi    %r15,-SP_SIZE           # make room for registers & psw
134         larl    %r13,system_call
135         lg      %r11,__LC_LAST_BREAK
136         .endm
137
138         .macro  SAVE_ALL_ASYNC psworg,savearea
139         stmg    %r11,%r15,\savearea
140         larl    %r13,system_call
141         lg      %r11,__LC_LAST_BREAK
142         la      %r12,\psworg
143         tm      \psworg+1,0x01          # test problem state bit
144         jnz     1f                      # from user -> load kernel stack
145         clc     \psworg+8(8),BASED(.Lcritical_end)
146         jhe     0f
147         clc     \psworg+8(8),BASED(.Lcritical_start)
148         jl      0f
149         brasl   %r14,cleanup_critical
150         tm      1(%r12),0x01            # retest problem state after cleanup
151         jnz     1f
152 0:      lg      %r14,__LC_ASYNC_STACK   # are we already on the async. stack ?
153         slgr    %r14,%r15
154         srag    %r14,%r14,STACK_SHIFT
155 #ifdef CONFIG_CHECK_STACK
156         jnz     1f
157         tml     %r15,STACK_SIZE - CONFIG_STACK_GUARD
158         jnz     2f
159         j       stack_overflow
160 #else
161         jz      2f
162 #endif
163 1:      lg      %r15,__LC_ASYNC_STACK   # load async stack
164 2:      aghi    %r15,-SP_SIZE           # make room for registers & psw
165         .endm
166
167         .macro  CREATE_STACK_FRAME savearea
168         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
169         stg     %r2,SP_ORIG_R2(%r15)    # store original content of gpr 2
170         mvc     SP_R11(40,%r15),\savearea # move %r11-%r15 to stack
171         stmg    %r0,%r10,SP_R0(%r15)    # store gprs %r0-%r10 to kernel stack
172         .endm
173
174         .macro  RESTORE_ALL psworg,sync
175         mvc     \psworg(16),SP_PSW(%r15) # move user PSW to lowcore
176         .if !\sync
177         ni      \psworg+1,0xfd          # clear wait state bit
178         .endif
179         lg      %r14,__LC_VDSO_PER_CPU
180         lmg     %r0,%r13,SP_R0(%r15)    # load gprs 0-13 of user
181         stpt    __LC_EXIT_TIMER
182         mvc     __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
183         lmg     %r14,%r15,SP_R14(%r15)  # load grps 14-15 of user
184         lpswe   \psworg                 # back to caller
185         .endm
186
187         .macro  LAST_BREAK
188         srag    %r10,%r11,23
189         jz      0f
190         stg     %r11,__TI_last_break(%r12)
191 0:
192         .endm
193
194         .macro REENABLE_IRQS
195         mvc     __SF_EMPTY(1,%r15),SP_PSW(%r15)
196         ni      __SF_EMPTY(%r15),0xbf
197         ssm     __SF_EMPTY(%r15)
198         .endm
199
200 /*
201  * Scheduler resume function, called by switch_to
202  *  gpr2 = (task_struct *) prev
203  *  gpr3 = (task_struct *) next
204  * Returns:
205  *  gpr2 = prev
206  */
207         .globl  __switch_to
208 __switch_to:
209         tm      __THREAD_per+4(%r3),0xe8 # is the new process using per ?
210         jz      __switch_to_noper               # if not we're fine
211         stctg   %c9,%c11,__SF_EMPTY(%r15)# We are using per stuff
212         clc     __THREAD_per(24,%r3),__SF_EMPTY(%r15)
213         je      __switch_to_noper            # we got away without bashing TLB's
214         lctlg   %c9,%c11,__THREAD_per(%r3)      # Nope we didn't
215 __switch_to_noper:
216         lg      %r4,__THREAD_info(%r2)              # get thread_info of prev
217         tm      __TI_flags+7(%r4),_TIF_MCCK_PENDING # machine check pending?
218         jz      __switch_to_no_mcck
219         ni      __TI_flags+7(%r4),255-_TIF_MCCK_PENDING # clear flag in prev
220         lg      %r4,__THREAD_info(%r3)              # get thread_info of next
221         oi      __TI_flags+7(%r4),_TIF_MCCK_PENDING # set it in next
222 __switch_to_no_mcck:
223         stmg    %r6,%r15,__SF_GPRS(%r15)# store __switch_to registers of prev task
224         stg     %r15,__THREAD_ksp(%r2)  # store kernel stack to prev->tss.ksp
225         lg      %r15,__THREAD_ksp(%r3)  # load kernel stack from next->tss.ksp
226         lmg     %r6,%r15,__SF_GPRS(%r15)# load __switch_to registers of next task
227         stg     %r3,__LC_CURRENT        # __LC_CURRENT = current task struct
228         lctl    %c4,%c4,__TASK_pid(%r3) # load pid to control reg. 4
229         lg      %r3,__THREAD_info(%r3)  # load thread_info from task struct
230         stg     %r3,__LC_THREAD_INFO
231         aghi    %r3,STACK_SIZE
232         stg     %r3,__LC_KERNEL_STACK   # __LC_KERNEL_STACK = new kernel stack
233         br      %r14
234
235 __critical_start:
236 /*
237  * SVC interrupt handler routine. System calls are synchronous events and
238  * are executed with interrupts enabled.
239  */
240
241         .globl  system_call
242 system_call:
243         stpt    __LC_SYNC_ENTER_TIMER
244 sysc_saveall:
245         SAVE_ALL_SVC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
246         CREATE_STACK_FRAME __LC_SAVE_AREA
247         mvc     SP_PSW(16,%r15),__LC_SVC_OLD_PSW
248         mvc     SP_ILC(4,%r15),__LC_SVC_ILC
249         stg     %r7,SP_ARGS(%r15)
250         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
251 sysc_vtime:
252         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
253 sysc_stime:
254         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
255 sysc_update:
256         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
257         LAST_BREAK
258 sysc_do_svc:
259         llgh    %r7,SP_SVCNR(%r15)
260         slag    %r7,%r7,2       # shift and test for svc 0
261         jnz     sysc_nr_ok
262         # svc 0: system call number in %r1
263         llgfr   %r1,%r1         # clear high word in r1
264         cghi    %r1,NR_syscalls
265         jnl     sysc_nr_ok
266         sth     %r1,SP_SVCNR(%r15)
267         slag    %r7,%r1,2       # shift and test for svc 0
268 sysc_nr_ok:
269         larl    %r10,sys_call_table
270 #ifdef CONFIG_COMPAT
271         tm      __TI_flags+5(%r12),(_TIF_31BIT>>16)  # running in 31 bit mode ?
272         jno     sysc_noemu
273         larl    %r10,sys_call_table_emu  # use 31 bit emulation system calls
274 sysc_noemu:
275 #endif
276         tm      __TI_flags+6(%r12),_TIF_SYSCALL
277         lgf     %r8,0(%r7,%r10) # load address of system call routine
278         jnz     sysc_tracesys
279         basr    %r14,%r8        # call sys_xxxx
280         stg     %r2,SP_R2(%r15) # store return value (change R2 on stack)
281
282 sysc_return:
283         LOCKDEP_SYS_EXIT
284 sysc_tif:
285         tm      __TI_flags+7(%r12),_TIF_WORK_SVC
286         jnz     sysc_work       # there is work to do (signals etc.)
287 sysc_restore:
288         RESTORE_ALL __LC_RETURN_PSW,1
289 sysc_done:
290
291 #
292 # There is work to do, but first we need to check if we return to userspace.
293 #
294 sysc_work:
295         tm      SP_PSW+1(%r15),0x01     # returning to user ?
296         jno     sysc_restore
297
298 #
299 # One of the work bits is on. Find out which one.
300 #
301 sysc_work_tif:
302         tm      __TI_flags+7(%r12),_TIF_MCCK_PENDING
303         jo      sysc_mcck_pending
304         tm      __TI_flags+7(%r12),_TIF_NEED_RESCHED
305         jo      sysc_reschedule
306         tm      __TI_flags+7(%r12),_TIF_SIGPENDING
307         jo      sysc_sigpending
308         tm      __TI_flags+7(%r12),_TIF_NOTIFY_RESUME
309         jo      sysc_notify_resume
310         tm      __TI_flags+7(%r12),_TIF_RESTART_SVC
311         jo      sysc_restart
312         tm      __TI_flags+7(%r12),_TIF_SINGLE_STEP
313         jo      sysc_singlestep
314         j       sysc_return             # beware of critical section cleanup
315
316 #
317 # _TIF_NEED_RESCHED is set, call schedule
318 #
319 sysc_reschedule:
320         larl    %r14,sysc_return
321         jg      schedule                # return point is sysc_return
322
323 #
324 # _TIF_MCCK_PENDING is set, call handler
325 #
326 sysc_mcck_pending:
327         larl    %r14,sysc_return
328         jg      s390_handle_mcck        # TIF bit will be cleared by handler
329
330 #
331 # _TIF_SIGPENDING is set, call do_signal
332 #
333 sysc_sigpending:
334         ni      __TI_flags+7(%r12),255-_TIF_SINGLE_STEP # clear TIF_SINGLE_STEP
335         la      %r2,SP_PTREGS(%r15)     # load pt_regs
336         brasl   %r14,do_signal          # call do_signal
337         tm      __TI_flags+7(%r12),_TIF_RESTART_SVC
338         jo      sysc_restart
339         tm      __TI_flags+7(%r12),_TIF_SINGLE_STEP
340         jo      sysc_singlestep
341         j       sysc_return
342
343 #
344 # _TIF_NOTIFY_RESUME is set, call do_notify_resume
345 #
346 sysc_notify_resume:
347         la      %r2,SP_PTREGS(%r15)     # load pt_regs
348         larl    %r14,sysc_return
349         jg      do_notify_resume        # call do_notify_resume
350
351 #
352 # _TIF_RESTART_SVC is set, set up registers and restart svc
353 #
354 sysc_restart:
355         ni      __TI_flags+7(%r12),255-_TIF_RESTART_SVC # clear TIF_RESTART_SVC
356         lg      %r7,SP_R2(%r15)         # load new svc number
357         mvc     SP_R2(8,%r15),SP_ORIG_R2(%r15) # restore first argument
358         lmg     %r2,%r6,SP_R2(%r15)     # load svc arguments
359         sth     %r7,SP_SVCNR(%r15)
360         slag    %r7,%r7,2
361         j       sysc_nr_ok              # restart svc
362
363 #
364 # _TIF_SINGLE_STEP is set, call do_single_step
365 #
366 sysc_singlestep:
367         ni      __TI_flags+7(%r12),255-_TIF_SINGLE_STEP # clear TIF_SINGLE_STEP
368         xc      SP_SVCNR(2,%r15),SP_SVCNR(%r15)         # clear svc number
369         la      %r2,SP_PTREGS(%r15)     # address of register-save area
370         larl    %r14,sysc_return        # load adr. of system return
371         jg      do_single_step          # branch to do_sigtrap
372
373 #
374 # call tracehook_report_syscall_entry/tracehook_report_syscall_exit before
375 # and after the system call
376 #
377 sysc_tracesys:
378         la      %r2,SP_PTREGS(%r15)     # load pt_regs
379         la      %r3,0
380         llgh    %r0,SP_SVCNR(%r15)
381         stg     %r0,SP_R2(%r15)
382         brasl   %r14,do_syscall_trace_enter
383         lghi    %r0,NR_syscalls
384         clgr    %r0,%r2
385         jnh     sysc_tracenogo
386         sllg    %r7,%r2,2               # svc number *4
387         lgf     %r8,0(%r7,%r10)
388 sysc_tracego:
389         lmg     %r3,%r6,SP_R3(%r15)
390         lg      %r2,SP_ORIG_R2(%r15)
391         basr    %r14,%r8                # call sys_xxx
392         stg     %r2,SP_R2(%r15)         # store return value
393 sysc_tracenogo:
394         tm      __TI_flags+6(%r12),_TIF_SYSCALL
395         jz      sysc_return
396         la      %r2,SP_PTREGS(%r15)     # load pt_regs
397         larl    %r14,sysc_return        # return point is sysc_return
398         jg      do_syscall_trace_exit
399
400 #
401 # a new process exits the kernel with ret_from_fork
402 #
403         .globl  ret_from_fork
404 ret_from_fork:
405         lg      %r13,__LC_SVC_NEW_PSW+8
406         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
407         tm      SP_PSW+1(%r15),0x01     # forking a kernel thread ?
408         jo      0f
409         stg     %r15,SP_R15(%r15)       # store stack pointer for new kthread
410 0:      brasl   %r14,schedule_tail
411         TRACE_IRQS_ON
412         stosm   24(%r15),0x03           # reenable interrupts
413         j       sysc_tracenogo
414
415 #
416 # kernel_execve function needs to deal with pt_regs that is not
417 # at the usual place
418 #
419         .globl  kernel_execve
420 kernel_execve:
421         stmg    %r12,%r15,96(%r15)
422         lgr     %r14,%r15
423         aghi    %r15,-SP_SIZE
424         stg     %r14,__SF_BACKCHAIN(%r15)
425         la      %r12,SP_PTREGS(%r15)
426         xc      0(__PT_SIZE,%r12),0(%r12)
427         lgr     %r5,%r12
428         brasl   %r14,do_execve
429         ltgfr   %r2,%r2
430         je      0f
431         aghi    %r15,SP_SIZE
432         lmg     %r12,%r15,96(%r15)
433         br      %r14
434         # execve succeeded.
435 0:      stnsm   __SF_EMPTY(%r15),0xfc   # disable interrupts
436         lg      %r15,__LC_KERNEL_STACK  # load ksp
437         aghi    %r15,-SP_SIZE           # make room for registers & psw
438         lg      %r13,__LC_SVC_NEW_PSW+8
439         mvc     SP_PTREGS(__PT_SIZE,%r15),0(%r12)       # copy pt_regs
440         lg      %r12,__LC_THREAD_INFO
441         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
442         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
443         brasl   %r14,execve_tail
444         j       sysc_return
445
446 /*
447  * Program check handler routine
448  */
449
450         .globl  pgm_check_handler
451 pgm_check_handler:
452 /*
453  * First we need to check for a special case:
454  * Single stepping an instruction that disables the PER event mask will
455  * cause a PER event AFTER the mask has been set. Example: SVC or LPSW.
456  * For a single stepped SVC the program check handler gets control after
457  * the SVC new PSW has been loaded. But we want to execute the SVC first and
458  * then handle the PER event. Therefore we update the SVC old PSW to point
459  * to the pgm_check_handler and branch to the SVC handler after we checked
460  * if we have to load the kernel stack register.
461  * For every other possible cause for PER event without the PER mask set
462  * we just ignore the PER event (FIXME: is there anything we have to do
463  * for LPSW?).
464  */
465         stpt    __LC_SYNC_ENTER_TIMER
466         tm      __LC_PGM_INT_CODE+1,0x80 # check whether we got a per exception
467         jnz     pgm_per                  # got per exception -> special case
468         SAVE_ALL_PGM __LC_PGM_OLD_PSW,__LC_SAVE_AREA
469         CREATE_STACK_FRAME __LC_SAVE_AREA
470         xc      SP_ILC(4,%r15),SP_ILC(%r15)
471         mvc     SP_PSW(16,%r15),__LC_PGM_OLD_PSW
472         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
473         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
474         jz      pgm_no_vtime
475         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
476         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
477         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
478         LAST_BREAK
479 pgm_no_vtime:
480         HANDLE_SIE_INTERCEPT
481         stg     %r11,SP_ARGS(%r15)
482         lgf     %r3,__LC_PGM_ILC        # load program interruption code
483         lg      %r4,__LC_TRANS_EXC_CODE
484         REENABLE_IRQS
485         lghi    %r8,0x7f
486         ngr     %r8,%r3
487         sll     %r8,3
488         larl    %r1,pgm_check_table
489         lg      %r1,0(%r8,%r1)          # load address of handler routine
490         la      %r2,SP_PTREGS(%r15)     # address of register-save area
491         basr    %r14,%r1                # branch to interrupt-handler
492 pgm_exit:
493         j       sysc_return
494
495 #
496 # handle per exception
497 #
498 pgm_per:
499         tm      __LC_PGM_OLD_PSW,0x40   # test if per event recording is on
500         jnz     pgm_per_std             # ok, normal per event from user space
501 # ok its one of the special cases, now we need to find out which one
502         clc     __LC_PGM_OLD_PSW(16),__LC_SVC_NEW_PSW
503         je      pgm_svcper
504 # no interesting special case, ignore PER event
505         lpswe   __LC_PGM_OLD_PSW
506
507 #
508 # Normal per exception
509 #
510 pgm_per_std:
511         SAVE_ALL_PGM __LC_PGM_OLD_PSW,__LC_SAVE_AREA
512         CREATE_STACK_FRAME __LC_SAVE_AREA
513         mvc     SP_PSW(16,%r15),__LC_PGM_OLD_PSW
514         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
515         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
516         jz      pgm_no_vtime2
517         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
518         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
519         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
520         LAST_BREAK
521 pgm_no_vtime2:
522         HANDLE_SIE_INTERCEPT
523         lg      %r1,__TI_task(%r12)
524         tm      SP_PSW+1(%r15),0x01     # kernel per event ?
525         jz      kernel_per
526         mvc     __THREAD_per+__PER_atmid(2,%r1),__LC_PER_ATMID
527         mvc     __THREAD_per+__PER_address(8,%r1),__LC_PER_ADDRESS
528         mvc     __THREAD_per+__PER_access_id(1,%r1),__LC_PER_ACCESS_ID
529         oi      __TI_flags+7(%r12),_TIF_SINGLE_STEP # set TIF_SINGLE_STEP
530         lgf     %r3,__LC_PGM_ILC        # load program interruption code
531         lg      %r4,__LC_TRANS_EXC_CODE
532         REENABLE_IRQS
533         lghi    %r8,0x7f
534         ngr     %r8,%r3                 # clear per-event-bit and ilc
535         je      pgm_exit2
536         sll     %r8,3
537         larl    %r1,pgm_check_table
538         lg      %r1,0(%r8,%r1)          # load address of handler routine
539         la      %r2,SP_PTREGS(%r15)     # address of register-save area
540         basr    %r14,%r1                # branch to interrupt-handler
541 pgm_exit2:
542         j       sysc_return
543
544 #
545 # it was a single stepped SVC that is causing all the trouble
546 #
547 pgm_svcper:
548         SAVE_ALL_PGM __LC_SVC_OLD_PSW,__LC_SAVE_AREA
549         CREATE_STACK_FRAME __LC_SAVE_AREA
550         mvc     SP_PSW(16,%r15),__LC_SVC_OLD_PSW
551         mvc     SP_ILC(4,%r15),__LC_SVC_ILC
552         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
553         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
554         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
555         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
556         LAST_BREAK
557         lg      %r8,__TI_task(%r12)
558         mvc     __THREAD_per+__PER_atmid(2,%r8),__LC_PER_ATMID
559         mvc     __THREAD_per+__PER_address(8,%r8),__LC_PER_ADDRESS
560         mvc     __THREAD_per+__PER_access_id(1,%r8),__LC_PER_ACCESS_ID
561         oi      __TI_flags+7(%r12),_TIF_SINGLE_STEP # set TIF_SINGLE_STEP
562         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
563         lmg     %r2,%r6,SP_R2(%r15)     # load svc arguments
564         j       sysc_do_svc
565
566 #
567 # per was called from kernel, must be kprobes
568 #
569 kernel_per:
570         xc      SP_SVCNR(2,%r15),SP_SVCNR(%r15) # clear svc number
571         la      %r2,SP_PTREGS(%r15)     # address of register-save area
572         brasl   %r14,do_single_step
573         j       pgm_exit
574
575 /*
576  * IO interrupt handler routine
577  */
578         .globl io_int_handler
579 io_int_handler:
580         stck    __LC_INT_CLOCK
581         stpt    __LC_ASYNC_ENTER_TIMER
582         SAVE_ALL_ASYNC __LC_IO_OLD_PSW,__LC_SAVE_AREA+40
583         CREATE_STACK_FRAME __LC_SAVE_AREA+40
584         mvc     SP_PSW(16,%r15),0(%r12) # move user PSW to stack
585         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
586         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
587         jz      io_no_vtime
588         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
589         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
590         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
591         LAST_BREAK
592 io_no_vtime:
593         HANDLE_SIE_INTERCEPT
594         TRACE_IRQS_OFF
595         la      %r2,SP_PTREGS(%r15)     # address of register-save area
596         brasl   %r14,do_IRQ             # call standard irq handler
597 io_return:
598         LOCKDEP_SYS_EXIT
599         TRACE_IRQS_ON
600 io_tif:
601         tm      __TI_flags+7(%r12),_TIF_WORK_INT
602         jnz     io_work                 # there is work to do (signals etc.)
603 io_restore:
604         RESTORE_ALL __LC_RETURN_PSW,0
605 io_done:
606
607 #
608 # There is work todo, find out in which context we have been interrupted:
609 # 1) if we return to user space we can do all _TIF_WORK_INT work
610 # 2) if we return to kernel code and kvm is enabled check if we need to
611 #    modify the psw to leave SIE
612 # 3) if we return to kernel code and preemptive scheduling is enabled check
613 #    the preemption counter and if it is zero call preempt_schedule_irq
614 # Before any work can be done, a switch to the kernel stack is required.
615 #
616 io_work:
617         tm      SP_PSW+1(%r15),0x01     # returning to user ?
618         jo      io_work_user            # yes -> do resched & signal
619 #ifdef CONFIG_PREEMPT
620         # check for preemptive scheduling
621         icm     %r0,15,__TI_precount(%r12)
622         jnz     io_restore              # preemption is disabled
623         tm      __TI_flags+7(%r12),_TIF_NEED_RESCHED
624         jno     io_restore
625         # switch to kernel stack
626         lg      %r1,SP_R15(%r15)
627         aghi    %r1,-SP_SIZE
628         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
629         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1) # clear back chain
630         lgr     %r15,%r1
631         # TRACE_IRQS_ON already done at io_return, call
632         # TRACE_IRQS_OFF to keep things symmetrical
633         TRACE_IRQS_OFF
634         brasl   %r14,preempt_schedule_irq
635         j       io_return
636 #else
637         j       io_restore
638 #endif
639
640 #
641 # Need to do work before returning to userspace, switch to kernel stack
642 #
643 io_work_user:
644         lg      %r1,__LC_KERNEL_STACK
645         aghi    %r1,-SP_SIZE
646         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
647         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1) # clear back chain
648         lgr     %r15,%r1
649
650 #
651 # One of the work bits is on. Find out which one.
652 # Checked are: _TIF_SIGPENDING, _TIF_NOTIFY_RESUME, _TIF_NEED_RESCHED
653 #              and _TIF_MCCK_PENDING
654 #
655 io_work_tif:
656         tm      __TI_flags+7(%r12),_TIF_MCCK_PENDING
657         jo      io_mcck_pending
658         tm      __TI_flags+7(%r12),_TIF_NEED_RESCHED
659         jo      io_reschedule
660         tm      __TI_flags+7(%r12),_TIF_SIGPENDING
661         jo      io_sigpending
662         tm      __TI_flags+7(%r12),_TIF_NOTIFY_RESUME
663         jo      io_notify_resume
664         j       io_return               # beware of critical section cleanup
665
666 #
667 # _TIF_MCCK_PENDING is set, call handler
668 #
669 io_mcck_pending:
670         # TRACE_IRQS_ON already done at io_return
671         brasl   %r14,s390_handle_mcck   # TIF bit will be cleared by handler
672         TRACE_IRQS_OFF
673         j       io_return
674
675 #
676 # _TIF_NEED_RESCHED is set, call schedule
677 #
678 io_reschedule:
679         # TRACE_IRQS_ON already done at io_return
680         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
681         brasl   %r14,schedule           # call scheduler
682         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
683         TRACE_IRQS_OFF
684         j       io_return
685
686 #
687 # _TIF_SIGPENDING or is set, call do_signal
688 #
689 io_sigpending:
690         # TRACE_IRQS_ON already done at io_return
691         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
692         la      %r2,SP_PTREGS(%r15)     # load pt_regs
693         brasl   %r14,do_signal          # call do_signal
694         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
695         TRACE_IRQS_OFF
696         j       io_return
697
698 #
699 # _TIF_NOTIFY_RESUME or is set, call do_notify_resume
700 #
701 io_notify_resume:
702         # TRACE_IRQS_ON already done at io_return
703         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
704         la      %r2,SP_PTREGS(%r15)     # load pt_regs
705         brasl   %r14,do_notify_resume   # call do_notify_resume
706         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
707         TRACE_IRQS_OFF
708         j       io_return
709
710 /*
711  * External interrupt handler routine
712  */
713         .globl  ext_int_handler
714 ext_int_handler:
715         stck    __LC_INT_CLOCK
716         stpt    __LC_ASYNC_ENTER_TIMER
717         SAVE_ALL_ASYNC __LC_EXT_OLD_PSW,__LC_SAVE_AREA+40
718         CREATE_STACK_FRAME __LC_SAVE_AREA+40
719         mvc     SP_PSW(16,%r15),0(%r12) # move user PSW to stack
720         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
721         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
722         jz      ext_no_vtime
723         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
724         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
725         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
726         LAST_BREAK
727 ext_no_vtime:
728         HANDLE_SIE_INTERCEPT
729         TRACE_IRQS_OFF
730         lghi    %r1,4096
731         la      %r2,SP_PTREGS(%r15)     # address of register-save area
732         llgf    %r3,__LC_CPU_ADDRESS    # get cpu address + interruption code
733         llgf    %r4,__LC_EXT_PARAMS     # get external parameter
734         lg      %r5,__LC_EXT_PARAMS2-4096(%r1)  # get 64 bit external parameter
735         brasl   %r14,do_extint
736         j       io_return
737
738 __critical_end:
739
740 /*
741  * Machine check handler routines
742  */
743         .globl mcck_int_handler
744 mcck_int_handler:
745         stck    __LC_MCCK_CLOCK
746         la      %r1,4095                # revalidate r1
747         spt     __LC_CPU_TIMER_SAVE_AREA-4095(%r1)      # revalidate cpu timer
748         lmg     %r0,%r15,__LC_GPREGS_SAVE_AREA-4095(%r1)# revalidate gprs
749         stmg    %r11,%r15,__LC_SAVE_AREA+80
750         larl    %r13,system_call
751         lg      %r11,__LC_LAST_BREAK
752         la      %r12,__LC_MCK_OLD_PSW
753         tm      __LC_MCCK_CODE,0x80     # system damage?
754         jo      mcck_int_main           # yes -> rest of mcck code invalid
755         la      %r14,4095
756         mvc     __LC_MCCK_ENTER_TIMER(8),__LC_CPU_TIMER_SAVE_AREA-4095(%r14)
757         tm      __LC_MCCK_CODE+5,0x02   # stored cpu timer value valid?
758         jo      1f
759         la      %r14,__LC_SYNC_ENTER_TIMER
760         clc     0(8,%r14),__LC_ASYNC_ENTER_TIMER
761         jl      0f
762         la      %r14,__LC_ASYNC_ENTER_TIMER
763 0:      clc     0(8,%r14),__LC_EXIT_TIMER
764         jl      0f
765         la      %r14,__LC_EXIT_TIMER
766 0:      clc     0(8,%r14),__LC_LAST_UPDATE_TIMER
767         jl      0f
768         la      %r14,__LC_LAST_UPDATE_TIMER
769 0:      spt     0(%r14)
770         mvc     __LC_MCCK_ENTER_TIMER(8),0(%r14)
771 1:      tm      __LC_MCCK_CODE+2,0x09   # mwp + ia of old psw valid?
772         jno     mcck_int_main           # no -> skip cleanup critical
773         tm      __LC_MCK_OLD_PSW+1,0x01 # test problem state bit
774         jnz     mcck_int_main           # from user -> load kernel stack
775         clc     __LC_MCK_OLD_PSW+8(8),BASED(.Lcritical_end)
776         jhe     mcck_int_main
777         clc     __LC_MCK_OLD_PSW+8(8),BASED(.Lcritical_start)
778         jl      mcck_int_main
779         brasl   %r14,cleanup_critical
780 mcck_int_main:
781         lg      %r14,__LC_PANIC_STACK   # are we already on the panic stack?
782         slgr    %r14,%r15
783         srag    %r14,%r14,PAGE_SHIFT
784         jz      0f
785         lg      %r15,__LC_PANIC_STACK   # load panic stack
786 0:      aghi    %r15,-SP_SIZE           # make room for registers & psw
787         CREATE_STACK_FRAME __LC_SAVE_AREA+80
788         mvc     SP_PSW(16,%r15),0(%r12)
789         lg      %r12,__LC_THREAD_INFO   # load pointer to thread_info struct
790         tm      __LC_MCCK_CODE+2,0x08   # mwp of old psw valid?
791         jno     mcck_no_vtime           # no -> no timer update
792         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
793         jz      mcck_no_vtime
794         UPDATE_VTIME __LC_EXIT_TIMER,__LC_MCCK_ENTER_TIMER,__LC_USER_TIMER
795         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
796         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_MCCK_ENTER_TIMER
797         LAST_BREAK
798 mcck_no_vtime:
799         la      %r2,SP_PTREGS(%r15)     # load pt_regs
800         brasl   %r14,s390_do_machine_check
801         tm      SP_PSW+1(%r15),0x01     # returning to user ?
802         jno     mcck_return
803         lg      %r1,__LC_KERNEL_STACK   # switch to kernel stack
804         aghi    %r1,-SP_SIZE
805         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
806         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1) # clear back chain
807         lgr     %r15,%r1
808         stosm   __SF_EMPTY(%r15),0x04   # turn dat on
809         tm      __TI_flags+7(%r12),_TIF_MCCK_PENDING
810         jno     mcck_return
811         HANDLE_SIE_INTERCEPT
812         TRACE_IRQS_OFF
813         brasl   %r14,s390_handle_mcck
814         TRACE_IRQS_ON
815 mcck_return:
816         mvc     __LC_RETURN_MCCK_PSW(16),SP_PSW(%r15) # move return PSW
817         ni      __LC_RETURN_MCCK_PSW+1,0xfd # clear wait state bit
818         lmg     %r0,%r15,SP_R0(%r15)    # load gprs 0-15
819         tm      __LC_RETURN_MCCK_PSW+1,0x01 # returning to user ?
820         jno     0f
821         stpt    __LC_EXIT_TIMER
822 0:      lpswe   __LC_RETURN_MCCK_PSW    # back to caller
823 mcck_done:
824
825 /*
826  * Restart interruption handler, kick starter for additional CPUs
827  */
828 #ifdef CONFIG_SMP
829         __CPUINIT
830         .globl restart_int_handler
831 restart_int_handler:
832         basr    %r1,0
833 restart_base:
834         spt     restart_vtime-restart_base(%r1)
835         stck    __LC_LAST_UPDATE_CLOCK
836         mvc     __LC_LAST_UPDATE_TIMER(8),restart_vtime-restart_base(%r1)
837         mvc     __LC_EXIT_TIMER(8),restart_vtime-restart_base(%r1)
838         lg      %r15,__LC_SAVE_AREA+120 # load ksp
839         lghi    %r10,__LC_CREGS_SAVE_AREA
840         lctlg   %c0,%c15,0(%r10) # get new ctl regs
841         lghi    %r10,__LC_AREGS_SAVE_AREA
842         lam     %a0,%a15,0(%r10)
843         lmg     %r6,%r15,__SF_GPRS(%r15) # load registers from clone
844         lg      %r1,__LC_THREAD_INFO
845         mvc     __LC_USER_TIMER(8),__TI_user_timer(%r1)
846         mvc     __LC_SYSTEM_TIMER(8),__TI_system_timer(%r1)
847         xc      __LC_STEAL_TIMER(8),__LC_STEAL_TIMER
848         stosm   __SF_EMPTY(%r15),0x04   # now we can turn dat on
849         jg      start_secondary
850         .align  8
851 restart_vtime:
852         .long   0x7fffffff,0xffffffff
853         .previous
854 #else
855 /*
856  * If we do not run with SMP enabled, let the new CPU crash ...
857  */
858         .globl restart_int_handler
859 restart_int_handler:
860         basr    %r1,0
861 restart_base:
862         lpswe   restart_crash-restart_base(%r1)
863         .align 8
864 restart_crash:
865         .long  0x000a0000,0x00000000,0x00000000,0x00000000
866 restart_go:
867 #endif
868
869 #ifdef CONFIG_CHECK_STACK
870 /*
871  * The synchronous or the asynchronous stack overflowed. We are dead.
872  * No need to properly save the registers, we are going to panic anyway.
873  * Setup a pt_regs so that show_trace can provide a good call trace.
874  */
875 stack_overflow:
876         lg      %r15,__LC_PANIC_STACK   # change to panic stack
877         aghi    %r15,-SP_SIZE
878         mvc     SP_PSW(16,%r15),0(%r12) # move user PSW to stack
879         stmg    %r0,%r10,SP_R0(%r15)    # store gprs %r0-%r10 to kernel stack
880         la      %r1,__LC_SAVE_AREA
881         chi     %r12,__LC_SVC_OLD_PSW
882         je      0f
883         chi     %r12,__LC_PGM_OLD_PSW
884         je      0f
885         la      %r1,__LC_SAVE_AREA+40
886 0:      mvc     SP_R11(40,%r15),0(%r1)  # move %r11-%r15 to stack
887         mvc     SP_ARGS(8,%r15),__LC_LAST_BREAK
888         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15) # clear back chain
889         la      %r2,SP_PTREGS(%r15)     # load pt_regs
890         jg      kernel_stack_overflow
891 #endif
892
893 cleanup_table_system_call:
894         .quad   system_call, sysc_do_svc
895 cleanup_table_sysc_tif:
896         .quad   sysc_tif, sysc_restore
897 cleanup_table_sysc_restore:
898         .quad   sysc_restore, sysc_done
899 cleanup_table_io_tif:
900         .quad   io_tif, io_restore
901 cleanup_table_io_restore:
902         .quad   io_restore, io_done
903
904 cleanup_critical:
905         clc     8(8,%r12),BASED(cleanup_table_system_call)
906         jl      0f
907         clc     8(8,%r12),BASED(cleanup_table_system_call+8)
908         jl      cleanup_system_call
909 0:
910         clc     8(8,%r12),BASED(cleanup_table_sysc_tif)
911         jl      0f
912         clc     8(8,%r12),BASED(cleanup_table_sysc_tif+8)
913         jl      cleanup_sysc_tif
914 0:
915         clc     8(8,%r12),BASED(cleanup_table_sysc_restore)
916         jl      0f
917         clc     8(8,%r12),BASED(cleanup_table_sysc_restore+8)
918         jl      cleanup_sysc_restore
919 0:
920         clc     8(8,%r12),BASED(cleanup_table_io_tif)
921         jl      0f
922         clc     8(8,%r12),BASED(cleanup_table_io_tif+8)
923         jl      cleanup_io_tif
924 0:
925         clc     8(8,%r12),BASED(cleanup_table_io_restore)
926         jl      0f
927         clc     8(8,%r12),BASED(cleanup_table_io_restore+8)
928         jl      cleanup_io_restore
929 0:
930         br      %r14
931
932 cleanup_system_call:
933         mvc     __LC_RETURN_PSW(16),0(%r12)
934         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+8)
935         jh      0f
936         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_MCCK_ENTER_TIMER
937         cghi    %r12,__LC_MCK_OLD_PSW
938         je      0f
939         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_ASYNC_ENTER_TIMER
940 0:      cghi    %r12,__LC_MCK_OLD_PSW
941         la      %r12,__LC_SAVE_AREA+80
942         je      0f
943         la      %r12,__LC_SAVE_AREA+40
944 0:      clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+16)
945         jhe     cleanup_vtime
946         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn)
947         jh      0f
948         mvc     __LC_SAVE_AREA(40),0(%r12)
949 0:      lg      %r15,__LC_KERNEL_STACK  # problem state -> load ksp
950         aghi    %r15,-SP_SIZE           # make room for registers & psw
951         stg     %r15,32(%r12)
952         stg     %r11,0(%r12)
953         CREATE_STACK_FRAME __LC_SAVE_AREA
954         mvc     SP_PSW(16,%r15),__LC_SVC_OLD_PSW
955         mvc     SP_ILC(4,%r15),__LC_SVC_ILC
956         stg     %r7,SP_ARGS(%r15)
957         mvc     8(8,%r12),__LC_THREAD_INFO
958 cleanup_vtime:
959         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+24)
960         jhe     cleanup_stime
961         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
962 cleanup_stime:
963         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+32)
964         jh      cleanup_update
965         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
966 cleanup_update:
967         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
968         srag    %r12,%r11,23
969         lg      %r12,__LC_THREAD_INFO
970         jz      0f
971         stg     %r11,__TI_last_break(%r12)
972 0:      mvc     __LC_RETURN_PSW+8(8),BASED(cleanup_table_system_call+8)
973         la      %r12,__LC_RETURN_PSW
974         br      %r14
975 cleanup_system_call_insn:
976         .quad   sysc_saveall
977         .quad   system_call
978         .quad   sysc_vtime
979         .quad   sysc_stime
980         .quad   sysc_update
981
982 cleanup_sysc_tif:
983         mvc     __LC_RETURN_PSW(8),0(%r12)
984         mvc     __LC_RETURN_PSW+8(8),BASED(cleanup_table_sysc_tif)
985         la      %r12,__LC_RETURN_PSW
986         br      %r14
987
988 cleanup_sysc_restore:
989         clc     8(8,%r12),BASED(cleanup_sysc_restore_insn)
990         je      2f
991         clc     8(8,%r12),BASED(cleanup_sysc_restore_insn+8)
992         jhe     0f
993         mvc     __LC_EXIT_TIMER(8),__LC_MCCK_ENTER_TIMER
994         cghi    %r12,__LC_MCK_OLD_PSW
995         je      0f
996         mvc     __LC_EXIT_TIMER(8),__LC_ASYNC_ENTER_TIMER
997 0:      mvc     __LC_RETURN_PSW(16),SP_PSW(%r15)
998         cghi    %r12,__LC_MCK_OLD_PSW
999         la      %r12,__LC_SAVE_AREA+80
1000         je      1f
1001         la      %r12,__LC_SAVE_AREA+40
1002 1:      mvc     0(40,%r12),SP_R11(%r15)
1003         lmg     %r0,%r10,SP_R0(%r15)
1004         lg      %r15,SP_R15(%r15)
1005 2:      la      %r12,__LC_RETURN_PSW
1006         br      %r14
1007 cleanup_sysc_restore_insn:
1008         .quad   sysc_done - 4
1009         .quad   sysc_done - 16
1010
1011 cleanup_io_tif:
1012         mvc     __LC_RETURN_PSW(8),0(%r12)
1013         mvc     __LC_RETURN_PSW+8(8),BASED(cleanup_table_io_tif)
1014         la      %r12,__LC_RETURN_PSW
1015         br      %r14
1016
1017 cleanup_io_restore:
1018         clc     8(8,%r12),BASED(cleanup_io_restore_insn)
1019         je      1f
1020         clc     8(8,%r12),BASED(cleanup_io_restore_insn+8)
1021         jhe     0f
1022         mvc     __LC_EXIT_TIMER(8),__LC_MCCK_ENTER_TIMER
1023 0:      mvc     __LC_RETURN_PSW(16),SP_PSW(%r15)
1024         mvc     __LC_SAVE_AREA+80(40),SP_R11(%r15)
1025         lmg     %r0,%r10,SP_R0(%r15)
1026         lg      %r15,SP_R15(%r15)
1027 1:      la      %r12,__LC_RETURN_PSW
1028         br      %r14
1029 cleanup_io_restore_insn:
1030         .quad   io_done - 4
1031         .quad   io_done - 16
1032
1033 /*
1034  * Integer constants
1035  */
1036                 .align  4
1037 .Lcritical_start:
1038                 .quad   __critical_start
1039 .Lcritical_end:
1040                 .quad   __critical_end
1041
1042                 .section .rodata, "a"
1043 #define SYSCALL(esa,esame,emu)  .long esame
1044         .globl  sys_call_table
1045 sys_call_table:
1046 #include "syscalls.S"
1047 #undef SYSCALL
1048
1049 #ifdef CONFIG_COMPAT
1050
1051 #define SYSCALL(esa,esame,emu)  .long emu
1052 sys_call_table_emu:
1053 #include "syscalls.S"
1054 #undef SYSCALL
1055 #endif