x86: Detect CPUID support early at boot
[~shefty/rdma-dev.git] / arch / x86 / kernel / head_32.S
1 /*
2  *
3  *  Copyright (C) 1991, 1992  Linus Torvalds
4  *
5  *  Enhanced CPU detection and feature setting code by Mike Jagdis
6  *  and Martin Mares, November 1997.
7  */
8
9 .text
10 #include <linux/threads.h>
11 #include <linux/init.h>
12 #include <linux/linkage.h>
13 #include <asm/segment.h>
14 #include <asm/page_types.h>
15 #include <asm/pgtable_types.h>
16 #include <asm/cache.h>
17 #include <asm/thread_info.h>
18 #include <asm/asm-offsets.h>
19 #include <asm/setup.h>
20 #include <asm/processor-flags.h>
21 #include <asm/msr-index.h>
22 #include <asm/cpufeature.h>
23 #include <asm/percpu.h>
24 #include <asm/nops.h>
25
26 /* Physical address */
27 #define pa(X) ((X) - __PAGE_OFFSET)
28
29 /*
30  * References to members of the new_cpu_data structure.
31  */
32
33 #define X86             new_cpu_data+CPUINFO_x86
34 #define X86_VENDOR      new_cpu_data+CPUINFO_x86_vendor
35 #define X86_MODEL       new_cpu_data+CPUINFO_x86_model
36 #define X86_MASK        new_cpu_data+CPUINFO_x86_mask
37 #define X86_HARD_MATH   new_cpu_data+CPUINFO_hard_math
38 #define X86_CPUID       new_cpu_data+CPUINFO_cpuid_level
39 #define X86_CAPABILITY  new_cpu_data+CPUINFO_x86_capability
40 #define X86_VENDOR_ID   new_cpu_data+CPUINFO_x86_vendor_id
41
42 /*
43  * This is how much memory in addition to the memory covered up to
44  * and including _end we need mapped initially.
45  * We need:
46  *     (KERNEL_IMAGE_SIZE/4096) / 1024 pages (worst case, non PAE)
47  *     (KERNEL_IMAGE_SIZE/4096) / 512 + 4 pages (worst case for PAE)
48  *
49  * Modulo rounding, each megabyte assigned here requires a kilobyte of
50  * memory, which is currently unreclaimed.
51  *
52  * This should be a multiple of a page.
53  *
54  * KERNEL_IMAGE_SIZE should be greater than pa(_end)
55  * and small than max_low_pfn, otherwise will waste some page table entries
56  */
57
58 #if PTRS_PER_PMD > 1
59 #define PAGE_TABLE_SIZE(pages) (((pages) / PTRS_PER_PMD) + PTRS_PER_PGD)
60 #else
61 #define PAGE_TABLE_SIZE(pages) ((pages) / PTRS_PER_PGD)
62 #endif
63
64 /* Number of possible pages in the lowmem region */
65 LOWMEM_PAGES = (((1<<32) - __PAGE_OFFSET) >> PAGE_SHIFT)
66         
67 /* Enough space to fit pagetables for the low memory linear map */
68 MAPPING_BEYOND_END = PAGE_TABLE_SIZE(LOWMEM_PAGES) << PAGE_SHIFT
69
70 /*
71  * Worst-case size of the kernel mapping we need to make:
72  * a relocatable kernel can live anywhere in lowmem, so we need to be able
73  * to map all of lowmem.
74  */
75 KERNEL_PAGES = LOWMEM_PAGES
76
77 INIT_MAP_SIZE = PAGE_TABLE_SIZE(KERNEL_PAGES) * PAGE_SIZE
78 RESERVE_BRK(pagetables, INIT_MAP_SIZE)
79
80 /*
81  * 32-bit kernel entrypoint; only used by the boot CPU.  On entry,
82  * %esi points to the real-mode code as a 32-bit pointer.
83  * CS and DS must be 4 GB flat segments, but we don't depend on
84  * any particular GDT layout, because we load our own as soon as we
85  * can.
86  */
87 __HEAD
88 ENTRY(startup_32)
89         movl pa(stack_start),%ecx
90         
91         /* test KEEP_SEGMENTS flag to see if the bootloader is asking
92                 us to not reload segments */
93         testb $(1<<6), BP_loadflags(%esi)
94         jnz 2f
95
96 /*
97  * Set segments to known values.
98  */
99         lgdt pa(boot_gdt_descr)
100         movl $(__BOOT_DS),%eax
101         movl %eax,%ds
102         movl %eax,%es
103         movl %eax,%fs
104         movl %eax,%gs
105         movl %eax,%ss
106 2:
107         leal -__PAGE_OFFSET(%ecx),%esp
108
109 /*
110  * Clear BSS first so that there are no surprises...
111  */
112         cld
113         xorl %eax,%eax
114         movl $pa(__bss_start),%edi
115         movl $pa(__bss_stop),%ecx
116         subl %edi,%ecx
117         shrl $2,%ecx
118         rep ; stosl
119 /*
120  * Copy bootup parameters out of the way.
121  * Note: %esi still has the pointer to the real-mode data.
122  * With the kexec as boot loader, parameter segment might be loaded beyond
123  * kernel image and might not even be addressable by early boot page tables.
124  * (kexec on panic case). Hence copy out the parameters before initializing
125  * page tables.
126  */
127         movl $pa(boot_params),%edi
128         movl $(PARAM_SIZE/4),%ecx
129         cld
130         rep
131         movsl
132         movl pa(boot_params) + NEW_CL_POINTER,%esi
133         andl %esi,%esi
134         jz 1f                   # No command line
135         movl $pa(boot_command_line),%edi
136         movl $(COMMAND_LINE_SIZE/4),%ecx
137         rep
138         movsl
139 1:
140
141 #ifdef CONFIG_OLPC
142         /* save OFW's pgdir table for later use when calling into OFW */
143         movl %cr3, %eax
144         movl %eax, pa(olpc_ofw_pgd)
145 #endif
146
147 /*
148  * Initialize page tables.  This creates a PDE and a set of page
149  * tables, which are located immediately beyond __brk_base.  The variable
150  * _brk_end is set up to point to the first "safe" location.
151  * Mappings are created both at virtual address 0 (identity mapping)
152  * and PAGE_OFFSET for up to _end.
153  */
154 #ifdef CONFIG_X86_PAE
155
156         /*
157          * In PAE mode initial_page_table is statically defined to contain
158          * enough entries to cover the VMSPLIT option (that is the top 1, 2 or 3
159          * entries). The identity mapping is handled by pointing two PGD entries
160          * to the first kernel PMD.
161          *
162          * Note the upper half of each PMD or PTE are always zero at this stage.
163          */
164
165 #define KPMDS (((-__PAGE_OFFSET) >> 30) & 3) /* Number of kernel PMDs */
166
167         xorl %ebx,%ebx                          /* %ebx is kept at zero */
168
169         movl $pa(__brk_base), %edi
170         movl $pa(initial_pg_pmd), %edx
171         movl $PTE_IDENT_ATTR, %eax
172 10:
173         leal PDE_IDENT_ATTR(%edi),%ecx          /* Create PMD entry */
174         movl %ecx,(%edx)                        /* Store PMD entry */
175                                                 /* Upper half already zero */
176         addl $8,%edx
177         movl $512,%ecx
178 11:
179         stosl
180         xchgl %eax,%ebx
181         stosl
182         xchgl %eax,%ebx
183         addl $0x1000,%eax
184         loop 11b
185
186         /*
187          * End condition: we must map up to the end + MAPPING_BEYOND_END.
188          */
189         movl $pa(_end) + MAPPING_BEYOND_END + PTE_IDENT_ATTR, %ebp
190         cmpl %ebp,%eax
191         jb 10b
192 1:
193         addl $__PAGE_OFFSET, %edi
194         movl %edi, pa(_brk_end)
195         shrl $12, %eax
196         movl %eax, pa(max_pfn_mapped)
197
198         /* Do early initialization of the fixmap area */
199         movl $pa(initial_pg_fixmap)+PDE_IDENT_ATTR,%eax
200         movl %eax,pa(initial_pg_pmd+0x1000*KPMDS-8)
201 #else   /* Not PAE */
202
203 page_pde_offset = (__PAGE_OFFSET >> 20);
204
205         movl $pa(__brk_base), %edi
206         movl $pa(initial_page_table), %edx
207         movl $PTE_IDENT_ATTR, %eax
208 10:
209         leal PDE_IDENT_ATTR(%edi),%ecx          /* Create PDE entry */
210         movl %ecx,(%edx)                        /* Store identity PDE entry */
211         movl %ecx,page_pde_offset(%edx)         /* Store kernel PDE entry */
212         addl $4,%edx
213         movl $1024, %ecx
214 11:
215         stosl
216         addl $0x1000,%eax
217         loop 11b
218         /*
219          * End condition: we must map up to the end + MAPPING_BEYOND_END.
220          */
221         movl $pa(_end) + MAPPING_BEYOND_END + PTE_IDENT_ATTR, %ebp
222         cmpl %ebp,%eax
223         jb 10b
224         addl $__PAGE_OFFSET, %edi
225         movl %edi, pa(_brk_end)
226         shrl $12, %eax
227         movl %eax, pa(max_pfn_mapped)
228
229         /* Do early initialization of the fixmap area */
230         movl $pa(initial_pg_fixmap)+PDE_IDENT_ATTR,%eax
231         movl %eax,pa(initial_page_table+0xffc)
232 #endif
233
234 #ifdef CONFIG_PARAVIRT
235         /* This is can only trip for a broken bootloader... */
236         cmpw $0x207, pa(boot_params + BP_version)
237         jb default_entry
238
239         /* Paravirt-compatible boot parameters.  Look to see what architecture
240                 we're booting under. */
241         movl pa(boot_params + BP_hardware_subarch), %eax
242         cmpl $num_subarch_entries, %eax
243         jae bad_subarch
244
245         movl pa(subarch_entries)(,%eax,4), %eax
246         subl $__PAGE_OFFSET, %eax
247         jmp *%eax
248
249 bad_subarch:
250 WEAK(lguest_entry)
251 WEAK(xen_entry)
252         /* Unknown implementation; there's really
253            nothing we can do at this point. */
254         ud2a
255
256         __INITDATA
257
258 subarch_entries:
259         .long default_entry             /* normal x86/PC */
260         .long lguest_entry              /* lguest hypervisor */
261         .long xen_entry                 /* Xen hypervisor */
262         .long default_entry             /* Moorestown MID */
263 num_subarch_entries = (. - subarch_entries) / 4
264 .previous
265 #else
266         jmp default_entry
267 #endif /* CONFIG_PARAVIRT */
268
269 #ifdef CONFIG_HOTPLUG_CPU
270 /*
271  * Boot CPU0 entry point. It's called from play_dead(). Everything has been set
272  * up already except stack. We just set up stack here. Then call
273  * start_secondary().
274  */
275 ENTRY(start_cpu0)
276         movl stack_start, %ecx
277         movl %ecx, %esp
278         jmp  *(initial_code)
279 ENDPROC(start_cpu0)
280 #endif
281
282 /*
283  * Non-boot CPU entry point; entered from trampoline.S
284  * We can't lgdt here, because lgdt itself uses a data segment, but
285  * we know the trampoline has already loaded the boot_gdt for us.
286  *
287  * If cpu hotplug is not supported then this code can go in init section
288  * which will be freed later
289  */
290 __CPUINIT
291 ENTRY(startup_32_smp)
292         cld
293         movl $(__BOOT_DS),%eax
294         movl %eax,%ds
295         movl %eax,%es
296         movl %eax,%fs
297         movl %eax,%gs
298         movl pa(stack_start),%ecx
299         movl %eax,%ss
300         leal -__PAGE_OFFSET(%ecx),%esp
301
302 default_entry:
303 #define CR0_STATE       (X86_CR0_PE | X86_CR0_MP | X86_CR0_ET | \
304                          X86_CR0_NE | X86_CR0_WP | X86_CR0_AM | \
305                          X86_CR0_PG)
306         movl $(CR0_STATE & ~X86_CR0_PG),%eax
307         movl %eax,%cr0
308
309 /*
310  * We want to start out with EFLAGS unambiguously cleared. Some BIOSes leave
311  * bits like NT set. This would confuse the debugger if this code is traced. So
312  * initialize them properly now before switching to protected mode. That means
313  * DF in particular (even though we have cleared it earlier after copying the
314  * command line) because GCC expects it.
315  */
316         pushl $0
317         popfl
318
319 /*
320  * New page tables may be in 4Mbyte page mode and may be using the global pages.
321  *
322  * NOTE! If we are on a 486 we may have no cr4 at all! Specifically, cr4 exists
323  * if and only if CPUID exists and has flags other than the FPU flag set.
324  */
325         movl $-1,pa(X86_CPUID)          # preset CPUID level
326         movl $X86_EFLAGS_ID,%ecx
327         pushl %ecx
328         popfl                           # set EFLAGS=ID
329         pushfl
330         popl %eax                       # get EFLAGS
331         testl $X86_EFLAGS_ID,%eax       # did EFLAGS.ID remained set?
332         jz 6f                           # hw disallowed setting of ID bit
333                                         # which means no CPUID and no CR4
334
335         xorl %eax,%eax
336         cpuid
337         movl %eax,pa(X86_CPUID)         # save largest std CPUID function
338
339         movl $1,%eax
340         cpuid
341         andl $~1,%edx                   # Ignore CPUID.FPU
342         jz 6f                           # No flags or only CPUID.FPU = no CR4
343
344         movl pa(mmu_cr4_features),%eax
345         movl %eax,%cr4
346
347         testb $X86_CR4_PAE, %al         # check if PAE is enabled
348         jz 6f
349
350         /* Check if extended functions are implemented */
351         movl $0x80000000, %eax
352         cpuid
353         /* Value must be in the range 0x80000001 to 0x8000ffff */
354         subl $0x80000001, %eax
355         cmpl $(0x8000ffff-0x80000001), %eax
356         ja 6f
357
358         /* Clear bogus XD_DISABLE bits */
359         call verify_cpu
360
361         mov $0x80000001, %eax
362         cpuid
363         /* Execute Disable bit supported? */
364         btl $(X86_FEATURE_NX & 31), %edx
365         jnc 6f
366
367         /* Setup EFER (Extended Feature Enable Register) */
368         movl $MSR_EFER, %ecx
369         rdmsr
370
371         btsl $_EFER_NX, %eax
372         /* Make changes effective */
373         wrmsr
374
375 6:
376
377 /*
378  * Enable paging
379  */
380         movl $pa(initial_page_table), %eax
381         movl %eax,%cr3          /* set the page table pointer.. */
382         movl $CR0_STATE,%eax
383         movl %eax,%cr0          /* ..and set paging (PG) bit */
384         ljmp $__BOOT_CS,$1f     /* Clear prefetch and normalize %eip */
385 1:
386         /* Shift the stack pointer to a virtual address */
387         addl $__PAGE_OFFSET, %esp
388
389 /*
390  * start system 32-bit setup. We need to re-do some of the things done
391  * in 16-bit mode for the "real" operations.
392  */
393         movl setup_once_ref,%eax
394         andl %eax,%eax
395         jz 1f                           # Did we do this already?
396         call *%eax
397 1:
398
399 /*
400  * Check if it is 486
401  */
402         movl $-1,X86_CPUID      # -1 for no CPUID initially
403         movb $4,X86             # at least 486
404         pushfl                  # push EFLAGS
405         popl %eax               # get EFLAGS
406         movl %eax,%ecx          # save original EFLAGS
407         xorl $0x200000,%eax     # flip ID bit in EFLAGS
408         pushl %eax              # copy to EFLAGS
409         popfl                   # set EFLAGS
410         pushfl                  # get new EFLAGS
411         popl %eax               # put it in eax
412         xorl %ecx,%eax          # change in flags
413         testl $0x200000,%eax    # check if ID bit changed
414         je is486
415
416         /* get vendor info */
417         xorl %eax,%eax                  # call CPUID with 0 -> return vendor ID
418         cpuid
419         movl %eax,X86_CPUID             # save CPUID level
420         movl %ebx,X86_VENDOR_ID         # lo 4 chars
421         movl %edx,X86_VENDOR_ID+4       # next 4 chars
422         movl %ecx,X86_VENDOR_ID+8       # last 4 chars
423
424         orl %eax,%eax                   # do we have processor info as well?
425         je is486
426
427         movl $1,%eax            # Use the CPUID instruction to get CPU type
428         cpuid
429         movb %al,%cl            # save reg for future use
430         andb $0x0f,%ah          # mask processor family
431         movb %ah,X86
432         andb $0xf0,%al          # mask model
433         shrb $4,%al
434         movb %al,X86_MODEL
435         andb $0x0f,%cl          # mask mask revision
436         movb %cl,X86_MASK
437         movl %edx,X86_CAPABILITY
438
439 is486:  movl $0x50022,%ecx      # set AM, WP, NE and MP
440         movl %cr0,%eax
441         andl $0x80000011,%eax   # Save PG,PE,ET
442         orl %ecx,%eax
443         movl %eax,%cr0
444
445         call check_x87
446         lgdt early_gdt_descr
447         lidt idt_descr
448         ljmp $(__KERNEL_CS),$1f
449 1:      movl $(__KERNEL_DS),%eax        # reload all the segment registers
450         movl %eax,%ss                   # after changing gdt.
451
452         movl $(__USER_DS),%eax          # DS/ES contains default USER segment
453         movl %eax,%ds
454         movl %eax,%es
455
456         movl $(__KERNEL_PERCPU), %eax
457         movl %eax,%fs                   # set this cpu's percpu
458
459         movl $(__KERNEL_STACK_CANARY),%eax
460         movl %eax,%gs
461
462         xorl %eax,%eax                  # Clear LDT
463         lldt %ax
464
465         pushl $0                # fake return address for unwinder
466         jmp *(initial_code)
467
468 /*
469  * We depend on ET to be correct. This checks for 287/387.
470  */
471 check_x87:
472         movb $0,X86_HARD_MATH
473         clts
474         fninit
475         fstsw %ax
476         cmpb $0,%al
477         je 1f
478         movl %cr0,%eax          /* no coprocessor: have to set bits */
479         xorl $4,%eax            /* set EM */
480         movl %eax,%cr0
481         ret
482         ALIGN
483 1:      movb $1,X86_HARD_MATH
484         .byte 0xDB,0xE4         /* fsetpm for 287, ignored by 387 */
485         ret
486
487         
488 #include "verify_cpu.S"
489
490 /*
491  *  setup_once
492  *
493  *  The setup work we only want to run on the BSP.
494  *
495  *  Warning: %esi is live across this function.
496  */
497 __INIT
498 setup_once:
499         /*
500          * Set up a idt with 256 entries pointing to ignore_int,
501          * interrupt gates. It doesn't actually load idt - that needs
502          * to be done on each CPU. Interrupts are enabled elsewhere,
503          * when we can be relatively sure everything is ok.
504          */
505
506         movl $idt_table,%edi
507         movl $early_idt_handlers,%eax
508         movl $NUM_EXCEPTION_VECTORS,%ecx
509 1:
510         movl %eax,(%edi)
511         movl %eax,4(%edi)
512         /* interrupt gate, dpl=0, present */
513         movl $(0x8E000000 + __KERNEL_CS),2(%edi)
514         addl $9,%eax
515         addl $8,%edi
516         loop 1b
517
518         movl $256 - NUM_EXCEPTION_VECTORS,%ecx
519         movl $ignore_int,%edx
520         movl $(__KERNEL_CS << 16),%eax
521         movw %dx,%ax            /* selector = 0x0010 = cs */
522         movw $0x8E00,%dx        /* interrupt gate - dpl=0, present */
523 2:
524         movl %eax,(%edi)
525         movl %edx,4(%edi)
526         addl $8,%edi
527         loop 2b
528
529 #ifdef CONFIG_CC_STACKPROTECTOR
530         /*
531          * Configure the stack canary. The linker can't handle this by
532          * relocation.  Manually set base address in stack canary
533          * segment descriptor.
534          */
535         movl $gdt_page,%eax
536         movl $stack_canary,%ecx
537         movw %cx, 8 * GDT_ENTRY_STACK_CANARY + 2(%eax)
538         shrl $16, %ecx
539         movb %cl, 8 * GDT_ENTRY_STACK_CANARY + 4(%eax)
540         movb %ch, 8 * GDT_ENTRY_STACK_CANARY + 7(%eax)
541 #endif
542
543         andl $0,setup_once_ref  /* Once is enough, thanks */
544         ret
545
546 ENTRY(early_idt_handlers)
547         # 36(%esp) %eflags
548         # 32(%esp) %cs
549         # 28(%esp) %eip
550         # 24(%rsp) error code
551         i = 0
552         .rept NUM_EXCEPTION_VECTORS
553         .if (EXCEPTION_ERRCODE_MASK >> i) & 1
554         ASM_NOP2
555         .else
556         pushl $0                # Dummy error code, to make stack frame uniform
557         .endif
558         pushl $i                # 20(%esp) Vector number
559         jmp early_idt_handler
560         i = i + 1
561         .endr
562 ENDPROC(early_idt_handlers)
563         
564         /* This is global to keep gas from relaxing the jumps */
565 ENTRY(early_idt_handler)
566         cld
567         cmpl $2,%ss:early_recursion_flag
568         je hlt_loop
569         incl %ss:early_recursion_flag
570
571         push %eax               # 16(%esp)
572         push %ecx               # 12(%esp)
573         push %edx               #  8(%esp)
574         push %ds                #  4(%esp)
575         push %es                #  0(%esp)
576         movl $(__KERNEL_DS),%eax
577         movl %eax,%ds
578         movl %eax,%es
579
580         cmpl $(__KERNEL_CS),32(%esp)
581         jne 10f
582
583         leal 28(%esp),%eax      # Pointer to %eip
584         call early_fixup_exception
585         andl %eax,%eax
586         jnz ex_entry            /* found an exception entry */
587
588 10:
589 #ifdef CONFIG_PRINTK
590         xorl %eax,%eax
591         movw %ax,2(%esp)        /* clean up the segment values on some cpus */
592         movw %ax,6(%esp)
593         movw %ax,34(%esp)
594         leal  40(%esp),%eax
595         pushl %eax              /* %esp before the exception */
596         pushl %ebx
597         pushl %ebp
598         pushl %esi
599         pushl %edi
600         movl %cr2,%eax
601         pushl %eax
602         pushl (20+6*4)(%esp)    /* trapno */
603         pushl $fault_msg
604         call printk
605 #endif
606         call dump_stack
607 hlt_loop:
608         hlt
609         jmp hlt_loop
610
611 ex_entry:
612         pop %es
613         pop %ds
614         pop %edx
615         pop %ecx
616         pop %eax
617         addl $8,%esp            /* drop vector number and error code */
618         decl %ss:early_recursion_flag
619         iret
620 ENDPROC(early_idt_handler)
621
622 /* This is the default interrupt "handler" :-) */
623         ALIGN
624 ignore_int:
625         cld
626 #ifdef CONFIG_PRINTK
627         pushl %eax
628         pushl %ecx
629         pushl %edx
630         pushl %es
631         pushl %ds
632         movl $(__KERNEL_DS),%eax
633         movl %eax,%ds
634         movl %eax,%es
635         cmpl $2,early_recursion_flag
636         je hlt_loop
637         incl early_recursion_flag
638         pushl 16(%esp)
639         pushl 24(%esp)
640         pushl 32(%esp)
641         pushl 40(%esp)
642         pushl $int_msg
643         call printk
644
645         call dump_stack
646
647         addl $(5*4),%esp
648         popl %ds
649         popl %es
650         popl %edx
651         popl %ecx
652         popl %eax
653 #endif
654         iret
655 ENDPROC(ignore_int)
656 __INITDATA
657         .align 4
658 early_recursion_flag:
659         .long 0
660
661 __REFDATA
662         .align 4
663 ENTRY(initial_code)
664         .long i386_start_kernel
665 ENTRY(setup_once_ref)
666         .long setup_once
667
668 /*
669  * BSS section
670  */
671 __PAGE_ALIGNED_BSS
672         .align PAGE_SIZE
673 #ifdef CONFIG_X86_PAE
674 initial_pg_pmd:
675         .fill 1024*KPMDS,4,0
676 #else
677 ENTRY(initial_page_table)
678         .fill 1024,4,0
679 #endif
680 initial_pg_fixmap:
681         .fill 1024,4,0
682 ENTRY(empty_zero_page)
683         .fill 4096,1,0
684 ENTRY(swapper_pg_dir)
685         .fill 1024,4,0
686
687 /*
688  * This starts the data section.
689  */
690 #ifdef CONFIG_X86_PAE
691 __PAGE_ALIGNED_DATA
692         /* Page-aligned for the benefit of paravirt? */
693         .align PAGE_SIZE
694 ENTRY(initial_page_table)
695         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0     /* low identity map */
696 # if KPMDS == 3
697         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0
698         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR+0x1000),0
699         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR+0x2000),0
700 # elif KPMDS == 2
701         .long   0,0
702         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0
703         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR+0x1000),0
704 # elif KPMDS == 1
705         .long   0,0
706         .long   0,0
707         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0
708 # else
709 #  error "Kernel PMDs should be 1, 2 or 3"
710 # endif
711         .align PAGE_SIZE                /* needs to be page-sized too */
712 #endif
713
714 .data
715 .balign 4
716 ENTRY(stack_start)
717         .long init_thread_union+THREAD_SIZE
718
719 __INITRODATA
720 int_msg:
721         .asciz "Unknown interrupt or fault at: %p %p %p\n"
722
723 fault_msg:
724 /* fault info: */
725         .ascii "BUG: Int %d: CR2 %p\n"
726 /* regs pushed in early_idt_handler: */
727         .ascii "     EDI %p  ESI %p  EBP %p  EBX %p\n"
728         .ascii "     ESP %p   ES %p   DS %p\n"
729         .ascii "     EDX %p  ECX %p  EAX %p\n"
730 /* fault frame: */
731         .ascii "     vec %p  err %p  EIP %p   CS %p  flg %p\n"
732         .ascii "Stack: %p %p %p %p %p %p %p %p\n"
733         .ascii "       %p %p %p %p %p %p %p %p\n"
734         .asciz "       %p %p %p %p %p %p %p %p\n"
735
736 #include "../../x86/xen/xen-head.S"
737
738 /*
739  * The IDT and GDT 'descriptors' are a strange 48-bit object
740  * only used by the lidt and lgdt instructions. They are not
741  * like usual segment descriptors - they consist of a 16-bit
742  * segment size, and 32-bit linear address value:
743  */
744
745         .data
746 .globl boot_gdt_descr
747 .globl idt_descr
748
749         ALIGN
750 # early boot GDT descriptor (must use 1:1 address mapping)
751         .word 0                         # 32 bit align gdt_desc.address
752 boot_gdt_descr:
753         .word __BOOT_DS+7
754         .long boot_gdt - __PAGE_OFFSET
755
756         .word 0                         # 32-bit align idt_desc.address
757 idt_descr:
758         .word IDT_ENTRIES*8-1           # idt contains 256 entries
759         .long idt_table
760
761 # boot GDT descriptor (later on used by CPU#0):
762         .word 0                         # 32 bit align gdt_desc.address
763 ENTRY(early_gdt_descr)
764         .word GDT_ENTRIES*8-1
765         .long gdt_page                  /* Overwritten for secondary CPUs */
766
767 /*
768  * The boot_gdt must mirror the equivalent in setup.S and is
769  * used only for booting.
770  */
771         .align L1_CACHE_BYTES
772 ENTRY(boot_gdt)
773         .fill GDT_ENTRY_BOOT_CS,8,0
774         .quad 0x00cf9a000000ffff        /* kernel 4GB code at 0x00000000 */
775         .quad 0x00cf92000000ffff        /* kernel 4GB data at 0x00000000 */