x86/Kconfig: Make early microcode loading a configuration feature
[~shefty/rdma-dev.git] / arch / x86 / kernel / head_32.S
1 /*
2  *
3  *  Copyright (C) 1991, 1992  Linus Torvalds
4  *
5  *  Enhanced CPU detection and feature setting code by Mike Jagdis
6  *  and Martin Mares, November 1997.
7  */
8
9 .text
10 #include <linux/threads.h>
11 #include <linux/init.h>
12 #include <linux/linkage.h>
13 #include <asm/segment.h>
14 #include <asm/page_types.h>
15 #include <asm/pgtable_types.h>
16 #include <asm/cache.h>
17 #include <asm/thread_info.h>
18 #include <asm/asm-offsets.h>
19 #include <asm/setup.h>
20 #include <asm/processor-flags.h>
21 #include <asm/msr-index.h>
22 #include <asm/cpufeature.h>
23 #include <asm/percpu.h>
24 #include <asm/nops.h>
25
26 /* Physical address */
27 #define pa(X) ((X) - __PAGE_OFFSET)
28
29 /*
30  * References to members of the new_cpu_data structure.
31  */
32
33 #define X86             new_cpu_data+CPUINFO_x86
34 #define X86_VENDOR      new_cpu_data+CPUINFO_x86_vendor
35 #define X86_MODEL       new_cpu_data+CPUINFO_x86_model
36 #define X86_MASK        new_cpu_data+CPUINFO_x86_mask
37 #define X86_HARD_MATH   new_cpu_data+CPUINFO_hard_math
38 #define X86_CPUID       new_cpu_data+CPUINFO_cpuid_level
39 #define X86_CAPABILITY  new_cpu_data+CPUINFO_x86_capability
40 #define X86_VENDOR_ID   new_cpu_data+CPUINFO_x86_vendor_id
41
42 /*
43  * This is how much memory in addition to the memory covered up to
44  * and including _end we need mapped initially.
45  * We need:
46  *     (KERNEL_IMAGE_SIZE/4096) / 1024 pages (worst case, non PAE)
47  *     (KERNEL_IMAGE_SIZE/4096) / 512 + 4 pages (worst case for PAE)
48  *
49  * Modulo rounding, each megabyte assigned here requires a kilobyte of
50  * memory, which is currently unreclaimed.
51  *
52  * This should be a multiple of a page.
53  *
54  * KERNEL_IMAGE_SIZE should be greater than pa(_end)
55  * and small than max_low_pfn, otherwise will waste some page table entries
56  */
57
58 #if PTRS_PER_PMD > 1
59 #define PAGE_TABLE_SIZE(pages) (((pages) / PTRS_PER_PMD) + PTRS_PER_PGD)
60 #else
61 #define PAGE_TABLE_SIZE(pages) ((pages) / PTRS_PER_PGD)
62 #endif
63
64 /* Number of possible pages in the lowmem region */
65 LOWMEM_PAGES = (((1<<32) - __PAGE_OFFSET) >> PAGE_SHIFT)
66         
67 /* Enough space to fit pagetables for the low memory linear map */
68 MAPPING_BEYOND_END = PAGE_TABLE_SIZE(LOWMEM_PAGES) << PAGE_SHIFT
69
70 /*
71  * Worst-case size of the kernel mapping we need to make:
72  * a relocatable kernel can live anywhere in lowmem, so we need to be able
73  * to map all of lowmem.
74  */
75 KERNEL_PAGES = LOWMEM_PAGES
76
77 INIT_MAP_SIZE = PAGE_TABLE_SIZE(KERNEL_PAGES) * PAGE_SIZE
78 RESERVE_BRK(pagetables, INIT_MAP_SIZE)
79
80 /*
81  * 32-bit kernel entrypoint; only used by the boot CPU.  On entry,
82  * %esi points to the real-mode code as a 32-bit pointer.
83  * CS and DS must be 4 GB flat segments, but we don't depend on
84  * any particular GDT layout, because we load our own as soon as we
85  * can.
86  */
87 __HEAD
88 ENTRY(startup_32)
89         movl pa(stack_start),%ecx
90         
91         /* test KEEP_SEGMENTS flag to see if the bootloader is asking
92                 us to not reload segments */
93         testb $(1<<6), BP_loadflags(%esi)
94         jnz 2f
95
96 /*
97  * Set segments to known values.
98  */
99         lgdt pa(boot_gdt_descr)
100         movl $(__BOOT_DS),%eax
101         movl %eax,%ds
102         movl %eax,%es
103         movl %eax,%fs
104         movl %eax,%gs
105         movl %eax,%ss
106 2:
107         leal -__PAGE_OFFSET(%ecx),%esp
108
109 /*
110  * Clear BSS first so that there are no surprises...
111  */
112         cld
113         xorl %eax,%eax
114         movl $pa(__bss_start),%edi
115         movl $pa(__bss_stop),%ecx
116         subl %edi,%ecx
117         shrl $2,%ecx
118         rep ; stosl
119 /*
120  * Copy bootup parameters out of the way.
121  * Note: %esi still has the pointer to the real-mode data.
122  * With the kexec as boot loader, parameter segment might be loaded beyond
123  * kernel image and might not even be addressable by early boot page tables.
124  * (kexec on panic case). Hence copy out the parameters before initializing
125  * page tables.
126  */
127         movl $pa(boot_params),%edi
128         movl $(PARAM_SIZE/4),%ecx
129         cld
130         rep
131         movsl
132         movl pa(boot_params) + NEW_CL_POINTER,%esi
133         andl %esi,%esi
134         jz 1f                   # No command line
135         movl $pa(boot_command_line),%edi
136         movl $(COMMAND_LINE_SIZE/4),%ecx
137         rep
138         movsl
139 1:
140
141 #ifdef CONFIG_OLPC
142         /* save OFW's pgdir table for later use when calling into OFW */
143         movl %cr3, %eax
144         movl %eax, pa(olpc_ofw_pgd)
145 #endif
146
147 #ifdef CONFIG_MICROCODE_EARLY
148         /* Early load ucode on BSP. */
149         call load_ucode_bsp
150 #endif
151
152 /*
153  * Initialize page tables.  This creates a PDE and a set of page
154  * tables, which are located immediately beyond __brk_base.  The variable
155  * _brk_end is set up to point to the first "safe" location.
156  * Mappings are created both at virtual address 0 (identity mapping)
157  * and PAGE_OFFSET for up to _end.
158  */
159 #ifdef CONFIG_X86_PAE
160
161         /*
162          * In PAE mode initial_page_table is statically defined to contain
163          * enough entries to cover the VMSPLIT option (that is the top 1, 2 or 3
164          * entries). The identity mapping is handled by pointing two PGD entries
165          * to the first kernel PMD.
166          *
167          * Note the upper half of each PMD or PTE are always zero at this stage.
168          */
169
170 #define KPMDS (((-__PAGE_OFFSET) >> 30) & 3) /* Number of kernel PMDs */
171
172         xorl %ebx,%ebx                          /* %ebx is kept at zero */
173
174         movl $pa(__brk_base), %edi
175         movl $pa(initial_pg_pmd), %edx
176         movl $PTE_IDENT_ATTR, %eax
177 10:
178         leal PDE_IDENT_ATTR(%edi),%ecx          /* Create PMD entry */
179         movl %ecx,(%edx)                        /* Store PMD entry */
180                                                 /* Upper half already zero */
181         addl $8,%edx
182         movl $512,%ecx
183 11:
184         stosl
185         xchgl %eax,%ebx
186         stosl
187         xchgl %eax,%ebx
188         addl $0x1000,%eax
189         loop 11b
190
191         /*
192          * End condition: we must map up to the end + MAPPING_BEYOND_END.
193          */
194         movl $pa(_end) + MAPPING_BEYOND_END + PTE_IDENT_ATTR, %ebp
195         cmpl %ebp,%eax
196         jb 10b
197 1:
198         addl $__PAGE_OFFSET, %edi
199         movl %edi, pa(_brk_end)
200         shrl $12, %eax
201         movl %eax, pa(max_pfn_mapped)
202
203         /* Do early initialization of the fixmap area */
204         movl $pa(initial_pg_fixmap)+PDE_IDENT_ATTR,%eax
205         movl %eax,pa(initial_pg_pmd+0x1000*KPMDS-8)
206 #else   /* Not PAE */
207
208 page_pde_offset = (__PAGE_OFFSET >> 20);
209
210         movl $pa(__brk_base), %edi
211         movl $pa(initial_page_table), %edx
212         movl $PTE_IDENT_ATTR, %eax
213 10:
214         leal PDE_IDENT_ATTR(%edi),%ecx          /* Create PDE entry */
215         movl %ecx,(%edx)                        /* Store identity PDE entry */
216         movl %ecx,page_pde_offset(%edx)         /* Store kernel PDE entry */
217         addl $4,%edx
218         movl $1024, %ecx
219 11:
220         stosl
221         addl $0x1000,%eax
222         loop 11b
223         /*
224          * End condition: we must map up to the end + MAPPING_BEYOND_END.
225          */
226         movl $pa(_end) + MAPPING_BEYOND_END + PTE_IDENT_ATTR, %ebp
227         cmpl %ebp,%eax
228         jb 10b
229         addl $__PAGE_OFFSET, %edi
230         movl %edi, pa(_brk_end)
231         shrl $12, %eax
232         movl %eax, pa(max_pfn_mapped)
233
234         /* Do early initialization of the fixmap area */
235         movl $pa(initial_pg_fixmap)+PDE_IDENT_ATTR,%eax
236         movl %eax,pa(initial_page_table+0xffc)
237 #endif
238
239 #ifdef CONFIG_PARAVIRT
240         /* This is can only trip for a broken bootloader... */
241         cmpw $0x207, pa(boot_params + BP_version)
242         jb default_entry
243
244         /* Paravirt-compatible boot parameters.  Look to see what architecture
245                 we're booting under. */
246         movl pa(boot_params + BP_hardware_subarch), %eax
247         cmpl $num_subarch_entries, %eax
248         jae bad_subarch
249
250         movl pa(subarch_entries)(,%eax,4), %eax
251         subl $__PAGE_OFFSET, %eax
252         jmp *%eax
253
254 bad_subarch:
255 WEAK(lguest_entry)
256 WEAK(xen_entry)
257         /* Unknown implementation; there's really
258            nothing we can do at this point. */
259         ud2a
260
261         __INITDATA
262
263 subarch_entries:
264         .long default_entry             /* normal x86/PC */
265         .long lguest_entry              /* lguest hypervisor */
266         .long xen_entry                 /* Xen hypervisor */
267         .long default_entry             /* Moorestown MID */
268 num_subarch_entries = (. - subarch_entries) / 4
269 .previous
270 #else
271         jmp default_entry
272 #endif /* CONFIG_PARAVIRT */
273
274 #ifdef CONFIG_HOTPLUG_CPU
275 /*
276  * Boot CPU0 entry point. It's called from play_dead(). Everything has been set
277  * up already except stack. We just set up stack here. Then call
278  * start_secondary().
279  */
280 ENTRY(start_cpu0)
281         movl stack_start, %ecx
282         movl %ecx, %esp
283         jmp  *(initial_code)
284 ENDPROC(start_cpu0)
285 #endif
286
287 /*
288  * Non-boot CPU entry point; entered from trampoline.S
289  * We can't lgdt here, because lgdt itself uses a data segment, but
290  * we know the trampoline has already loaded the boot_gdt for us.
291  *
292  * If cpu hotplug is not supported then this code can go in init section
293  * which will be freed later
294  */
295 __CPUINIT
296 ENTRY(startup_32_smp)
297         cld
298         movl $(__BOOT_DS),%eax
299         movl %eax,%ds
300         movl %eax,%es
301         movl %eax,%fs
302         movl %eax,%gs
303         movl pa(stack_start),%ecx
304         movl %eax,%ss
305         leal -__PAGE_OFFSET(%ecx),%esp
306
307 #ifdef CONFIG_MICROCODE_EARLY
308         /* Early load ucode on AP. */
309         call load_ucode_ap
310 #endif
311
312
313 default_entry:
314 /*
315  *      New page tables may be in 4Mbyte page mode and may
316  *      be using the global pages. 
317  *
318  *      NOTE! If we are on a 486 we may have no cr4 at all!
319  *      Specifically, cr4 exists if and only if CPUID exists
320  *      and has flags other than the FPU flag set.
321  */
322         movl $X86_EFLAGS_ID,%ecx
323         pushl %ecx
324         popfl
325         pushfl
326         popl %eax
327         pushl $0
328         popfl
329         pushfl
330         popl %edx
331         xorl %edx,%eax
332         testl %ecx,%eax
333         jz 6f                   # No ID flag = no CPUID = no CR4
334
335         movl $1,%eax
336         cpuid
337         andl $~1,%edx           # Ignore CPUID.FPU
338         jz 6f                   # No flags or only CPUID.FPU = no CR4
339
340         movl pa(mmu_cr4_features),%eax
341         movl %eax,%cr4
342
343         testb $X86_CR4_PAE, %al         # check if PAE is enabled
344         jz 6f
345
346         /* Check if extended functions are implemented */
347         movl $0x80000000, %eax
348         cpuid
349         /* Value must be in the range 0x80000001 to 0x8000ffff */
350         subl $0x80000001, %eax
351         cmpl $(0x8000ffff-0x80000001), %eax
352         ja 6f
353
354         /* Clear bogus XD_DISABLE bits */
355         call verify_cpu
356
357         mov $0x80000001, %eax
358         cpuid
359         /* Execute Disable bit supported? */
360         btl $(X86_FEATURE_NX & 31), %edx
361         jnc 6f
362
363         /* Setup EFER (Extended Feature Enable Register) */
364         movl $MSR_EFER, %ecx
365         rdmsr
366
367         btsl $_EFER_NX, %eax
368         /* Make changes effective */
369         wrmsr
370
371 6:
372
373 /*
374  * Enable paging
375  */
376         movl $pa(initial_page_table), %eax
377         movl %eax,%cr3          /* set the page table pointer.. */
378         movl %cr0,%eax
379         orl  $X86_CR0_PG,%eax
380         movl %eax,%cr0          /* ..and set paging (PG) bit */
381         ljmp $__BOOT_CS,$1f     /* Clear prefetch and normalize %eip */
382 1:
383         /* Shift the stack pointer to a virtual address */
384         addl $__PAGE_OFFSET, %esp
385
386 /*
387  * Initialize eflags.  Some BIOS's leave bits like NT set.  This would
388  * confuse the debugger if this code is traced.
389  * XXX - best to initialize before switching to protected mode.
390  */
391         pushl $0
392         popfl
393
394 /*
395  * start system 32-bit setup. We need to re-do some of the things done
396  * in 16-bit mode for the "real" operations.
397  */
398         movl setup_once_ref,%eax
399         andl %eax,%eax
400         jz 1f                           # Did we do this already?
401         call *%eax
402 1:
403         
404 /* check if it is 486 or 386. */
405 /*
406  * XXX - this does a lot of unnecessary setup.  Alignment checks don't
407  * apply at our cpl of 0 and the stack ought to be aligned already, and
408  * we don't need to preserve eflags.
409  */
410         movl $-1,X86_CPUID      # -1 for no CPUID initially
411         movb $3,X86             # at least 386
412         pushfl                  # push EFLAGS
413         popl %eax               # get EFLAGS
414         movl %eax,%ecx          # save original EFLAGS
415         xorl $0x240000,%eax     # flip AC and ID bits in EFLAGS
416         pushl %eax              # copy to EFLAGS
417         popfl                   # set EFLAGS
418         pushfl                  # get new EFLAGS
419         popl %eax               # put it in eax
420         xorl %ecx,%eax          # change in flags
421         pushl %ecx              # restore original EFLAGS
422         popfl
423         testl $0x40000,%eax     # check if AC bit changed
424         je is386
425
426         movb $4,X86             # at least 486
427         testl $0x200000,%eax    # check if ID bit changed
428         je is486
429
430         /* get vendor info */
431         xorl %eax,%eax                  # call CPUID with 0 -> return vendor ID
432         cpuid
433         movl %eax,X86_CPUID             # save CPUID level
434         movl %ebx,X86_VENDOR_ID         # lo 4 chars
435         movl %edx,X86_VENDOR_ID+4       # next 4 chars
436         movl %ecx,X86_VENDOR_ID+8       # last 4 chars
437
438         orl %eax,%eax                   # do we have processor info as well?
439         je is486
440
441         movl $1,%eax            # Use the CPUID instruction to get CPU type
442         cpuid
443         movb %al,%cl            # save reg for future use
444         andb $0x0f,%ah          # mask processor family
445         movb %ah,X86
446         andb $0xf0,%al          # mask model
447         shrb $4,%al
448         movb %al,X86_MODEL
449         andb $0x0f,%cl          # mask mask revision
450         movb %cl,X86_MASK
451         movl %edx,X86_CAPABILITY
452
453 is486:  movl $0x50022,%ecx      # set AM, WP, NE and MP
454         jmp 2f
455
456 is386:  movl $2,%ecx            # set MP
457 2:      movl %cr0,%eax
458         andl $0x80000011,%eax   # Save PG,PE,ET
459         orl %ecx,%eax
460         movl %eax,%cr0
461
462         call check_x87
463         lgdt early_gdt_descr
464         lidt idt_descr
465         ljmp $(__KERNEL_CS),$1f
466 1:      movl $(__KERNEL_DS),%eax        # reload all the segment registers
467         movl %eax,%ss                   # after changing gdt.
468
469         movl $(__USER_DS),%eax          # DS/ES contains default USER segment
470         movl %eax,%ds
471         movl %eax,%es
472
473         movl $(__KERNEL_PERCPU), %eax
474         movl %eax,%fs                   # set this cpu's percpu
475
476         movl $(__KERNEL_STACK_CANARY),%eax
477         movl %eax,%gs
478
479         xorl %eax,%eax                  # Clear LDT
480         lldt %ax
481
482         cld                     # gcc2 wants the direction flag cleared at all times
483         pushl $0                # fake return address for unwinder
484         jmp *(initial_code)
485
486 /*
487  * We depend on ET to be correct. This checks for 287/387.
488  */
489 check_x87:
490         movb $0,X86_HARD_MATH
491         clts
492         fninit
493         fstsw %ax
494         cmpb $0,%al
495         je 1f
496         movl %cr0,%eax          /* no coprocessor: have to set bits */
497         xorl $4,%eax            /* set EM */
498         movl %eax,%cr0
499         ret
500         ALIGN
501 1:      movb $1,X86_HARD_MATH
502         .byte 0xDB,0xE4         /* fsetpm for 287, ignored by 387 */
503         ret
504
505         
506 #include "verify_cpu.S"
507
508 /*
509  *  setup_once
510  *
511  *  The setup work we only want to run on the BSP.
512  *
513  *  Warning: %esi is live across this function.
514  */
515 __INIT
516 setup_once:
517         /*
518          * Set up a idt with 256 entries pointing to ignore_int,
519          * interrupt gates. It doesn't actually load idt - that needs
520          * to be done on each CPU. Interrupts are enabled elsewhere,
521          * when we can be relatively sure everything is ok.
522          */
523
524         movl $idt_table,%edi
525         movl $early_idt_handlers,%eax
526         movl $NUM_EXCEPTION_VECTORS,%ecx
527 1:
528         movl %eax,(%edi)
529         movl %eax,4(%edi)
530         /* interrupt gate, dpl=0, present */
531         movl $(0x8E000000 + __KERNEL_CS),2(%edi)
532         addl $9,%eax
533         addl $8,%edi
534         loop 1b
535
536         movl $256 - NUM_EXCEPTION_VECTORS,%ecx
537         movl $ignore_int,%edx
538         movl $(__KERNEL_CS << 16),%eax
539         movw %dx,%ax            /* selector = 0x0010 = cs */
540         movw $0x8E00,%dx        /* interrupt gate - dpl=0, present */
541 2:
542         movl %eax,(%edi)
543         movl %edx,4(%edi)
544         addl $8,%edi
545         loop 2b
546
547 #ifdef CONFIG_CC_STACKPROTECTOR
548         /*
549          * Configure the stack canary. The linker can't handle this by
550          * relocation.  Manually set base address in stack canary
551          * segment descriptor.
552          */
553         movl $gdt_page,%eax
554         movl $stack_canary,%ecx
555         movw %cx, 8 * GDT_ENTRY_STACK_CANARY + 2(%eax)
556         shrl $16, %ecx
557         movb %cl, 8 * GDT_ENTRY_STACK_CANARY + 4(%eax)
558         movb %ch, 8 * GDT_ENTRY_STACK_CANARY + 7(%eax)
559 #endif
560
561         andl $0,setup_once_ref  /* Once is enough, thanks */
562         ret
563
564 ENTRY(early_idt_handlers)
565         # 36(%esp) %eflags
566         # 32(%esp) %cs
567         # 28(%esp) %eip
568         # 24(%rsp) error code
569         i = 0
570         .rept NUM_EXCEPTION_VECTORS
571         .if (EXCEPTION_ERRCODE_MASK >> i) & 1
572         ASM_NOP2
573         .else
574         pushl $0                # Dummy error code, to make stack frame uniform
575         .endif
576         pushl $i                # 20(%esp) Vector number
577         jmp early_idt_handler
578         i = i + 1
579         .endr
580 ENDPROC(early_idt_handlers)
581         
582         /* This is global to keep gas from relaxing the jumps */
583 ENTRY(early_idt_handler)
584         cld
585         cmpl $2,%ss:early_recursion_flag
586         je hlt_loop
587         incl %ss:early_recursion_flag
588
589         push %eax               # 16(%esp)
590         push %ecx               # 12(%esp)
591         push %edx               #  8(%esp)
592         push %ds                #  4(%esp)
593         push %es                #  0(%esp)
594         movl $(__KERNEL_DS),%eax
595         movl %eax,%ds
596         movl %eax,%es
597
598         cmpl $(__KERNEL_CS),32(%esp)
599         jne 10f
600
601         leal 28(%esp),%eax      # Pointer to %eip
602         call early_fixup_exception
603         andl %eax,%eax
604         jnz ex_entry            /* found an exception entry */
605
606 10:
607 #ifdef CONFIG_PRINTK
608         xorl %eax,%eax
609         movw %ax,2(%esp)        /* clean up the segment values on some cpus */
610         movw %ax,6(%esp)
611         movw %ax,34(%esp)
612         leal  40(%esp),%eax
613         pushl %eax              /* %esp before the exception */
614         pushl %ebx
615         pushl %ebp
616         pushl %esi
617         pushl %edi
618         movl %cr2,%eax
619         pushl %eax
620         pushl (20+6*4)(%esp)    /* trapno */
621         pushl $fault_msg
622         call printk
623 #endif
624         call dump_stack
625 hlt_loop:
626         hlt
627         jmp hlt_loop
628
629 ex_entry:
630         pop %es
631         pop %ds
632         pop %edx
633         pop %ecx
634         pop %eax
635         addl $8,%esp            /* drop vector number and error code */
636         decl %ss:early_recursion_flag
637         iret
638 ENDPROC(early_idt_handler)
639
640 /* This is the default interrupt "handler" :-) */
641         ALIGN
642 ignore_int:
643         cld
644 #ifdef CONFIG_PRINTK
645         pushl %eax
646         pushl %ecx
647         pushl %edx
648         pushl %es
649         pushl %ds
650         movl $(__KERNEL_DS),%eax
651         movl %eax,%ds
652         movl %eax,%es
653         cmpl $2,early_recursion_flag
654         je hlt_loop
655         incl early_recursion_flag
656         pushl 16(%esp)
657         pushl 24(%esp)
658         pushl 32(%esp)
659         pushl 40(%esp)
660         pushl $int_msg
661         call printk
662
663         call dump_stack
664
665         addl $(5*4),%esp
666         popl %ds
667         popl %es
668         popl %edx
669         popl %ecx
670         popl %eax
671 #endif
672         iret
673 ENDPROC(ignore_int)
674 __INITDATA
675         .align 4
676 early_recursion_flag:
677         .long 0
678
679 __REFDATA
680         .align 4
681 ENTRY(initial_code)
682         .long i386_start_kernel
683 ENTRY(setup_once_ref)
684         .long setup_once
685
686 /*
687  * BSS section
688  */
689 __PAGE_ALIGNED_BSS
690         .align PAGE_SIZE
691 #ifdef CONFIG_X86_PAE
692 initial_pg_pmd:
693         .fill 1024*KPMDS,4,0
694 #else
695 ENTRY(initial_page_table)
696         .fill 1024,4,0
697 #endif
698 initial_pg_fixmap:
699         .fill 1024,4,0
700 ENTRY(empty_zero_page)
701         .fill 4096,1,0
702 ENTRY(swapper_pg_dir)
703         .fill 1024,4,0
704
705 /*
706  * This starts the data section.
707  */
708 #ifdef CONFIG_X86_PAE
709 __PAGE_ALIGNED_DATA
710         /* Page-aligned for the benefit of paravirt? */
711         .align PAGE_SIZE
712 ENTRY(initial_page_table)
713         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0     /* low identity map */
714 # if KPMDS == 3
715         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0
716         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR+0x1000),0
717         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR+0x2000),0
718 # elif KPMDS == 2
719         .long   0,0
720         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0
721         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR+0x1000),0
722 # elif KPMDS == 1
723         .long   0,0
724         .long   0,0
725         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0
726 # else
727 #  error "Kernel PMDs should be 1, 2 or 3"
728 # endif
729         .align PAGE_SIZE                /* needs to be page-sized too */
730 #endif
731
732 .data
733 .balign 4
734 ENTRY(stack_start)
735         .long init_thread_union+THREAD_SIZE
736
737 __INITRODATA
738 int_msg:
739         .asciz "Unknown interrupt or fault at: %p %p %p\n"
740
741 fault_msg:
742 /* fault info: */
743         .ascii "BUG: Int %d: CR2 %p\n"
744 /* regs pushed in early_idt_handler: */
745         .ascii "     EDI %p  ESI %p  EBP %p  EBX %p\n"
746         .ascii "     ESP %p   ES %p   DS %p\n"
747         .ascii "     EDX %p  ECX %p  EAX %p\n"
748 /* fault frame: */
749         .ascii "     vec %p  err %p  EIP %p   CS %p  flg %p\n"
750         .ascii "Stack: %p %p %p %p %p %p %p %p\n"
751         .ascii "       %p %p %p %p %p %p %p %p\n"
752         .asciz "       %p %p %p %p %p %p %p %p\n"
753
754 #include "../../x86/xen/xen-head.S"
755
756 /*
757  * The IDT and GDT 'descriptors' are a strange 48-bit object
758  * only used by the lidt and lgdt instructions. They are not
759  * like usual segment descriptors - they consist of a 16-bit
760  * segment size, and 32-bit linear address value:
761  */
762
763         .data
764 .globl boot_gdt_descr
765 .globl idt_descr
766
767         ALIGN
768 # early boot GDT descriptor (must use 1:1 address mapping)
769         .word 0                         # 32 bit align gdt_desc.address
770 boot_gdt_descr:
771         .word __BOOT_DS+7
772         .long boot_gdt - __PAGE_OFFSET
773
774         .word 0                         # 32-bit align idt_desc.address
775 idt_descr:
776         .word IDT_ENTRIES*8-1           # idt contains 256 entries
777         .long idt_table
778
779 # boot GDT descriptor (later on used by CPU#0):
780         .word 0                         # 32 bit align gdt_desc.address
781 ENTRY(early_gdt_descr)
782         .word GDT_ENTRIES*8-1
783         .long gdt_page                  /* Overwritten for secondary CPUs */
784
785 /*
786  * The boot_gdt must mirror the equivalent in setup.S and is
787  * used only for booting.
788  */
789         .align L1_CACHE_BYTES
790 ENTRY(boot_gdt)
791         .fill GDT_ENTRY_BOOT_CS,8,0
792         .quad 0x00cf9a000000ffff        /* kernel 4GB code at 0x00000000 */
793         .quad 0x00cf92000000ffff        /* kernel 4GB data at 0x00000000 */