]> git.openfabrics.org - ~shefty/rdma-dev.git/blob - arch/x86/kernel/entry_64.S
x86-64: Use symbolics instead of raw numbers in entry_64.S
[~shefty/rdma-dev.git] / arch / x86 / kernel / entry_64.S
1 /*
2  *  linux/arch/x86_64/entry.S
3  *
4  *  Copyright (C) 1991, 1992  Linus Torvalds
5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
7  */
8
9 /*
10  * entry.S contains the system-call and fault low-level handling routines.
11  *
12  * NOTE: This code handles signal-recognition, which happens every time
13  * after an interrupt and after each system call.
14  *
15  * Normal syscalls and interrupts don't save a full stack frame, this is
16  * only done for syscall tracing, signals or fork/exec et.al.
17  *
18  * A note on terminology:
19  * - top of stack: Architecture defined interrupt frame from SS to RIP
20  * at the top of the kernel process stack.
21  * - partial stack frame: partially saved registers upto R11.
22  * - full stack frame: Like partial stack frame, but all register saved.
23  *
24  * Some macro usage:
25  * - CFI macros are used to generate dwarf2 unwind information for better
26  * backtraces. They don't change any code.
27  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
28  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
29  * There are unfortunately lots of special cases where some registers
30  * not touched. The macro is a big mess that should be cleaned up.
31  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
32  * Gives a full stack frame.
33  * - ENTRY/END Define functions in the symbol table.
34  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
35  * frame that is otherwise undefined after a SYSCALL
36  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
37  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
38  */
39
40 #include <linux/linkage.h>
41 #include <asm/segment.h>
42 #include <asm/cache.h>
43 #include <asm/errno.h>
44 #include <asm/dwarf2.h>
45 #include <asm/calling.h>
46 #include <asm/asm-offsets.h>
47 #include <asm/msr.h>
48 #include <asm/unistd.h>
49 #include <asm/thread_info.h>
50 #include <asm/hw_irq.h>
51 #include <asm/page_types.h>
52 #include <asm/irqflags.h>
53 #include <asm/paravirt.h>
54 #include <asm/ftrace.h>
55 #include <asm/percpu.h>
56
57 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
58 #include <linux/elf-em.h>
59 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
60 #define __AUDIT_ARCH_64BIT 0x80000000
61 #define __AUDIT_ARCH_LE    0x40000000
62
63         .code64
64 #ifdef CONFIG_FUNCTION_TRACER
65 #ifdef CONFIG_DYNAMIC_FTRACE
66 ENTRY(mcount)
67         retq
68 END(mcount)
69
70 ENTRY(ftrace_caller)
71         cmpl $0, function_trace_stop
72         jne  ftrace_stub
73
74         MCOUNT_SAVE_FRAME
75
76         movq 0x38(%rsp), %rdi
77         movq 8(%rbp), %rsi
78         subq $MCOUNT_INSN_SIZE, %rdi
79
80 GLOBAL(ftrace_call)
81         call ftrace_stub
82
83         MCOUNT_RESTORE_FRAME
84
85 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
86 GLOBAL(ftrace_graph_call)
87         jmp ftrace_stub
88 #endif
89
90 GLOBAL(ftrace_stub)
91         retq
92 END(ftrace_caller)
93
94 #else /* ! CONFIG_DYNAMIC_FTRACE */
95 ENTRY(mcount)
96         cmpl $0, function_trace_stop
97         jne  ftrace_stub
98
99         cmpq $ftrace_stub, ftrace_trace_function
100         jnz trace
101
102 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
103         cmpq $ftrace_stub, ftrace_graph_return
104         jnz ftrace_graph_caller
105
106         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
107         jnz ftrace_graph_caller
108 #endif
109
110 GLOBAL(ftrace_stub)
111         retq
112
113 trace:
114         MCOUNT_SAVE_FRAME
115
116         movq 0x38(%rsp), %rdi
117         movq 8(%rbp), %rsi
118         subq $MCOUNT_INSN_SIZE, %rdi
119
120         call   *ftrace_trace_function
121
122         MCOUNT_RESTORE_FRAME
123
124         jmp ftrace_stub
125 END(mcount)
126 #endif /* CONFIG_DYNAMIC_FTRACE */
127 #endif /* CONFIG_FUNCTION_TRACER */
128
129 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
130 ENTRY(ftrace_graph_caller)
131         cmpl $0, function_trace_stop
132         jne ftrace_stub
133
134         MCOUNT_SAVE_FRAME
135
136         leaq 8(%rbp), %rdi
137         movq 0x38(%rsp), %rsi
138         movq (%rbp), %rdx
139         subq $MCOUNT_INSN_SIZE, %rsi
140
141         call    prepare_ftrace_return
142
143         MCOUNT_RESTORE_FRAME
144
145         retq
146 END(ftrace_graph_caller)
147
148 GLOBAL(return_to_handler)
149         subq  $24, %rsp
150
151         /* Save the return values */
152         movq %rax, (%rsp)
153         movq %rdx, 8(%rsp)
154         movq %rbp, %rdi
155
156         call ftrace_return_to_handler
157
158         movq %rax, %rdi
159         movq 8(%rsp), %rdx
160         movq (%rsp), %rax
161         addq $24, %rsp
162         jmp *%rdi
163 #endif
164
165
166 #ifndef CONFIG_PREEMPT
167 #define retint_kernel retint_restore_args
168 #endif
169
170 #ifdef CONFIG_PARAVIRT
171 ENTRY(native_usergs_sysret64)
172         swapgs
173         sysretq
174 ENDPROC(native_usergs_sysret64)
175 #endif /* CONFIG_PARAVIRT */
176
177
178 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
179 #ifdef CONFIG_TRACE_IRQFLAGS
180         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
181         jnc  1f
182         TRACE_IRQS_ON
183 1:
184 #endif
185 .endm
186
187 /*
188  * C code is not supposed to know about undefined top of stack. Every time
189  * a C function with an pt_regs argument is called from the SYSCALL based
190  * fast path FIXUP_TOP_OF_STACK is needed.
191  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
192  * manipulation.
193  */
194
195         /* %rsp:at FRAMEEND */
196         .macro FIXUP_TOP_OF_STACK tmp offset=0
197         movq PER_CPU_VAR(old_rsp),\tmp
198         movq \tmp,RSP+\offset(%rsp)
199         movq $__USER_DS,SS+\offset(%rsp)
200         movq $__USER_CS,CS+\offset(%rsp)
201         movq $-1,RCX+\offset(%rsp)
202         movq R11+\offset(%rsp),\tmp  /* get eflags */
203         movq \tmp,EFLAGS+\offset(%rsp)
204         .endm
205
206         .macro RESTORE_TOP_OF_STACK tmp offset=0
207         movq RSP+\offset(%rsp),\tmp
208         movq \tmp,PER_CPU_VAR(old_rsp)
209         movq EFLAGS+\offset(%rsp),\tmp
210         movq \tmp,R11+\offset(%rsp)
211         .endm
212
213         .macro FAKE_STACK_FRAME child_rip
214         /* push in order ss, rsp, eflags, cs, rip */
215         xorl %eax, %eax
216         pushq $__KERNEL_DS /* ss */
217         CFI_ADJUST_CFA_OFFSET   8
218         /*CFI_REL_OFFSET        ss,0*/
219         pushq %rax /* rsp */
220         CFI_ADJUST_CFA_OFFSET   8
221         CFI_REL_OFFSET  rsp,0
222         pushq $X86_EFLAGS_IF /* eflags - interrupts on */
223         CFI_ADJUST_CFA_OFFSET   8
224         /*CFI_REL_OFFSET        rflags,0*/
225         pushq $__KERNEL_CS /* cs */
226         CFI_ADJUST_CFA_OFFSET   8
227         /*CFI_REL_OFFSET        cs,0*/
228         pushq \child_rip /* rip */
229         CFI_ADJUST_CFA_OFFSET   8
230         CFI_REL_OFFSET  rip,0
231         pushq   %rax /* orig rax */
232         CFI_ADJUST_CFA_OFFSET   8
233         .endm
234
235         .macro UNFAKE_STACK_FRAME
236         addq $8*6, %rsp
237         CFI_ADJUST_CFA_OFFSET   -(6*8)
238         .endm
239
240 /*
241  * initial frame state for interrupts (and exceptions without error code)
242  */
243         .macro EMPTY_FRAME start=1 offset=0
244         .if \start
245         CFI_STARTPROC simple
246         CFI_SIGNAL_FRAME
247         CFI_DEF_CFA rsp,8+\offset
248         .else
249         CFI_DEF_CFA_OFFSET 8+\offset
250         .endif
251         .endm
252
253 /*
254  * initial frame state for interrupts (and exceptions without error code)
255  */
256         .macro INTR_FRAME start=1 offset=0
257         EMPTY_FRAME \start, SS+8+\offset-RIP
258         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
259         CFI_REL_OFFSET rsp, RSP+\offset-RIP
260         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
261         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
262         CFI_REL_OFFSET rip, RIP+\offset-RIP
263         .endm
264
265 /*
266  * initial frame state for exceptions with error code (and interrupts
267  * with vector already pushed)
268  */
269         .macro XCPT_FRAME start=1 offset=0
270         INTR_FRAME \start, RIP+\offset-ORIG_RAX
271         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
272         .endm
273
274 /*
275  * frame that enables calling into C.
276  */
277         .macro PARTIAL_FRAME start=1 offset=0
278         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
279         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
280         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
281         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
282         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
283         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
284         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
285         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
286         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
287         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
288         .endm
289
290 /*
291  * frame that enables passing a complete pt_regs to a C function.
292  */
293         .macro DEFAULT_FRAME start=1 offset=0
294         PARTIAL_FRAME \start, R11+\offset-R15
295         CFI_REL_OFFSET rbx, RBX+\offset
296         CFI_REL_OFFSET rbp, RBP+\offset
297         CFI_REL_OFFSET r12, R12+\offset
298         CFI_REL_OFFSET r13, R13+\offset
299         CFI_REL_OFFSET r14, R14+\offset
300         CFI_REL_OFFSET r15, R15+\offset
301         .endm
302
303 /* save partial stack frame */
304 ENTRY(save_args)
305         XCPT_FRAME
306         cld
307         movq_cfi rdi, RDI+16-ARGOFFSET
308         movq_cfi rsi, RSI+16-ARGOFFSET
309         movq_cfi rdx, RDX+16-ARGOFFSET
310         movq_cfi rcx, RCX+16-ARGOFFSET
311         movq_cfi rax, RAX+16-ARGOFFSET
312         movq_cfi  r8,  R8+16-ARGOFFSET
313         movq_cfi  r9,  R9+16-ARGOFFSET
314         movq_cfi r10, R10+16-ARGOFFSET
315         movq_cfi r11, R11+16-ARGOFFSET
316
317         leaq -ARGOFFSET+16(%rsp),%rdi   /* arg1 for handler */
318         movq_cfi rbp, 8         /* push %rbp */
319         leaq 8(%rsp), %rbp              /* mov %rsp, %ebp */
320         testl $3, CS(%rdi)
321         je 1f
322         SWAPGS
323         /*
324          * irq_count is used to check if a CPU is already on an interrupt stack
325          * or not. While this is essentially redundant with preempt_count it is
326          * a little cheaper to use a separate counter in the PDA (short of
327          * moving irq_enter into assembly, which would be too much work)
328          */
329 1:      incl PER_CPU_VAR(irq_count)
330         jne 2f
331         popq_cfi %rax                   /* move return address... */
332         mov PER_CPU_VAR(irq_stack_ptr),%rsp
333         EMPTY_FRAME 0
334         pushq_cfi %rbp                  /* backlink for unwinder */
335         pushq_cfi %rax                  /* ... to the new stack */
336         /*
337          * We entered an interrupt context - irqs are off:
338          */
339 2:      TRACE_IRQS_OFF
340         ret
341         CFI_ENDPROC
342 END(save_args)
343
344 ENTRY(save_rest)
345         PARTIAL_FRAME 1 REST_SKIP+8
346         movq 5*8+16(%rsp), %r11 /* save return address */
347         movq_cfi rbx, RBX+16
348         movq_cfi rbp, RBP+16
349         movq_cfi r12, R12+16
350         movq_cfi r13, R13+16
351         movq_cfi r14, R14+16
352         movq_cfi r15, R15+16
353         movq %r11, 8(%rsp)      /* return address */
354         FIXUP_TOP_OF_STACK %r11, 16
355         ret
356         CFI_ENDPROC
357 END(save_rest)
358
359 /* save complete stack frame */
360         .pushsection .kprobes.text, "ax"
361 ENTRY(save_paranoid)
362         XCPT_FRAME 1 RDI+8
363         cld
364         movq_cfi rdi, RDI+8
365         movq_cfi rsi, RSI+8
366         movq_cfi rdx, RDX+8
367         movq_cfi rcx, RCX+8
368         movq_cfi rax, RAX+8
369         movq_cfi r8, R8+8
370         movq_cfi r9, R9+8
371         movq_cfi r10, R10+8
372         movq_cfi r11, R11+8
373         movq_cfi rbx, RBX+8
374         movq_cfi rbp, RBP+8
375         movq_cfi r12, R12+8
376         movq_cfi r13, R13+8
377         movq_cfi r14, R14+8
378         movq_cfi r15, R15+8
379         movl $1,%ebx
380         movl $MSR_GS_BASE,%ecx
381         rdmsr
382         testl %edx,%edx
383         js 1f   /* negative -> in kernel */
384         SWAPGS
385         xorl %ebx,%ebx
386 1:      ret
387         CFI_ENDPROC
388 END(save_paranoid)
389         .popsection
390
391 /*
392  * A newly forked process directly context switches into this address.
393  *
394  * rdi: prev task we switched from
395  */
396 ENTRY(ret_from_fork)
397         DEFAULT_FRAME
398
399         LOCK ; btr $TIF_FORK,TI_flags(%r8)
400
401         push kernel_eflags(%rip)
402         CFI_ADJUST_CFA_OFFSET 8
403         popf                                    # reset kernel eflags
404         CFI_ADJUST_CFA_OFFSET -8
405
406         call schedule_tail                      # rdi: 'prev' task parameter
407
408         GET_THREAD_INFO(%rcx)
409
410         RESTORE_REST
411
412         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
413         je   int_ret_from_sys_call
414
415         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
416         jnz  int_ret_from_sys_call
417
418         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
419         jmp ret_from_sys_call                   # go to the SYSRET fastpath
420
421         CFI_ENDPROC
422 END(ret_from_fork)
423
424 /*
425  * System call entry. Upto 6 arguments in registers are supported.
426  *
427  * SYSCALL does not save anything on the stack and does not change the
428  * stack pointer.
429  */
430
431 /*
432  * Register setup:
433  * rax  system call number
434  * rdi  arg0
435  * rcx  return address for syscall/sysret, C arg3
436  * rsi  arg1
437  * rdx  arg2
438  * r10  arg3    (--> moved to rcx for C)
439  * r8   arg4
440  * r9   arg5
441  * r11  eflags for syscall/sysret, temporary for C
442  * r12-r15,rbp,rbx saved by C code, not touched.
443  *
444  * Interrupts are off on entry.
445  * Only called from user space.
446  *
447  * XXX  if we had a free scratch register we could save the RSP into the stack frame
448  *      and report it properly in ps. Unfortunately we haven't.
449  *
450  * When user can change the frames always force IRET. That is because
451  * it deals with uncanonical addresses better. SYSRET has trouble
452  * with them due to bugs in both AMD and Intel CPUs.
453  */
454
455 ENTRY(system_call)
456         CFI_STARTPROC   simple
457         CFI_SIGNAL_FRAME
458         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
459         CFI_REGISTER    rip,rcx
460         /*CFI_REGISTER  rflags,r11*/
461         SWAPGS_UNSAFE_STACK
462         /*
463          * A hypervisor implementation might want to use a label
464          * after the swapgs, so that it can do the swapgs
465          * for the guest and jump here on syscall.
466          */
467 ENTRY(system_call_after_swapgs)
468
469         movq    %rsp,PER_CPU_VAR(old_rsp)
470         movq    PER_CPU_VAR(kernel_stack),%rsp
471         /*
472          * No need to follow this irqs off/on section - it's straight
473          * and short:
474          */
475         ENABLE_INTERRUPTS(CLBR_NONE)
476         SAVE_ARGS 8,1
477         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
478         movq  %rcx,RIP-ARGOFFSET(%rsp)
479         CFI_REL_OFFSET rip,RIP-ARGOFFSET
480         GET_THREAD_INFO(%rcx)
481         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%rcx)
482         jnz tracesys
483 system_call_fastpath:
484         cmpq $__NR_syscall_max,%rax
485         ja badsys
486         movq %r10,%rcx
487         call *sys_call_table(,%rax,8)  # XXX:    rip relative
488         movq %rax,RAX-ARGOFFSET(%rsp)
489 /*
490  * Syscall return path ending with SYSRET (fast path)
491  * Has incomplete stack frame and undefined top of stack.
492  */
493 ret_from_sys_call:
494         movl $_TIF_ALLWORK_MASK,%edi
495         /* edi: flagmask */
496 sysret_check:
497         LOCKDEP_SYS_EXIT
498         GET_THREAD_INFO(%rcx)
499         DISABLE_INTERRUPTS(CLBR_NONE)
500         TRACE_IRQS_OFF
501         movl TI_flags(%rcx),%edx
502         andl %edi,%edx
503         jnz  sysret_careful
504         CFI_REMEMBER_STATE
505         /*
506          * sysretq will re-enable interrupts:
507          */
508         TRACE_IRQS_ON
509         movq RIP-ARGOFFSET(%rsp),%rcx
510         CFI_REGISTER    rip,rcx
511         RESTORE_ARGS 0,-ARG_SKIP,1
512         /*CFI_REGISTER  rflags,r11*/
513         movq    PER_CPU_VAR(old_rsp), %rsp
514         USERGS_SYSRET64
515
516         CFI_RESTORE_STATE
517         /* Handle reschedules */
518         /* edx: work, edi: workmask */
519 sysret_careful:
520         bt $TIF_NEED_RESCHED,%edx
521         jnc sysret_signal
522         TRACE_IRQS_ON
523         ENABLE_INTERRUPTS(CLBR_NONE)
524         pushq %rdi
525         CFI_ADJUST_CFA_OFFSET 8
526         call schedule
527         popq  %rdi
528         CFI_ADJUST_CFA_OFFSET -8
529         jmp sysret_check
530
531         /* Handle a signal */
532 sysret_signal:
533         TRACE_IRQS_ON
534         ENABLE_INTERRUPTS(CLBR_NONE)
535 #ifdef CONFIG_AUDITSYSCALL
536         bt $TIF_SYSCALL_AUDIT,%edx
537         jc sysret_audit
538 #endif
539         /*
540          * We have a signal, or exit tracing or single-step.
541          * These all wind up with the iret return path anyway,
542          * so just join that path right now.
543          */
544         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
545         jmp int_check_syscall_exit_work
546
547 badsys:
548         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
549         jmp ret_from_sys_call
550
551 #ifdef CONFIG_AUDITSYSCALL
552         /*
553          * Fast path for syscall audit without full syscall trace.
554          * We just call audit_syscall_entry() directly, and then
555          * jump back to the normal fast path.
556          */
557 auditsys:
558         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
559         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
560         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
561         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
562         movq %rax,%rsi                  /* 2nd arg: syscall number */
563         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
564         call audit_syscall_entry
565         LOAD_ARGS 0             /* reload call-clobbered registers */
566         jmp system_call_fastpath
567
568         /*
569          * Return fast path for syscall audit.  Call audit_syscall_exit()
570          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
571          * masked off.
572          */
573 sysret_audit:
574         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
575         cmpq $0,%rsi            /* is it < 0? */
576         setl %al                /* 1 if so, 0 if not */
577         movzbl %al,%edi         /* zero-extend that into %edi */
578         inc %edi /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
579         call audit_syscall_exit
580         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
581         jmp sysret_check
582 #endif  /* CONFIG_AUDITSYSCALL */
583
584         /* Do syscall tracing */
585 tracesys:
586 #ifdef CONFIG_AUDITSYSCALL
587         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%rcx)
588         jz auditsys
589 #endif
590         SAVE_REST
591         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
592         FIXUP_TOP_OF_STACK %rdi
593         movq %rsp,%rdi
594         call syscall_trace_enter
595         /*
596          * Reload arg registers from stack in case ptrace changed them.
597          * We don't reload %rax because syscall_trace_enter() returned
598          * the value it wants us to use in the table lookup.
599          */
600         LOAD_ARGS ARGOFFSET, 1
601         RESTORE_REST
602         cmpq $__NR_syscall_max,%rax
603         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
604         movq %r10,%rcx  /* fixup for C */
605         call *sys_call_table(,%rax,8)
606         movq %rax,RAX-ARGOFFSET(%rsp)
607         /* Use IRET because user could have changed frame */
608
609 /*
610  * Syscall return path ending with IRET.
611  * Has correct top of stack, but partial stack frame.
612  */
613 GLOBAL(int_ret_from_sys_call)
614         DISABLE_INTERRUPTS(CLBR_NONE)
615         TRACE_IRQS_OFF
616         testl $3,CS-ARGOFFSET(%rsp)
617         je retint_restore_args
618         movl $_TIF_ALLWORK_MASK,%edi
619         /* edi: mask to check */
620 GLOBAL(int_with_check)
621         LOCKDEP_SYS_EXIT_IRQ
622         GET_THREAD_INFO(%rcx)
623         movl TI_flags(%rcx),%edx
624         andl %edi,%edx
625         jnz   int_careful
626         andl    $~TS_COMPAT,TI_status(%rcx)
627         jmp   retint_swapgs
628
629         /* Either reschedule or signal or syscall exit tracking needed. */
630         /* First do a reschedule test. */
631         /* edx: work, edi: workmask */
632 int_careful:
633         bt $TIF_NEED_RESCHED,%edx
634         jnc  int_very_careful
635         TRACE_IRQS_ON
636         ENABLE_INTERRUPTS(CLBR_NONE)
637         pushq %rdi
638         CFI_ADJUST_CFA_OFFSET 8
639         call schedule
640         popq %rdi
641         CFI_ADJUST_CFA_OFFSET -8
642         DISABLE_INTERRUPTS(CLBR_NONE)
643         TRACE_IRQS_OFF
644         jmp int_with_check
645
646         /* handle signals and tracing -- both require a full stack frame */
647 int_very_careful:
648         TRACE_IRQS_ON
649         ENABLE_INTERRUPTS(CLBR_NONE)
650 int_check_syscall_exit_work:
651         SAVE_REST
652         /* Check for syscall exit trace */
653         testl $_TIF_WORK_SYSCALL_EXIT,%edx
654         jz int_signal
655         pushq %rdi
656         CFI_ADJUST_CFA_OFFSET 8
657         leaq 8(%rsp),%rdi       # &ptregs -> arg1
658         call syscall_trace_leave
659         popq %rdi
660         CFI_ADJUST_CFA_OFFSET -8
661         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
662         jmp int_restore_rest
663
664 int_signal:
665         testl $_TIF_DO_NOTIFY_MASK,%edx
666         jz 1f
667         movq %rsp,%rdi          # &ptregs -> arg1
668         xorl %esi,%esi          # oldset -> arg2
669         call do_notify_resume
670 1:      movl $_TIF_WORK_MASK,%edi
671 int_restore_rest:
672         RESTORE_REST
673         DISABLE_INTERRUPTS(CLBR_NONE)
674         TRACE_IRQS_OFF
675         jmp int_with_check
676         CFI_ENDPROC
677 END(system_call)
678
679 /*
680  * Certain special system calls that need to save a complete full stack frame.
681  */
682         .macro PTREGSCALL label,func,arg
683 ENTRY(\label)
684         PARTIAL_FRAME 1 8               /* offset 8: return address */
685         subq $REST_SKIP, %rsp
686         CFI_ADJUST_CFA_OFFSET REST_SKIP
687         call save_rest
688         DEFAULT_FRAME 0 8               /* offset 8: return address */
689         leaq 8(%rsp), \arg      /* pt_regs pointer */
690         call \func
691         jmp ptregscall_common
692         CFI_ENDPROC
693 END(\label)
694         .endm
695
696         PTREGSCALL stub_clone, sys_clone, %r8
697         PTREGSCALL stub_fork, sys_fork, %rdi
698         PTREGSCALL stub_vfork, sys_vfork, %rdi
699         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
700         PTREGSCALL stub_iopl, sys_iopl, %rsi
701
702 ENTRY(ptregscall_common)
703         DEFAULT_FRAME 1 8       /* offset 8: return address */
704         RESTORE_TOP_OF_STACK %r11, 8
705         movq_cfi_restore R15+8, r15
706         movq_cfi_restore R14+8, r14
707         movq_cfi_restore R13+8, r13
708         movq_cfi_restore R12+8, r12
709         movq_cfi_restore RBP+8, rbp
710         movq_cfi_restore RBX+8, rbx
711         ret $REST_SKIP          /* pop extended registers */
712         CFI_ENDPROC
713 END(ptregscall_common)
714
715 ENTRY(stub_execve)
716         CFI_STARTPROC
717         addq $8, %rsp
718         PARTIAL_FRAME 0
719         SAVE_REST
720         FIXUP_TOP_OF_STACK %r11
721         movq %rsp, %rcx
722         call sys_execve
723         RESTORE_TOP_OF_STACK %r11
724         movq %rax,RAX(%rsp)
725         RESTORE_REST
726         jmp int_ret_from_sys_call
727         CFI_ENDPROC
728 END(stub_execve)
729
730 /*
731  * sigreturn is special because it needs to restore all registers on return.
732  * This cannot be done with SYSRET, so use the IRET return path instead.
733  */
734 ENTRY(stub_rt_sigreturn)
735         CFI_STARTPROC
736         addq $8, %rsp
737         PARTIAL_FRAME 0
738         SAVE_REST
739         movq %rsp,%rdi
740         FIXUP_TOP_OF_STACK %r11
741         call sys_rt_sigreturn
742         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
743         RESTORE_REST
744         jmp int_ret_from_sys_call
745         CFI_ENDPROC
746 END(stub_rt_sigreturn)
747
748 /*
749  * Build the entry stubs and pointer table with some assembler magic.
750  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
751  * single cache line on all modern x86 implementations.
752  */
753         .section .init.rodata,"a"
754 ENTRY(interrupt)
755         .text
756         .p2align 5
757         .p2align CONFIG_X86_L1_CACHE_SHIFT
758 ENTRY(irq_entries_start)
759         INTR_FRAME
760 vector=FIRST_EXTERNAL_VECTOR
761 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
762         .balign 32
763   .rept 7
764     .if vector < NR_VECTORS
765       .if vector <> FIRST_EXTERNAL_VECTOR
766         CFI_ADJUST_CFA_OFFSET -8
767       .endif
768 1:      pushq $(~vector+0x80)   /* Note: always in signed byte range */
769         CFI_ADJUST_CFA_OFFSET 8
770       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
771         jmp 2f
772       .endif
773       .previous
774         .quad 1b
775       .text
776 vector=vector+1
777     .endif
778   .endr
779 2:      jmp common_interrupt
780 .endr
781         CFI_ENDPROC
782 END(irq_entries_start)
783
784 .previous
785 END(interrupt)
786 .previous
787
788 /*
789  * Interrupt entry/exit.
790  *
791  * Interrupt entry points save only callee clobbered registers in fast path.
792  *
793  * Entry runs with interrupts off.
794  */
795
796 /* 0(%rsp): ~(interrupt number) */
797         .macro interrupt func
798         subq $ORIG_RAX-ARGOFFSET+8, %rsp
799         CFI_ADJUST_CFA_OFFSET ORIG_RAX-ARGOFFSET+8
800         call save_args
801         PARTIAL_FRAME 0
802         call \func
803         .endm
804
805 /*
806  * Interrupt entry/exit should be protected against kprobes
807  */
808         .pushsection .kprobes.text, "ax"
809         /*
810          * The interrupt stubs push (~vector+0x80) onto the stack and
811          * then jump to common_interrupt.
812          */
813         .p2align CONFIG_X86_L1_CACHE_SHIFT
814 common_interrupt:
815         XCPT_FRAME
816         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
817         interrupt do_IRQ
818         /* 0(%rsp): old_rsp-ARGOFFSET */
819 ret_from_intr:
820         DISABLE_INTERRUPTS(CLBR_NONE)
821         TRACE_IRQS_OFF
822         decl PER_CPU_VAR(irq_count)
823         leaveq
824         CFI_DEF_CFA_REGISTER    rsp
825         CFI_ADJUST_CFA_OFFSET   -8
826 exit_intr:
827         GET_THREAD_INFO(%rcx)
828         testl $3,CS-ARGOFFSET(%rsp)
829         je retint_kernel
830
831         /* Interrupt came from user space */
832         /*
833          * Has a correct top of stack, but a partial stack frame
834          * %rcx: thread info. Interrupts off.
835          */
836 retint_with_reschedule:
837         movl $_TIF_WORK_MASK,%edi
838 retint_check:
839         LOCKDEP_SYS_EXIT_IRQ
840         movl TI_flags(%rcx),%edx
841         andl %edi,%edx
842         CFI_REMEMBER_STATE
843         jnz  retint_careful
844
845 retint_swapgs:          /* return to user-space */
846         /*
847          * The iretq could re-enable interrupts:
848          */
849         DISABLE_INTERRUPTS(CLBR_ANY)
850         TRACE_IRQS_IRETQ
851         SWAPGS
852         jmp restore_args
853
854 retint_restore_args:    /* return to kernel space */
855         DISABLE_INTERRUPTS(CLBR_ANY)
856         /*
857          * The iretq could re-enable interrupts:
858          */
859         TRACE_IRQS_IRETQ
860 restore_args:
861         RESTORE_ARGS 0,8,0
862
863 irq_return:
864         INTERRUPT_RETURN
865
866         .section __ex_table, "a"
867         .quad irq_return, bad_iret
868         .previous
869
870 #ifdef CONFIG_PARAVIRT
871 ENTRY(native_iret)
872         iretq
873
874         .section __ex_table,"a"
875         .quad native_iret, bad_iret
876         .previous
877 #endif
878
879         .section .fixup,"ax"
880 bad_iret:
881         /*
882          * The iret traps when the %cs or %ss being restored is bogus.
883          * We've lost the original trap vector and error code.
884          * #GPF is the most likely one to get for an invalid selector.
885          * So pretend we completed the iret and took the #GPF in user mode.
886          *
887          * We are now running with the kernel GS after exception recovery.
888          * But error_entry expects us to have user GS to match the user %cs,
889          * so swap back.
890          */
891         pushq $0
892
893         SWAPGS
894         jmp general_protection
895
896         .previous
897
898         /* edi: workmask, edx: work */
899 retint_careful:
900         CFI_RESTORE_STATE
901         bt    $TIF_NEED_RESCHED,%edx
902         jnc   retint_signal
903         TRACE_IRQS_ON
904         ENABLE_INTERRUPTS(CLBR_NONE)
905         pushq %rdi
906         CFI_ADJUST_CFA_OFFSET   8
907         call  schedule
908         popq %rdi
909         CFI_ADJUST_CFA_OFFSET   -8
910         GET_THREAD_INFO(%rcx)
911         DISABLE_INTERRUPTS(CLBR_NONE)
912         TRACE_IRQS_OFF
913         jmp retint_check
914
915 retint_signal:
916         testl $_TIF_DO_NOTIFY_MASK,%edx
917         jz    retint_swapgs
918         TRACE_IRQS_ON
919         ENABLE_INTERRUPTS(CLBR_NONE)
920         SAVE_REST
921         movq $-1,ORIG_RAX(%rsp)
922         xorl %esi,%esi          # oldset
923         movq %rsp,%rdi          # &pt_regs
924         call do_notify_resume
925         RESTORE_REST
926         DISABLE_INTERRUPTS(CLBR_NONE)
927         TRACE_IRQS_OFF
928         GET_THREAD_INFO(%rcx)
929         jmp retint_with_reschedule
930
931 #ifdef CONFIG_PREEMPT
932         /* Returning to kernel space. Check if we need preemption */
933         /* rcx:  threadinfo. interrupts off. */
934 ENTRY(retint_kernel)
935         cmpl $0,TI_preempt_count(%rcx)
936         jnz  retint_restore_args
937         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
938         jnc  retint_restore_args
939         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
940         jnc  retint_restore_args
941         call preempt_schedule_irq
942         jmp exit_intr
943 #endif
944
945         CFI_ENDPROC
946 END(common_interrupt)
947 /*
948  * End of kprobes section
949  */
950        .popsection
951
952 /*
953  * APIC interrupts.
954  */
955 .macro apicinterrupt num sym do_sym
956 ENTRY(\sym)
957         INTR_FRAME
958         pushq $~(\num)
959         CFI_ADJUST_CFA_OFFSET 8
960         interrupt \do_sym
961         jmp ret_from_intr
962         CFI_ENDPROC
963 END(\sym)
964 .endm
965
966 #ifdef CONFIG_SMP
967 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
968         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
969 apicinterrupt REBOOT_VECTOR \
970         reboot_interrupt smp_reboot_interrupt
971 #endif
972
973 #ifdef CONFIG_X86_UV
974 apicinterrupt UV_BAU_MESSAGE \
975         uv_bau_message_intr1 uv_bau_message_interrupt
976 #endif
977 apicinterrupt LOCAL_TIMER_VECTOR \
978         apic_timer_interrupt smp_apic_timer_interrupt
979 apicinterrupt X86_PLATFORM_IPI_VECTOR \
980         x86_platform_ipi smp_x86_platform_ipi
981
982 #ifdef CONFIG_SMP
983 apicinterrupt INVALIDATE_TLB_VECTOR_START+0 \
984         invalidate_interrupt0 smp_invalidate_interrupt
985 apicinterrupt INVALIDATE_TLB_VECTOR_START+1 \
986         invalidate_interrupt1 smp_invalidate_interrupt
987 apicinterrupt INVALIDATE_TLB_VECTOR_START+2 \
988         invalidate_interrupt2 smp_invalidate_interrupt
989 apicinterrupt INVALIDATE_TLB_VECTOR_START+3 \
990         invalidate_interrupt3 smp_invalidate_interrupt
991 apicinterrupt INVALIDATE_TLB_VECTOR_START+4 \
992         invalidate_interrupt4 smp_invalidate_interrupt
993 apicinterrupt INVALIDATE_TLB_VECTOR_START+5 \
994         invalidate_interrupt5 smp_invalidate_interrupt
995 apicinterrupt INVALIDATE_TLB_VECTOR_START+6 \
996         invalidate_interrupt6 smp_invalidate_interrupt
997 apicinterrupt INVALIDATE_TLB_VECTOR_START+7 \
998         invalidate_interrupt7 smp_invalidate_interrupt
999 #endif
1000
1001 apicinterrupt THRESHOLD_APIC_VECTOR \
1002         threshold_interrupt smp_threshold_interrupt
1003 apicinterrupt THERMAL_APIC_VECTOR \
1004         thermal_interrupt smp_thermal_interrupt
1005
1006 #ifdef CONFIG_X86_MCE
1007 apicinterrupt MCE_SELF_VECTOR \
1008         mce_self_interrupt smp_mce_self_interrupt
1009 #endif
1010
1011 #ifdef CONFIG_SMP
1012 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1013         call_function_single_interrupt smp_call_function_single_interrupt
1014 apicinterrupt CALL_FUNCTION_VECTOR \
1015         call_function_interrupt smp_call_function_interrupt
1016 apicinterrupt RESCHEDULE_VECTOR \
1017         reschedule_interrupt smp_reschedule_interrupt
1018 #endif
1019
1020 apicinterrupt ERROR_APIC_VECTOR \
1021         error_interrupt smp_error_interrupt
1022 apicinterrupt SPURIOUS_APIC_VECTOR \
1023         spurious_interrupt smp_spurious_interrupt
1024
1025 #ifdef CONFIG_PERF_EVENTS
1026 apicinterrupt LOCAL_PENDING_VECTOR \
1027         perf_pending_interrupt smp_perf_pending_interrupt
1028 #endif
1029
1030 /*
1031  * Exception entry points.
1032  */
1033 .macro zeroentry sym do_sym
1034 ENTRY(\sym)
1035         INTR_FRAME
1036         PARAVIRT_ADJUST_EXCEPTION_FRAME
1037         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1038         subq $ORIG_RAX-R15, %rsp
1039         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1040         call error_entry
1041         DEFAULT_FRAME 0
1042         movq %rsp,%rdi          /* pt_regs pointer */
1043         xorl %esi,%esi          /* no error code */
1044         call \do_sym
1045         jmp error_exit          /* %ebx: no swapgs flag */
1046         CFI_ENDPROC
1047 END(\sym)
1048 .endm
1049
1050 .macro paranoidzeroentry sym do_sym
1051 ENTRY(\sym)
1052         INTR_FRAME
1053         PARAVIRT_ADJUST_EXCEPTION_FRAME
1054         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1055         subq $ORIG_RAX-R15, %rsp
1056         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1057         call save_paranoid
1058         TRACE_IRQS_OFF
1059         movq %rsp,%rdi          /* pt_regs pointer */
1060         xorl %esi,%esi          /* no error code */
1061         call \do_sym
1062         jmp paranoid_exit       /* %ebx: no swapgs flag */
1063         CFI_ENDPROC
1064 END(\sym)
1065 .endm
1066
1067 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1068 .macro paranoidzeroentry_ist sym do_sym ist
1069 ENTRY(\sym)
1070         INTR_FRAME
1071         PARAVIRT_ADJUST_EXCEPTION_FRAME
1072         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1073         subq $ORIG_RAX-R15, %rsp
1074         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1075         call save_paranoid
1076         TRACE_IRQS_OFF
1077         movq %rsp,%rdi          /* pt_regs pointer */
1078         xorl %esi,%esi          /* no error code */
1079         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1080         call \do_sym
1081         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1082         jmp paranoid_exit       /* %ebx: no swapgs flag */
1083         CFI_ENDPROC
1084 END(\sym)
1085 .endm
1086
1087 .macro errorentry sym do_sym
1088 ENTRY(\sym)
1089         XCPT_FRAME
1090         PARAVIRT_ADJUST_EXCEPTION_FRAME
1091         subq $ORIG_RAX-R15, %rsp
1092         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1093         call error_entry
1094         DEFAULT_FRAME 0
1095         movq %rsp,%rdi                  /* pt_regs pointer */
1096         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1097         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1098         call \do_sym
1099         jmp error_exit                  /* %ebx: no swapgs flag */
1100         CFI_ENDPROC
1101 END(\sym)
1102 .endm
1103
1104         /* error code is on the stack already */
1105 .macro paranoiderrorentry sym do_sym
1106 ENTRY(\sym)
1107         XCPT_FRAME
1108         PARAVIRT_ADJUST_EXCEPTION_FRAME
1109         subq $ORIG_RAX-R15, %rsp
1110         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1111         call save_paranoid
1112         DEFAULT_FRAME 0
1113         TRACE_IRQS_OFF
1114         movq %rsp,%rdi                  /* pt_regs pointer */
1115         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1116         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1117         call \do_sym
1118         jmp paranoid_exit               /* %ebx: no swapgs flag */
1119         CFI_ENDPROC
1120 END(\sym)
1121 .endm
1122
1123 zeroentry divide_error do_divide_error
1124 zeroentry overflow do_overflow
1125 zeroentry bounds do_bounds
1126 zeroentry invalid_op do_invalid_op
1127 zeroentry device_not_available do_device_not_available
1128 paranoiderrorentry double_fault do_double_fault
1129 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1130 errorentry invalid_TSS do_invalid_TSS
1131 errorentry segment_not_present do_segment_not_present
1132 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1133 zeroentry coprocessor_error do_coprocessor_error
1134 errorentry alignment_check do_alignment_check
1135 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1136
1137         /* Reload gs selector with exception handling */
1138         /* edi:  new selector */
1139 ENTRY(native_load_gs_index)
1140         CFI_STARTPROC
1141         pushf
1142         CFI_ADJUST_CFA_OFFSET 8
1143         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1144         SWAPGS
1145 gs_change:
1146         movl %edi,%gs
1147 2:      mfence          /* workaround */
1148         SWAPGS
1149         popf
1150         CFI_ADJUST_CFA_OFFSET -8
1151         ret
1152         CFI_ENDPROC
1153 END(native_load_gs_index)
1154
1155         .section __ex_table,"a"
1156         .align 8
1157         .quad gs_change,bad_gs
1158         .previous
1159         .section .fixup,"ax"
1160         /* running with kernelgs */
1161 bad_gs:
1162         SWAPGS                  /* switch back to user gs */
1163         xorl %eax,%eax
1164         movl %eax,%gs
1165         jmp  2b
1166         .previous
1167
1168 ENTRY(kernel_thread_helper)
1169         pushq $0                # fake return address
1170         CFI_STARTPROC
1171         /*
1172          * Here we are in the child and the registers are set as they were
1173          * at kernel_thread() invocation in the parent.
1174          */
1175         call *%rsi
1176         # exit
1177         mov %eax, %edi
1178         call do_exit
1179         ud2                     # padding for call trace
1180         CFI_ENDPROC
1181 END(kernel_thread_helper)
1182
1183 /*
1184  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1185  *
1186  * C extern interface:
1187  *       extern long execve(const char *name, char **argv, char **envp)
1188  *
1189  * asm input arguments:
1190  *      rdi: name, rsi: argv, rdx: envp
1191  *
1192  * We want to fallback into:
1193  *      extern long sys_execve(const char *name, char **argv,char **envp, struct pt_regs *regs)
1194  *
1195  * do_sys_execve asm fallback arguments:
1196  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1197  */
1198 ENTRY(kernel_execve)
1199         CFI_STARTPROC
1200         FAKE_STACK_FRAME $0
1201         SAVE_ALL
1202         movq %rsp,%rcx
1203         call sys_execve
1204         movq %rax, RAX(%rsp)
1205         RESTORE_REST
1206         testq %rax,%rax
1207         je int_ret_from_sys_call
1208         RESTORE_ARGS
1209         UNFAKE_STACK_FRAME
1210         ret
1211         CFI_ENDPROC
1212 END(kernel_execve)
1213
1214 /* Call softirq on interrupt stack. Interrupts are off. */
1215 ENTRY(call_softirq)
1216         CFI_STARTPROC
1217         push %rbp
1218         CFI_ADJUST_CFA_OFFSET   8
1219         CFI_REL_OFFSET rbp,0
1220         mov  %rsp,%rbp
1221         CFI_DEF_CFA_REGISTER rbp
1222         incl PER_CPU_VAR(irq_count)
1223         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1224         push  %rbp                      # backlink for old unwinder
1225         call __do_softirq
1226         leaveq
1227         CFI_DEF_CFA_REGISTER    rsp
1228         CFI_ADJUST_CFA_OFFSET   -8
1229         decl PER_CPU_VAR(irq_count)
1230         ret
1231         CFI_ENDPROC
1232 END(call_softirq)
1233
1234 #ifdef CONFIG_XEN
1235 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1236
1237 /*
1238  * A note on the "critical region" in our callback handler.
1239  * We want to avoid stacking callback handlers due to events occurring
1240  * during handling of the last event. To do this, we keep events disabled
1241  * until we've done all processing. HOWEVER, we must enable events before
1242  * popping the stack frame (can't be done atomically) and so it would still
1243  * be possible to get enough handler activations to overflow the stack.
1244  * Although unlikely, bugs of that kind are hard to track down, so we'd
1245  * like to avoid the possibility.
1246  * So, on entry to the handler we detect whether we interrupted an
1247  * existing activation in its critical region -- if so, we pop the current
1248  * activation and restart the handler using the previous one.
1249  */
1250 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1251         CFI_STARTPROC
1252 /*
1253  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1254  * see the correct pointer to the pt_regs
1255  */
1256         movq %rdi, %rsp            # we don't return, adjust the stack frame
1257         CFI_ENDPROC
1258         DEFAULT_FRAME
1259 11:     incl PER_CPU_VAR(irq_count)
1260         movq %rsp,%rbp
1261         CFI_DEF_CFA_REGISTER rbp
1262         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1263         pushq %rbp                      # backlink for old unwinder
1264         call xen_evtchn_do_upcall
1265         popq %rsp
1266         CFI_DEF_CFA_REGISTER rsp
1267         decl PER_CPU_VAR(irq_count)
1268         jmp  error_exit
1269         CFI_ENDPROC
1270 END(do_hypervisor_callback)
1271
1272 /*
1273  * Hypervisor uses this for application faults while it executes.
1274  * We get here for two reasons:
1275  *  1. Fault while reloading DS, ES, FS or GS
1276  *  2. Fault while executing IRET
1277  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1278  * registers that could be reloaded and zeroed the others.
1279  * Category 2 we fix up by killing the current process. We cannot use the
1280  * normal Linux return path in this case because if we use the IRET hypercall
1281  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1282  * We distinguish between categories by comparing each saved segment register
1283  * with its current contents: any discrepancy means we in category 1.
1284  */
1285 ENTRY(xen_failsafe_callback)
1286         INTR_FRAME 1 (6*8)
1287         /*CFI_REL_OFFSET gs,GS*/
1288         /*CFI_REL_OFFSET fs,FS*/
1289         /*CFI_REL_OFFSET es,ES*/
1290         /*CFI_REL_OFFSET ds,DS*/
1291         CFI_REL_OFFSET r11,8
1292         CFI_REL_OFFSET rcx,0
1293         movw %ds,%cx
1294         cmpw %cx,0x10(%rsp)
1295         CFI_REMEMBER_STATE
1296         jne 1f
1297         movw %es,%cx
1298         cmpw %cx,0x18(%rsp)
1299         jne 1f
1300         movw %fs,%cx
1301         cmpw %cx,0x20(%rsp)
1302         jne 1f
1303         movw %gs,%cx
1304         cmpw %cx,0x28(%rsp)
1305         jne 1f
1306         /* All segments match their saved values => Category 2 (Bad IRET). */
1307         movq (%rsp),%rcx
1308         CFI_RESTORE rcx
1309         movq 8(%rsp),%r11
1310         CFI_RESTORE r11
1311         addq $0x30,%rsp
1312         CFI_ADJUST_CFA_OFFSET -0x30
1313         pushq_cfi $0    /* RIP */
1314         pushq_cfi %r11
1315         pushq_cfi %rcx
1316         jmp general_protection
1317         CFI_RESTORE_STATE
1318 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1319         movq (%rsp),%rcx
1320         CFI_RESTORE rcx
1321         movq 8(%rsp),%r11
1322         CFI_RESTORE r11
1323         addq $0x30,%rsp
1324         CFI_ADJUST_CFA_OFFSET -0x30
1325         pushq_cfi $0
1326         SAVE_ALL
1327         jmp error_exit
1328         CFI_ENDPROC
1329 END(xen_failsafe_callback)
1330
1331 apicinterrupt XEN_HVM_EVTCHN_CALLBACK \
1332         xen_hvm_callback_vector xen_evtchn_do_upcall
1333
1334 #endif /* CONFIG_XEN */
1335
1336 /*
1337  * Some functions should be protected against kprobes
1338  */
1339         .pushsection .kprobes.text, "ax"
1340
1341 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1342 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1343 paranoiderrorentry stack_segment do_stack_segment
1344 #ifdef CONFIG_XEN
1345 zeroentry xen_debug do_debug
1346 zeroentry xen_int3 do_int3
1347 errorentry xen_stack_segment do_stack_segment
1348 #endif
1349 errorentry general_protection do_general_protection
1350 errorentry page_fault do_page_fault
1351 #ifdef CONFIG_X86_MCE
1352 paranoidzeroentry machine_check *machine_check_vector(%rip)
1353 #endif
1354
1355         /*
1356          * "Paranoid" exit path from exception stack.
1357          * Paranoid because this is used by NMIs and cannot take
1358          * any kernel state for granted.
1359          * We don't do kernel preemption checks here, because only
1360          * NMI should be common and it does not enable IRQs and
1361          * cannot get reschedule ticks.
1362          *
1363          * "trace" is 0 for the NMI handler only, because irq-tracing
1364          * is fundamentally NMI-unsafe. (we cannot change the soft and
1365          * hard flags at once, atomically)
1366          */
1367
1368         /* ebx: no swapgs flag */
1369 ENTRY(paranoid_exit)
1370         DEFAULT_FRAME
1371         DISABLE_INTERRUPTS(CLBR_NONE)
1372         TRACE_IRQS_OFF
1373         testl %ebx,%ebx                         /* swapgs needed? */
1374         jnz paranoid_restore
1375         testl $3,CS(%rsp)
1376         jnz   paranoid_userspace
1377 paranoid_swapgs:
1378         TRACE_IRQS_IRETQ 0
1379         SWAPGS_UNSAFE_STACK
1380         RESTORE_ALL 8
1381         jmp irq_return
1382 paranoid_restore:
1383         TRACE_IRQS_IRETQ 0
1384         RESTORE_ALL 8
1385         jmp irq_return
1386 paranoid_userspace:
1387         GET_THREAD_INFO(%rcx)
1388         movl TI_flags(%rcx),%ebx
1389         andl $_TIF_WORK_MASK,%ebx
1390         jz paranoid_swapgs
1391         movq %rsp,%rdi                  /* &pt_regs */
1392         call sync_regs
1393         movq %rax,%rsp                  /* switch stack for scheduling */
1394         testl $_TIF_NEED_RESCHED,%ebx
1395         jnz paranoid_schedule
1396         movl %ebx,%edx                  /* arg3: thread flags */
1397         TRACE_IRQS_ON
1398         ENABLE_INTERRUPTS(CLBR_NONE)
1399         xorl %esi,%esi                  /* arg2: oldset */
1400         movq %rsp,%rdi                  /* arg1: &pt_regs */
1401         call do_notify_resume
1402         DISABLE_INTERRUPTS(CLBR_NONE)
1403         TRACE_IRQS_OFF
1404         jmp paranoid_userspace
1405 paranoid_schedule:
1406         TRACE_IRQS_ON
1407         ENABLE_INTERRUPTS(CLBR_ANY)
1408         call schedule
1409         DISABLE_INTERRUPTS(CLBR_ANY)
1410         TRACE_IRQS_OFF
1411         jmp paranoid_userspace
1412         CFI_ENDPROC
1413 END(paranoid_exit)
1414
1415 /*
1416  * Exception entry point. This expects an error code/orig_rax on the stack.
1417  * returns in "no swapgs flag" in %ebx.
1418  */
1419 ENTRY(error_entry)
1420         XCPT_FRAME
1421         CFI_ADJUST_CFA_OFFSET 15*8
1422         /* oldrax contains error code */
1423         cld
1424         movq_cfi rdi, RDI+8
1425         movq_cfi rsi, RSI+8
1426         movq_cfi rdx, RDX+8
1427         movq_cfi rcx, RCX+8
1428         movq_cfi rax, RAX+8
1429         movq_cfi  r8,  R8+8
1430         movq_cfi  r9,  R9+8
1431         movq_cfi r10, R10+8
1432         movq_cfi r11, R11+8
1433         movq_cfi rbx, RBX+8
1434         movq_cfi rbp, RBP+8
1435         movq_cfi r12, R12+8
1436         movq_cfi r13, R13+8
1437         movq_cfi r14, R14+8
1438         movq_cfi r15, R15+8
1439         xorl %ebx,%ebx
1440         testl $3,CS+8(%rsp)
1441         je error_kernelspace
1442 error_swapgs:
1443         SWAPGS
1444 error_sti:
1445         TRACE_IRQS_OFF
1446         ret
1447
1448 /*
1449  * There are two places in the kernel that can potentially fault with
1450  * usergs. Handle them here. The exception handlers after iret run with
1451  * kernel gs again, so don't set the user space flag. B stepping K8s
1452  * sometimes report an truncated RIP for IRET exceptions returning to
1453  * compat mode. Check for these here too.
1454  */
1455 error_kernelspace:
1456         incl %ebx
1457         leaq irq_return(%rip),%rcx
1458         cmpq %rcx,RIP+8(%rsp)
1459         je error_swapgs
1460         movl %ecx,%eax  /* zero extend */
1461         cmpq %rax,RIP+8(%rsp)
1462         je bstep_iret
1463         cmpq $gs_change,RIP+8(%rsp)
1464         je error_swapgs
1465         jmp error_sti
1466
1467 bstep_iret:
1468         /* Fix truncated RIP */
1469         movq %rcx,RIP+8(%rsp)
1470         jmp error_swapgs
1471         CFI_ENDPROC
1472 END(error_entry)
1473
1474
1475 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1476 ENTRY(error_exit)
1477         DEFAULT_FRAME
1478         movl %ebx,%eax
1479         RESTORE_REST
1480         DISABLE_INTERRUPTS(CLBR_NONE)
1481         TRACE_IRQS_OFF
1482         GET_THREAD_INFO(%rcx)
1483         testl %eax,%eax
1484         jne retint_kernel
1485         LOCKDEP_SYS_EXIT_IRQ
1486         movl TI_flags(%rcx),%edx
1487         movl $_TIF_WORK_MASK,%edi
1488         andl %edi,%edx
1489         jnz retint_careful
1490         jmp retint_swapgs
1491         CFI_ENDPROC
1492 END(error_exit)
1493
1494
1495         /* runs on exception stack */
1496 ENTRY(nmi)
1497         INTR_FRAME
1498         PARAVIRT_ADJUST_EXCEPTION_FRAME
1499         pushq_cfi $-1
1500         subq $ORIG_RAX-R15, %rsp
1501         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1502         call save_paranoid
1503         DEFAULT_FRAME 0
1504         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1505         movq %rsp,%rdi
1506         movq $-1,%rsi
1507         call do_nmi
1508 #ifdef CONFIG_TRACE_IRQFLAGS
1509         /* paranoidexit; without TRACE_IRQS_OFF */
1510         /* ebx: no swapgs flag */
1511         DISABLE_INTERRUPTS(CLBR_NONE)
1512         testl %ebx,%ebx                         /* swapgs needed? */
1513         jnz nmi_restore
1514         testl $3,CS(%rsp)
1515         jnz nmi_userspace
1516 nmi_swapgs:
1517         SWAPGS_UNSAFE_STACK
1518 nmi_restore:
1519         RESTORE_ALL 8
1520         jmp irq_return
1521 nmi_userspace:
1522         GET_THREAD_INFO(%rcx)
1523         movl TI_flags(%rcx),%ebx
1524         andl $_TIF_WORK_MASK,%ebx
1525         jz nmi_swapgs
1526         movq %rsp,%rdi                  /* &pt_regs */
1527         call sync_regs
1528         movq %rax,%rsp                  /* switch stack for scheduling */
1529         testl $_TIF_NEED_RESCHED,%ebx
1530         jnz nmi_schedule
1531         movl %ebx,%edx                  /* arg3: thread flags */
1532         ENABLE_INTERRUPTS(CLBR_NONE)
1533         xorl %esi,%esi                  /* arg2: oldset */
1534         movq %rsp,%rdi                  /* arg1: &pt_regs */
1535         call do_notify_resume
1536         DISABLE_INTERRUPTS(CLBR_NONE)
1537         jmp nmi_userspace
1538 nmi_schedule:
1539         ENABLE_INTERRUPTS(CLBR_ANY)
1540         call schedule
1541         DISABLE_INTERRUPTS(CLBR_ANY)
1542         jmp nmi_userspace
1543         CFI_ENDPROC
1544 #else
1545         jmp paranoid_exit
1546         CFI_ENDPROC
1547 #endif
1548 END(nmi)
1549
1550 ENTRY(ignore_sysret)
1551         CFI_STARTPROC
1552         mov $-ENOSYS,%eax
1553         sysret
1554         CFI_ENDPROC
1555 END(ignore_sysret)
1556
1557 /*
1558  * End of kprobes section
1559  */
1560         .popsection