]> git.openfabrics.org - ~shefty/rdma-dev.git/blob - arch/x86/kernel/head_32.S
fa8c1b8e09fb9f65b832c1fb15c84ee4c39b6336
[~shefty/rdma-dev.git] / arch / x86 / kernel / head_32.S
1 /*
2  *
3  *  Copyright (C) 1991, 1992  Linus Torvalds
4  *
5  *  Enhanced CPU detection and feature setting code by Mike Jagdis
6  *  and Martin Mares, November 1997.
7  */
8
9 .text
10 #include <linux/threads.h>
11 #include <linux/init.h>
12 #include <linux/linkage.h>
13 #include <asm/segment.h>
14 #include <asm/page_types.h>
15 #include <asm/pgtable_types.h>
16 #include <asm/cache.h>
17 #include <asm/thread_info.h>
18 #include <asm/asm-offsets.h>
19 #include <asm/setup.h>
20 #include <asm/processor-flags.h>
21 #include <asm/msr-index.h>
22 #include <asm/cpufeature.h>
23 #include <asm/percpu.h>
24
25 /* Physical address */
26 #define pa(X) ((X) - __PAGE_OFFSET)
27
28 /*
29  * References to members of the new_cpu_data structure.
30  */
31
32 #define X86             new_cpu_data+CPUINFO_x86
33 #define X86_VENDOR      new_cpu_data+CPUINFO_x86_vendor
34 #define X86_MODEL       new_cpu_data+CPUINFO_x86_model
35 #define X86_MASK        new_cpu_data+CPUINFO_x86_mask
36 #define X86_HARD_MATH   new_cpu_data+CPUINFO_hard_math
37 #define X86_CPUID       new_cpu_data+CPUINFO_cpuid_level
38 #define X86_CAPABILITY  new_cpu_data+CPUINFO_x86_capability
39 #define X86_VENDOR_ID   new_cpu_data+CPUINFO_x86_vendor_id
40
41 /*
42  * This is how much memory in addition to the memory covered up to
43  * and including _end we need mapped initially.
44  * We need:
45  *     (KERNEL_IMAGE_SIZE/4096) / 1024 pages (worst case, non PAE)
46  *     (KERNEL_IMAGE_SIZE/4096) / 512 + 4 pages (worst case for PAE)
47  *
48  * Modulo rounding, each megabyte assigned here requires a kilobyte of
49  * memory, which is currently unreclaimed.
50  *
51  * This should be a multiple of a page.
52  *
53  * KERNEL_IMAGE_SIZE should be greater than pa(_end)
54  * and small than max_low_pfn, otherwise will waste some page table entries
55  */
56
57 #if PTRS_PER_PMD > 1
58 #define PAGE_TABLE_SIZE(pages) (((pages) / PTRS_PER_PMD) + PTRS_PER_PGD)
59 #else
60 #define PAGE_TABLE_SIZE(pages) ((pages) / PTRS_PER_PGD)
61 #endif
62
63 /* Enough space to fit pagetables for the low memory linear map */
64 MAPPING_BEYOND_END = \
65         PAGE_TABLE_SIZE(((1<<32) - __PAGE_OFFSET) >> PAGE_SHIFT) << PAGE_SHIFT
66
67 /*
68  * Worst-case size of the kernel mapping we need to make:
69  * the worst-case size of the kernel itself, plus the extra we need
70  * to map for the linear map.
71  */
72 KERNEL_PAGES = (KERNEL_IMAGE_SIZE + MAPPING_BEYOND_END)>>PAGE_SHIFT
73
74 INIT_MAP_SIZE = PAGE_TABLE_SIZE(KERNEL_PAGES) * PAGE_SIZE_asm
75 RESERVE_BRK(pagetables, INIT_MAP_SIZE)
76
77 /*
78  * 32-bit kernel entrypoint; only used by the boot CPU.  On entry,
79  * %esi points to the real-mode code as a 32-bit pointer.
80  * CS and DS must be 4 GB flat segments, but we don't depend on
81  * any particular GDT layout, because we load our own as soon as we
82  * can.
83  */
84 __HEAD
85 ENTRY(startup_32)
86         /* test KEEP_SEGMENTS flag to see if the bootloader is asking
87                 us to not reload segments */
88         testb $(1<<6), BP_loadflags(%esi)
89         jnz 2f
90
91 /*
92  * Set segments to known values.
93  */
94         lgdt pa(boot_gdt_descr)
95         movl $(__BOOT_DS),%eax
96         movl %eax,%ds
97         movl %eax,%es
98         movl %eax,%fs
99         movl %eax,%gs
100 2:
101
102 /*
103  * Clear BSS first so that there are no surprises...
104  */
105         cld
106         xorl %eax,%eax
107         movl $pa(__bss_start),%edi
108         movl $pa(__bss_stop),%ecx
109         subl %edi,%ecx
110         shrl $2,%ecx
111         rep ; stosl
112 /*
113  * Copy bootup parameters out of the way.
114  * Note: %esi still has the pointer to the real-mode data.
115  * With the kexec as boot loader, parameter segment might be loaded beyond
116  * kernel image and might not even be addressable by early boot page tables.
117  * (kexec on panic case). Hence copy out the parameters before initializing
118  * page tables.
119  */
120         movl $pa(boot_params),%edi
121         movl $(PARAM_SIZE/4),%ecx
122         cld
123         rep
124         movsl
125         movl pa(boot_params) + NEW_CL_POINTER,%esi
126         andl %esi,%esi
127         jz 1f                   # No comand line
128         movl $pa(boot_command_line),%edi
129         movl $(COMMAND_LINE_SIZE/4),%ecx
130         rep
131         movsl
132 1:
133
134 #ifdef CONFIG_OLPC_OPENFIRMWARE
135         /* save OFW's pgdir table for later use when calling into OFW */
136         movl %cr3, %eax
137         movl %eax, pa(olpc_ofw_pgd)
138 #endif
139
140 #ifdef CONFIG_PARAVIRT
141         /* This is can only trip for a broken bootloader... */
142         cmpw $0x207, pa(boot_params + BP_version)
143         jb default_entry
144
145         /* Paravirt-compatible boot parameters.  Look to see what architecture
146                 we're booting under. */
147         movl pa(boot_params + BP_hardware_subarch), %eax
148         cmpl $num_subarch_entries, %eax
149         jae bad_subarch
150
151         movl pa(subarch_entries)(,%eax,4), %eax
152         subl $__PAGE_OFFSET, %eax
153         jmp *%eax
154
155 bad_subarch:
156 WEAK(lguest_entry)
157 WEAK(xen_entry)
158         /* Unknown implementation; there's really
159            nothing we can do at this point. */
160         ud2a
161
162         __INITDATA
163
164 subarch_entries:
165         .long default_entry             /* normal x86/PC */
166         .long lguest_entry              /* lguest hypervisor */
167         .long xen_entry                 /* Xen hypervisor */
168         .long default_entry             /* Moorestown MID */
169 num_subarch_entries = (. - subarch_entries) / 4
170 .previous
171 #endif /* CONFIG_PARAVIRT */
172
173 /*
174  * Initialize page tables.  This creates a PDE and a set of page
175  * tables, which are located immediately beyond __brk_base.  The variable
176  * _brk_end is set up to point to the first "safe" location.
177  * Mappings are created both at virtual address 0 (identity mapping)
178  * and PAGE_OFFSET for up to _end.
179  *
180  * Note that the stack is not yet set up!
181  */
182 default_entry:
183 #ifdef CONFIG_X86_PAE
184
185         /*
186          * In PAE mode swapper_pg_dir is statically defined to contain enough
187          * entries to cover the VMSPLIT option (that is the top 1, 2 or 3
188          * entries). The identity mapping is handled by pointing two PGD
189          * entries to the first kernel PMD.
190          *
191          * Note the upper half of each PMD or PTE are always zero at
192          * this stage.
193          */
194
195 #define KPMDS (((-__PAGE_OFFSET) >> 30) & 3) /* Number of kernel PMDs */
196
197         xorl %ebx,%ebx                          /* %ebx is kept at zero */
198
199         movl $pa(__brk_base), %edi
200         movl $pa(swapper_pg_pmd), %edx
201         movl $PTE_IDENT_ATTR, %eax
202 10:
203         leal PDE_IDENT_ATTR(%edi),%ecx          /* Create PMD entry */
204         movl %ecx,(%edx)                        /* Store PMD entry */
205                                                 /* Upper half already zero */
206         addl $8,%edx
207         movl $512,%ecx
208 11:
209         stosl
210         xchgl %eax,%ebx
211         stosl
212         xchgl %eax,%ebx
213         addl $0x1000,%eax
214         loop 11b
215
216         /*
217          * End condition: we must map up to the end + MAPPING_BEYOND_END.
218          */
219         movl $pa(_end) + MAPPING_BEYOND_END + PTE_IDENT_ATTR, %ebp
220         cmpl %ebp,%eax
221         jb 10b
222 1:
223         addl $__PAGE_OFFSET, %edi
224         movl %edi, pa(_brk_end)
225         shrl $12, %eax
226         movl %eax, pa(max_pfn_mapped)
227
228         /* Do early initialization of the fixmap area */
229         movl $pa(swapper_pg_fixmap)+PDE_IDENT_ATTR,%eax
230         movl %eax,pa(swapper_pg_pmd+0x1000*KPMDS-8)
231 #else   /* Not PAE */
232
233 page_pde_offset = (__PAGE_OFFSET >> 20);
234
235         movl $pa(__brk_base), %edi
236         movl $pa(swapper_pg_dir), %edx
237         movl $PTE_IDENT_ATTR, %eax
238 10:
239         leal PDE_IDENT_ATTR(%edi),%ecx          /* Create PDE entry */
240         movl %ecx,(%edx)                        /* Store identity PDE entry */
241         movl %ecx,page_pde_offset(%edx)         /* Store kernel PDE entry */
242         addl $4,%edx
243         movl $1024, %ecx
244 11:
245         stosl
246         addl $0x1000,%eax
247         loop 11b
248         /*
249          * End condition: we must map up to the end + MAPPING_BEYOND_END.
250          */
251         movl $pa(_end) + MAPPING_BEYOND_END + PTE_IDENT_ATTR, %ebp
252         cmpl %ebp,%eax
253         jb 10b
254         addl $__PAGE_OFFSET, %edi
255         movl %edi, pa(_brk_end)
256         shrl $12, %eax
257         movl %eax, pa(max_pfn_mapped)
258
259         /* Do early initialization of the fixmap area */
260         movl $pa(swapper_pg_fixmap)+PDE_IDENT_ATTR,%eax
261         movl %eax,pa(swapper_pg_dir+0xffc)
262 #endif
263         jmp 3f
264 /*
265  * Non-boot CPU entry point; entered from trampoline.S
266  * We can't lgdt here, because lgdt itself uses a data segment, but
267  * we know the trampoline has already loaded the boot_gdt for us.
268  *
269  * If cpu hotplug is not supported then this code can go in init section
270  * which will be freed later
271  */
272
273 __CPUINIT
274
275 #ifdef CONFIG_SMP
276 ENTRY(startup_32_smp)
277         cld
278         movl $(__BOOT_DS),%eax
279         movl %eax,%ds
280         movl %eax,%es
281         movl %eax,%fs
282         movl %eax,%gs
283 #endif /* CONFIG_SMP */
284 3:
285
286 /*
287  *      New page tables may be in 4Mbyte page mode and may
288  *      be using the global pages. 
289  *
290  *      NOTE! If we are on a 486 we may have no cr4 at all!
291  *      So we do not try to touch it unless we really have
292  *      some bits in it to set.  This won't work if the BSP
293  *      implements cr4 but this AP does not -- very unlikely
294  *      but be warned!  The same applies to the pse feature
295  *      if not equally supported. --macro
296  *
297  *      NOTE! We have to correct for the fact that we're
298  *      not yet offset PAGE_OFFSET..
299  */
300 #define cr4_bits pa(mmu_cr4_features)
301         movl cr4_bits,%edx
302         andl %edx,%edx
303         jz 6f
304         movl %cr4,%eax          # Turn on paging options (PSE,PAE,..)
305         orl %edx,%eax
306         movl %eax,%cr4
307
308         testb $X86_CR4_PAE, %al         # check if PAE is enabled
309         jz 6f
310
311         /* Check if extended functions are implemented */
312         movl $0x80000000, %eax
313         cpuid
314         /* Value must be in the range 0x80000001 to 0x8000ffff */
315         subl $0x80000001, %eax
316         cmpl $(0x8000ffff-0x80000001), %eax
317         ja 6f
318         mov $0x80000001, %eax
319         cpuid
320         /* Execute Disable bit supported? */
321         btl $(X86_FEATURE_NX & 31), %edx
322         jnc 6f
323
324         /* Setup EFER (Extended Feature Enable Register) */
325         movl $MSR_EFER, %ecx
326         rdmsr
327
328         btsl $_EFER_NX, %eax
329         /* Make changes effective */
330         wrmsr
331
332 6:
333
334 /*
335  * Enable paging
336  */
337         movl pa(initial_page_table), %eax
338         movl %eax,%cr3          /* set the page table pointer.. */
339         movl %cr0,%eax
340         orl  $X86_CR0_PG,%eax
341         movl %eax,%cr0          /* ..and set paging (PG) bit */
342         ljmp $__BOOT_CS,$1f     /* Clear prefetch and normalize %eip */
343 1:
344         /* Set up the stack pointer */
345         lss stack_start,%esp
346
347 /*
348  * Initialize eflags.  Some BIOS's leave bits like NT set.  This would
349  * confuse the debugger if this code is traced.
350  * XXX - best to initialize before switching to protected mode.
351  */
352         pushl $0
353         popfl
354
355 #ifdef CONFIG_SMP
356         cmpb $0, ready
357         jz  1f                          /* Initial CPU cleans BSS */
358         jmp checkCPUtype
359 1:
360 #endif /* CONFIG_SMP */
361
362 /*
363  * start system 32-bit setup. We need to re-do some of the things done
364  * in 16-bit mode for the "real" operations.
365  */
366         call setup_idt
367
368 checkCPUtype:
369
370         movl $-1,X86_CPUID              #  -1 for no CPUID initially
371
372 /* check if it is 486 or 386. */
373 /*
374  * XXX - this does a lot of unnecessary setup.  Alignment checks don't
375  * apply at our cpl of 0 and the stack ought to be aligned already, and
376  * we don't need to preserve eflags.
377  */
378
379         movb $3,X86             # at least 386
380         pushfl                  # push EFLAGS
381         popl %eax               # get EFLAGS
382         movl %eax,%ecx          # save original EFLAGS
383         xorl $0x240000,%eax     # flip AC and ID bits in EFLAGS
384         pushl %eax              # copy to EFLAGS
385         popfl                   # set EFLAGS
386         pushfl                  # get new EFLAGS
387         popl %eax               # put it in eax
388         xorl %ecx,%eax          # change in flags
389         pushl %ecx              # restore original EFLAGS
390         popfl
391         testl $0x40000,%eax     # check if AC bit changed
392         je is386
393
394         movb $4,X86             # at least 486
395         testl $0x200000,%eax    # check if ID bit changed
396         je is486
397
398         /* get vendor info */
399         xorl %eax,%eax                  # call CPUID with 0 -> return vendor ID
400         cpuid
401         movl %eax,X86_CPUID             # save CPUID level
402         movl %ebx,X86_VENDOR_ID         # lo 4 chars
403         movl %edx,X86_VENDOR_ID+4       # next 4 chars
404         movl %ecx,X86_VENDOR_ID+8       # last 4 chars
405
406         orl %eax,%eax                   # do we have processor info as well?
407         je is486
408
409         movl $1,%eax            # Use the CPUID instruction to get CPU type
410         cpuid
411         movb %al,%cl            # save reg for future use
412         andb $0x0f,%ah          # mask processor family
413         movb %ah,X86
414         andb $0xf0,%al          # mask model
415         shrb $4,%al
416         movb %al,X86_MODEL
417         andb $0x0f,%cl          # mask mask revision
418         movb %cl,X86_MASK
419         movl %edx,X86_CAPABILITY
420
421 is486:  movl $0x50022,%ecx      # set AM, WP, NE and MP
422         jmp 2f
423
424 is386:  movl $2,%ecx            # set MP
425 2:      movl %cr0,%eax
426         andl $0x80000011,%eax   # Save PG,PE,ET
427         orl %ecx,%eax
428         movl %eax,%cr0
429
430         call check_x87
431         lgdt early_gdt_descr
432         lidt idt_descr
433         ljmp $(__KERNEL_CS),$1f
434 1:      movl $(__KERNEL_DS),%eax        # reload all the segment registers
435         movl %eax,%ss                   # after changing gdt.
436
437         movl $(__USER_DS),%eax          # DS/ES contains default USER segment
438         movl %eax,%ds
439         movl %eax,%es
440
441         movl $(__KERNEL_PERCPU), %eax
442         movl %eax,%fs                   # set this cpu's percpu
443
444 #ifdef CONFIG_CC_STACKPROTECTOR
445         /*
446          * The linker can't handle this by relocation.  Manually set
447          * base address in stack canary segment descriptor.
448          */
449         cmpb $0,ready
450         jne 1f
451         movl $gdt_page,%eax
452         movl $stack_canary,%ecx
453         movw %cx, 8 * GDT_ENTRY_STACK_CANARY + 2(%eax)
454         shrl $16, %ecx
455         movb %cl, 8 * GDT_ENTRY_STACK_CANARY + 4(%eax)
456         movb %ch, 8 * GDT_ENTRY_STACK_CANARY + 7(%eax)
457 1:
458 #endif
459         movl $(__KERNEL_STACK_CANARY),%eax
460         movl %eax,%gs
461
462         xorl %eax,%eax                  # Clear LDT
463         lldt %ax
464
465         cld                     # gcc2 wants the direction flag cleared at all times
466         pushl $0                # fake return address for unwinder
467 #ifdef CONFIG_SMP
468         movb ready, %cl
469         movb $1, ready
470         cmpb $0,%cl             # the first CPU calls start_kernel
471         je   1f
472         movl (stack_start), %esp
473 1:
474 #endif /* CONFIG_SMP */
475         jmp *(initial_code)
476
477 /*
478  * We depend on ET to be correct. This checks for 287/387.
479  */
480 check_x87:
481         movb $0,X86_HARD_MATH
482         clts
483         fninit
484         fstsw %ax
485         cmpb $0,%al
486         je 1f
487         movl %cr0,%eax          /* no coprocessor: have to set bits */
488         xorl $4,%eax            /* set EM */
489         movl %eax,%cr0
490         ret
491         ALIGN
492 1:      movb $1,X86_HARD_MATH
493         .byte 0xDB,0xE4         /* fsetpm for 287, ignored by 387 */
494         ret
495
496 /*
497  *  setup_idt
498  *
499  *  sets up a idt with 256 entries pointing to
500  *  ignore_int, interrupt gates. It doesn't actually load
501  *  idt - that can be done only after paging has been enabled
502  *  and the kernel moved to PAGE_OFFSET. Interrupts
503  *  are enabled elsewhere, when we can be relatively
504  *  sure everything is ok.
505  *
506  *  Warning: %esi is live across this function.
507  */
508 setup_idt:
509         lea ignore_int,%edx
510         movl $(__KERNEL_CS << 16),%eax
511         movw %dx,%ax            /* selector = 0x0010 = cs */
512         movw $0x8E00,%dx        /* interrupt gate - dpl=0, present */
513
514         lea idt_table,%edi
515         mov $256,%ecx
516 rp_sidt:
517         movl %eax,(%edi)
518         movl %edx,4(%edi)
519         addl $8,%edi
520         dec %ecx
521         jne rp_sidt
522
523 .macro  set_early_handler handler,trapno
524         lea \handler,%edx
525         movl $(__KERNEL_CS << 16),%eax
526         movw %dx,%ax
527         movw $0x8E00,%dx        /* interrupt gate - dpl=0, present */
528         lea idt_table,%edi
529         movl %eax,8*\trapno(%edi)
530         movl %edx,8*\trapno+4(%edi)
531 .endm
532
533         set_early_handler handler=early_divide_err,trapno=0
534         set_early_handler handler=early_illegal_opcode,trapno=6
535         set_early_handler handler=early_protection_fault,trapno=13
536         set_early_handler handler=early_page_fault,trapno=14
537
538         ret
539
540 early_divide_err:
541         xor %edx,%edx
542         pushl $0        /* fake errcode */
543         jmp early_fault
544
545 early_illegal_opcode:
546         movl $6,%edx
547         pushl $0        /* fake errcode */
548         jmp early_fault
549
550 early_protection_fault:
551         movl $13,%edx
552         jmp early_fault
553
554 early_page_fault:
555         movl $14,%edx
556         jmp early_fault
557
558 early_fault:
559         cld
560 #ifdef CONFIG_PRINTK
561         pusha
562         movl $(__KERNEL_DS),%eax
563         movl %eax,%ds
564         movl %eax,%es
565         cmpl $2,early_recursion_flag
566         je hlt_loop
567         incl early_recursion_flag
568         movl %cr2,%eax
569         pushl %eax
570         pushl %edx              /* trapno */
571         pushl $fault_msg
572         call printk
573 #endif
574         call dump_stack
575 hlt_loop:
576         hlt
577         jmp hlt_loop
578
579 /* This is the default interrupt "handler" :-) */
580         ALIGN
581 ignore_int:
582         cld
583 #ifdef CONFIG_PRINTK
584         pushl %eax
585         pushl %ecx
586         pushl %edx
587         pushl %es
588         pushl %ds
589         movl $(__KERNEL_DS),%eax
590         movl %eax,%ds
591         movl %eax,%es
592         cmpl $2,early_recursion_flag
593         je hlt_loop
594         incl early_recursion_flag
595         pushl 16(%esp)
596         pushl 24(%esp)
597         pushl 32(%esp)
598         pushl 40(%esp)
599         pushl $int_msg
600         call printk
601
602         call dump_stack
603
604         addl $(5*4),%esp
605         popl %ds
606         popl %es
607         popl %edx
608         popl %ecx
609         popl %eax
610 #endif
611         iret
612
613         __REFDATA
614 .align 4
615 ENTRY(initial_code)
616         .long i386_start_kernel
617 ENTRY(initial_page_table)
618         .long pa(swapper_pg_dir)
619
620 /*
621  * BSS section
622  */
623 __PAGE_ALIGNED_BSS
624         .align PAGE_SIZE_asm
625 #ifdef CONFIG_X86_PAE
626 swapper_pg_pmd:
627         .fill 1024*KPMDS,4,0
628 #else
629 ENTRY(swapper_pg_dir)
630         .fill 1024,4,0
631 #endif
632 swapper_pg_fixmap:
633         .fill 1024,4,0
634 #ifdef CONFIG_X86_TRAMPOLINE
635 ENTRY(trampoline_pg_dir)
636         .fill 1024,4,0
637 #endif
638 ENTRY(empty_zero_page)
639         .fill 4096,1,0
640
641 /*
642  * This starts the data section.
643  */
644 #ifdef CONFIG_X86_PAE
645 __PAGE_ALIGNED_DATA
646         /* Page-aligned for the benefit of paravirt? */
647         .align PAGE_SIZE_asm
648 ENTRY(swapper_pg_dir)
649         .long   pa(swapper_pg_pmd+PGD_IDENT_ATTR),0     /* low identity map */
650 # if KPMDS == 3
651         .long   pa(swapper_pg_pmd+PGD_IDENT_ATTR),0
652         .long   pa(swapper_pg_pmd+PGD_IDENT_ATTR+0x1000),0
653         .long   pa(swapper_pg_pmd+PGD_IDENT_ATTR+0x2000),0
654 # elif KPMDS == 2
655         .long   0,0
656         .long   pa(swapper_pg_pmd+PGD_IDENT_ATTR),0
657         .long   pa(swapper_pg_pmd+PGD_IDENT_ATTR+0x1000),0
658 # elif KPMDS == 1
659         .long   0,0
660         .long   0,0
661         .long   pa(swapper_pg_pmd+PGD_IDENT_ATTR),0
662 # else
663 #  error "Kernel PMDs should be 1, 2 or 3"
664 # endif
665         .align PAGE_SIZE_asm            /* needs to be page-sized too */
666 #endif
667
668 .data
669 ENTRY(stack_start)
670         .long init_thread_union+THREAD_SIZE
671         .long __BOOT_DS
672
673 ready:  .byte 0
674
675 early_recursion_flag:
676         .long 0
677
678 int_msg:
679         .asciz "Unknown interrupt or fault at: %p %p %p\n"
680
681 fault_msg:
682 /* fault info: */
683         .ascii "BUG: Int %d: CR2 %p\n"
684 /* pusha regs: */
685         .ascii "     EDI %p  ESI %p  EBP %p  ESP %p\n"
686         .ascii "     EBX %p  EDX %p  ECX %p  EAX %p\n"
687 /* fault frame: */
688         .ascii "     err %p  EIP %p   CS %p  flg %p\n"
689         .ascii "Stack: %p %p %p %p %p %p %p %p\n"
690         .ascii "       %p %p %p %p %p %p %p %p\n"
691         .asciz "       %p %p %p %p %p %p %p %p\n"
692
693 #include "../../x86/xen/xen-head.S"
694
695 /*
696  * The IDT and GDT 'descriptors' are a strange 48-bit object
697  * only used by the lidt and lgdt instructions. They are not
698  * like usual segment descriptors - they consist of a 16-bit
699  * segment size, and 32-bit linear address value:
700  */
701
702 .globl boot_gdt_descr
703 .globl idt_descr
704
705         ALIGN
706 # early boot GDT descriptor (must use 1:1 address mapping)
707         .word 0                         # 32 bit align gdt_desc.address
708 boot_gdt_descr:
709         .word __BOOT_DS+7
710         .long boot_gdt - __PAGE_OFFSET
711
712         .word 0                         # 32-bit align idt_desc.address
713 idt_descr:
714         .word IDT_ENTRIES*8-1           # idt contains 256 entries
715         .long idt_table
716
717 # boot GDT descriptor (later on used by CPU#0):
718         .word 0                         # 32 bit align gdt_desc.address
719 ENTRY(early_gdt_descr)
720         .word GDT_ENTRIES*8-1
721         .long gdt_page                  /* Overwritten for secondary CPUs */
722
723 /*
724  * The boot_gdt must mirror the equivalent in setup.S and is
725  * used only for booting.
726  */
727         .align L1_CACHE_BYTES
728 ENTRY(boot_gdt)
729         .fill GDT_ENTRY_BOOT_CS,8,0
730         .quad 0x00cf9a000000ffff        /* kernel 4GB code at 0x00000000 */
731         .quad 0x00cf92000000ffff        /* kernel 4GB data at 0x00000000 */